/[gentoo-projects]/portage-utils/configure.ac
Gentoo

Contents of /portage-utils/configure.ac

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.8 - (show annotations) (download)
Sun Apr 15 05:43:12 2012 UTC (2 years, 3 months ago) by vapier
Branch: MAIN
Changes since 1.7: +1 -1 lines
use newer AX macro as the old one has been dropped

1 AC_PREREQ([2.65])
2 AC_INIT([portage-utils], [cvs])
3 AC_CONFIG_AUX_DIR([autotools])
4 AM_INIT_AUTOMAKE([1.11 dist-xz no-dist-gzip silent-rules -Wall])
5 AM_SILENT_RULES([yes]) # AM_INIT_AUTOMAKE([silent-rules]) is broken atm
6 AC_CONFIG_HEADER([config.h])
7 AC_CONFIG_MACRO_DIR([autotools/m4])
8
9 AC_PROG_CC_C99
10 AM_PROG_CC_C_O
11 AC_USE_SYSTEM_EXTENSIONS
12
13 gl_EARLY
14 gl_INIT
15
16 AC_CHECK_LIB([kvm], [kvm_open])
17
18 AC_CHECK_FUNCS_ONCE(m4_flatten([
19 scandirat
20 ]))
21
22 AC_ARG_WITH([eprefix], [AS_HELP_STRING([--with-eprefix], [path for Gentoo/Prefix project])])
23 # ensure eprefix ends with a slash, since the code base expects that
24 case "$with_eprefix" in
25 */) with_eprefix="$with_eprefix" ;;
26 *) with_eprefix="${with_eprefix}/" ;;
27 esac
28 AC_DEFINE_UNQUOTED([CONFIG_EPREFIX], ["$with_eprefix"], [path for Gentoo/Prefix project])
29
30 AX_CFLAGS_WARN_ALL
31 AC_DEFUN([PT_CHECK_CFLAG],[AX_CHECK_COMPILER_FLAGS([$1],[CFLAGS="$CFLAGS $1"])])
32 m4_foreach_w([flag], [
33 -Wunused
34 -Wimplicit
35 -Wshadow
36 -Wformat=2
37 -Wmissing-declarations
38 -Wno-missing-prototypes
39 -Wwrite-strings
40 -Wbad-function-cast
41 -Wnested-externs
42 -Wcomment
43 -Winline
44 -Wchar-subscripts
45 -Wcast-align
46 -Wno-format-nonliteral
47 -Wsequence-point
48 -Wextra
49 ], [
50 AX_CHECK_COMPILE_FLAG(flag, AS_VAR_APPEND([CFLAGS], " flag"))
51 ])
52
53 AC_CONFIG_FILES([
54 Makefile
55 autotools/gnulib/Makefile
56 ])
57 AC_OUTPUT

  ViewVC Help
Powered by ViewVC 1.1.20