/[gentoo-alt]/trunk/sys-fs/e2fsprogs/e2fsprogs-1.38.ebuild
Gentoo

Contents of /trunk/sys-fs/e2fsprogs/e2fsprogs-1.38.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 665 - (show annotations) (download)
Wed Aug 24 11:19:51 2005 UTC (9 years, 3 months ago) by flameeyes
File size: 3499 byte(s)
Added e2fsprogs that installs on G/FBSD. See bug #103388.

1 # Copyright 1999-2005 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header$
4
5 inherit eutils flag-o-matic toolchain-funcs
6
7 DESCRIPTION="Standard EXT2 and EXT3 filesystem utilities"
8 HOMEPAGE="http://e2fsprogs.sourceforge.net/"
9 SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
10
11 LICENSE="GPL-2"
12 SLOT="0"
13 KEYWORDS="alpha amd64 arm hppa ia64 m68k ~mips ppc ppc64 s390 sh sparc x86"
14 IUSE="nls static"
15
16 # Dietlibc support is broken, see #81096
17 #diet? ( dev-libs/dietlibc )
18 RDEPEND="~sys-libs/com_err-${PV}
19 ~sys-libs/ss-${PV}"
20 DEPEND="${RDEPEND}
21 nls? ( sys-devel/gettext )
22 sys-apps/texinfo"
23
24 src_unpack() {
25 unpack ${A}; cd "${S}"
26 # Fix a cosmetic error in mk_cmds's help output.
27 epatch "${FILESDIR}"/e2fsprogs-1.32-mk_cmds-cosmetic.patch
28 chmod u+w po/*.po # Userpriv fix #27348
29 # Clean up makefile to suck less
30 epatch "${FILESDIR}"/e2fsprogs-1.36-makefile.patch
31 # Fix segfault with disconnected inodes #91751
32 epatch "${FILESDIR}"/${P}-disconnected-inodes.patch
33
34 # kernel headers use the same defines as e2fsprogs and can cause issues #48829
35 sed -i \
36 -e 's:CONFIG_JBD_DEBUG:__CONFIG_JBD_DEBUG__E2FS:g' \
37 $(grep -rl CONFIG_JBD_DEBUG *) \
38 || die "sed jbd debug failed"
39
40 # building e2fsprogs on sparc results in silo breaking
41 [[ ${ARCH} == "sparc" ]] && filter-flags -fstack-protector
42
43 # fake out files we forked into sep packages
44 sed -i \
45 -e '/^LIB_SUBDIRS/s:lib/et::' \
46 -e '/^LIB_SUBDIRS/s:lib/ss::' \
47 Makefile.in || die "remove subdirs"
48 ln -s "${ROOT}"/usr/$(get_libdir)/libcom_err.a lib/libcom_err.a
49 ln -s "${ROOT}"/$(get_libdir)/libcom_err.so lib/libcom_err.so
50 ln -s /usr/bin/mk_cmds lib/ss/mk_cmds
51 ln -s "${ROOT}"/usr/include/ss/ss_err.h lib/ss/
52 ln -s "${ROOT}"/$(get_libdir)/libss.so lib/libss.so
53
54 # Keep the package from doing silly things
55 export LDCONFIG=/bin/true
56 export CC=$(tc-getCC)
57 export STRIP=/bin/true
58 }
59
60 src_compile() {
61 local myconf
62 # use diet && myconf="${myconf} --with-diet-libc"
63 econf \
64 --bindir=/bin \
65 --sbindir=/sbin \
66 --enable-elf-shlibs \
67 --with-ldopts="${LDFLAGS}" \
68 $(use_enable !static dynamic-e2fsck) \
69 --without-included-gettext \
70 $(use_enable nls) \
71 $(use_enable userland_GNU fsck) \
72 ${myconf} \
73 || die
74 if [[ ${CTARGET:-${CHOST}} != *-uclibc ]] && grep -qs 'USE_INCLUDED_LIBINTL.*yes' config.{log,status} ; then
75 eerror "INTL sanity check failed, aborting build."
76 eerror "Please post your ${S}/config.log file as an"
77 eerror "attachment to http://bugs.gentoo.org/show_bug.cgi?id=81096"
78 die "Preventing included intl cruft from building"
79 fi
80 mkdir -p lib/{blkid,e2p,et,ext2fs,ss,uuid}/{checker,elfshared,pic,profiled} #102412
81 # Parallel make sometimes fails
82 emake -j1 COMPILE_ET=compile_et || die
83 }
84
85 src_install() {
86 make DESTDIR="${D}" install || die
87 dodoc ChangeLog README RELEASE-NOTES SHLIBS
88 docinto e2fsck
89 dodoc e2fsck/ChangeLog e2fsck/CHANGES
90
91 # Move shared libraries to /lib/, install static libraries to /usr/lib/,
92 # and install linker scripts to /usr/lib/.
93 dodir /$(get_libdir)
94 mv "${D}"/usr/$(get_libdir)/*.so* "${D}"/$(get_libdir)/
95 dolib.a lib/*.a || die "dolib.a"
96 local x
97 cd "${D}"/$(get_libdir)
98 for x in *.so ; do
99 gen_usr_ldscript ${x} || die "gen ldscript ${x}"
100 done
101
102 # move 'useless' stuff to /usr/
103 dosbin "${D}"/sbin/mklost+found
104 rm -f "${D}"/sbin/mklost+found
105
106 # these manpages are already provided by FreeBSD libc
107 use elibc_FreeBSD && \
108 rm -f ${D}/usr/share/man/man3/{uuid,uuid_compare}.3 \
109 ${D}/usr/share/man/man1/uuidgen.1
110 }

Properties

Name Value
svn:eol-style native
svn:keywords Author Date Id Revision

  ViewVC Help
Powered by ViewVC 1.1.20