/[gentoo-x86]/app-admin/webapp-config/webapp-config-9999.ebuild
Gentoo

Contents of /app-admin/webapp-config/webapp-config-9999.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.6 - (show annotations) (download)
Thu Sep 5 18:15:49 2013 UTC (15 months, 3 weeks ago) by mgorny
Branch: MAIN
Changes since 1.5: +2 -2 lines
Clean up PYTHON_COMPAT from old implementations.

(Portage version: 2.2.1/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

1 # Copyright 1999-2013 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/app-admin/webapp-config/webapp-config-9999.ebuild,v 1.5 2013/08/04 00:28:55 blueness Exp $
4
5 EAPI="5"
6
7 PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} pypy2_0 )
8
9 inherit distutils-r1
10
11 if [[ ${PV} = 9999* ]]
12 then
13 EGIT_REPO_URI="git://git.overlays.gentoo.org/proj/${PN}.git"
14 inherit git-2
15 KEYWORDS=""
16 else
17 SRC_URI="http://dev.gentoo.org/~blueness/${PN}/${P}.tar.bz2"
18 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
19 fi
20
21 DESCRIPTION="Gentoo's installer for web-based applications"
22 HOMEPAGE="http://sourceforge.net/projects/webapp-config/"
23
24 LICENSE="GPL-2"
25 SLOT="0"
26 IUSE="+portage"
27
28 DEPEND="app-text/xmlto"
29 RDEPEND="portage? ( sys-apps/portage[${PYTHON_USEDEP}] )"
30
31 python_compile_all() {
32 emake -C doc/
33 }
34
35 python_install() {
36 # According to this discussion:
37 # http://mail.python.org/pipermail/distutils-sig/2004-February/003713.html
38 # distutils does not provide for specifying two different script install
39 # locations. Since we only install one script here the following should
40 # be ok
41 distutils-r1_python_install --install-scripts="/usr/sbin"
42 }
43
44 python_install_all() {
45 distutils-r1_python_install_all
46
47 insinto /etc/vhosts
48 doins config/webapp-config
49
50 keepdir /usr/share/webapps
51 keepdir /var/db/webapps
52
53 dodoc AUTHORS
54 doman doc/*.[58]
55 dohtml doc/*.[58].html
56 }
57
58 python_test() {
59 PYTHONPATH="." "${PYTHON}" WebappConfig/tests/dtest.py \
60 || die "Testing failed with ${EPYTHON}"
61 }
62
63 pkg_postinst() {
64 elog "Now that you have upgraded webapp-config, you **must** update your"
65 elog "config files in /etc/vhosts/webapp-config before you emerge any"
66 elog "packages that use webapp-config."
67 }

  ViewVC Help
Powered by ViewVC 1.1.20