/[gentoo-x86]/app-admin/webapp-config/webapp-config-1.51-r1.ebuild
Gentoo

Contents of /app-admin/webapp-config/webapp-config-1.51-r1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.2 - (show annotations) (download)
Thu Sep 5 18:15:49 2013 UTC (10 months, 2 weeks ago) by mgorny
Branch: MAIN
CVS Tags: HEAD
Changes since 1.1: +2 -2 lines
Clean up PYTHON_COMPAT from old implementations.

(Portage version: 2.2.1/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

1 # Copyright 1999-2013 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/app-admin/webapp-config/webapp-config-1.51-r1.ebuild,v 1.1 2013/08/06 11:09:00 blueness Exp $
4
5 EAPI="5"
6
7 PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} pypy2_0 )
8
9 inherit distutils-r1
10
11 DESCRIPTION="Gentoo's installer for web-based applications"
12 HOMEPAGE="http://sourceforge.net/projects/webapp-config/"
13 SRC_URI="http://dev.gentoo.org/~blueness/${PN}/${P}.tar.bz2"
14
15 LICENSE="GPL-2"
16 SLOT="0"
17 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
18 IUSE="+portage"
19
20 DEPEND="app-text/xmlto"
21 RDEPEND="portage? ( sys-apps/portage[${PYTHON_USEDEP}] )"
22
23 PATCHES=( "${FILESDIR}"/${P}-fix-indentation.patch )
24
25 python_compile_all() {
26 emake -C doc/
27 }
28
29 python_install() {
30 # According to this discussion:
31 # http://mail.python.org/pipermail/distutils-sig/2004-February/003713.html
32 # distutils does not provide for specifying two different script install
33 # locations. Since we only install one script here the following should
34 # be ok
35 distutils-r1_python_install --install-scripts="/usr/sbin"
36 }
37
38 python_install_all() {
39 distutils-r1_python_install_all
40
41 insinto /etc/vhosts
42 doins config/webapp-config
43
44 keepdir /usr/share/webapps
45 keepdir /var/db/webapps
46
47 dodoc AUTHORS
48 doman doc/*.[58]
49 dohtml doc/*.[58].html
50 }
51
52 python_test() {
53 PYTHONPATH="." "${PYTHON}" WebappConfig/tests/dtest.py \
54 || die "Testing failed with ${EPYTHON}"
55 }
56
57 pkg_postinst() {
58 elog "Now that you have upgraded webapp-config, you **must** update your"
59 elog "config files in /etc/vhosts/webapp-config before you emerge any"
60 elog "packages that use webapp-config."
61 }

  ViewVC Help
Powered by ViewVC 1.1.20