/[gentoo-x86]/app-arch/tar/tar-1.25-r1.ebuild
Gentoo

Contents of /app-arch/tar/tar-1.25-r1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.6 - (show annotations) (download)
Mon Nov 25 12:20:59 2013 UTC (10 months, 4 weeks ago) by polynomial-c
Branch: MAIN
CVS Tags: HEAD
Changes since 1.5: +1 -1 lines
FILE REMOVED
Version bump. Removed old

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 0x981CA6FC)

1 # Copyright 1999-2013 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/app-arch/tar/tar-1.25-r1.ebuild,v 1.5 2013/10/15 09:03:17 polynomial-c Exp $
4
5 EAPI="3"
6
7 inherit flag-o-matic eutils
8
9 DESCRIPTION="Use this to make tarballs :)"
10 HOMEPAGE="http://www.gnu.org/software/tar/"
11 SRC_URI="mirror://gnu/tar/${P}.tar.bz2
12 mirror://gnu-alpha/tar/${P}.tar.bz2"
13
14 LICENSE="GPL-3+"
15 SLOT="0"
16 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~x86-fbsd ~x64-freebsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
17 IUSE="nls static userland_GNU"
18
19 RDEPEND=""
20 DEPEND="${RDEPEND}
21 nls? ( >=sys-devel/gettext-0.10.35 )"
22
23 src_prepare() {
24 epatch "${FILESDIR}"/${P}-incremental-fix.patch #349164
25 epatch "${FILESDIR}"/${P}-verify-fix.patch #349155
26 epatch "${FILESDIR}"/${P}-verify-check.patch
27 if ! use userland_GNU ; then
28 sed -i \
29 -e 's:/backup\.sh:/gbackup.sh:' \
30 scripts/{backup,dump-remind,restore}.in \
31 || die "sed non-GNU"
32 fi
33 }
34
35 src_configure() {
36 local myconf
37 use static && append-ldflags -static
38 use userland_GNU || myconf="--program-prefix=g"
39 # Work around bug in sandbox #67051
40 gl_cv_func_chown_follows_symlink=yes \
41 FORCE_UNSAFE_CONFIGURE=1 \
42 econf \
43 --enable-backup-scripts \
44 --bindir="${EPREFIX}"/bin \
45 --libexecdir="${EPREFIX}"/usr/sbin \
46 $(use_enable nls) \
47 ${myconf}
48 }
49
50 src_install() {
51 local p=""
52 use userland_GNU || p=g
53
54 emake DESTDIR="${D}" install || die
55
56 if [[ -z ${p} ]] ; then
57 # a nasty yet required piece of baggage
58 exeinto /etc
59 doexe "${FILESDIR}"/rmt || die
60 fi
61
62 # autoconf looks for gtar before tar (in configure scripts), hence
63 # in Prefix it is important that it is there, otherwise, a gtar from
64 # the host system (FreeBSD, Solaris, Darwin) will be found instead
65 # of the Prefix provided (GNU) tar
66 if use prefix ; then
67 dosym tar /bin/gtar
68 fi
69
70 dodoc AUTHORS ChangeLog* NEWS README* THANKS
71 newman "${FILESDIR}"/tar.1 ${p}tar.1
72 mv "${ED}"/usr/sbin/${p}backup{,-tar}
73 mv "${ED}"/usr/sbin/${p}restore{,-tar}
74 }

  ViewVC Help
Powered by ViewVC 1.1.20