/[gentoo-x86]/app-backup/spideroak-bin/spideroak-bin-4.6.9945.ebuild
Gentoo

Contents of /app-backup/spideroak-bin/spideroak-bin-4.6.9945.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.5 - (show annotations) (download)
Mon May 6 22:03:48 2013 UTC (15 months, 2 weeks ago) by blueness
Branch: MAIN
CVS Tags: HEAD
Changes since 1.4: +1 -1 lines
Error occurred while calculating annotation data.
FILE REMOVED
Version bump and clean older unstable, bug #468774

(Portage version: 2.1.11.62/cvs/Linux x86_64, signed Manifest commit with key 0xF52D4BBA)

1 # Copyright 1999-2013 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/app-backup/spideroak-bin/spideroak-bin-4.6.9945.ebuild,v 1.4 2013/03/23 19:44:29 vapier Exp $
4
5 EAPI="4"
6
7 inherit eutils versionator unpacker
8
9 REV=$(get_version_component_range 3)
10 SRC_URI_BASE="https://spideroak.com/directdownload?platform=ubuntulucid"
11
12 DESCRIPTION="An easy, secure and consolidated free online backup, storage, access and sharing system."
13 HOMEPAGE="https://spideroak.com"
14 SRC_URI="x86? ( ${SRC_URI_BASE}&arch=i386&revision=${REV} -> ${P}_x86.deb )
15 amd64? ( ${SRC_URI_BASE}&arch=x86_64&revision=${REV} -> ${P}_amd64.deb )"
16 RESTRICT="mirror strip"
17
18 LICENSE="spideroak"
19 SLOT="0"
20 KEYWORDS="~amd64 ~x86"
21 IUSE="dbus headless system-libs"
22
23 SSL_SLOT="0.9.8"
24
25 DEPEND=""
26 RDEPEND="
27 dbus? ( sys-apps/dbus )
28 !headless? (
29 media-libs/fontconfig
30 media-libs/freetype:2
31 dev-libs/glib:2
32 x11-libs/libICE
33 x11-libs/libSM
34 x11-libs/libX11
35 x11-libs/libXext
36 x11-libs/libXmu
37 x11-libs/libXrender
38 x11-libs/libXt
39 )
40 system-libs? (
41 dev-libs/openssl:$SSL_SLOT
42 net-misc/curl
43 >=sys-devel/gcc-4
44 dev-libs/glib:2
45 dev-libs/libpcre
46 media-libs/libpng:1.2
47 dev-qt/qtcore:4
48 dev-qt/qtgui:4
49 dev-db/sqlite:3
50 net-libs/libssh2
51 sys-libs/zlib
52 dev-lang/python:2.7
53 dev-python/pycurl
54 )
55 "
56
57 S=${WORKDIR}
58
59 QA_PREBUILT="*"
60
61 src_prepare() {
62 epatch "${FILESDIR}"/opt-path.patch
63 use headless && epatch "${FILESDIR}"/headless.patch
64
65 # Remove bundled libraries/plugins/python interpreter. Please keep this
66 # mapping in sync with the RDEPEND system-libs? ( atoms ) above, and the
67 # list of deleted files below
68 #
69 # libcrypto.so.0.$SSL_SLOT => dev-libs/openssl:$SSL_SLOT
70 # libssl.so.$SSL_SLOT => dev-libs/openssl:$SSL_SLOT
71 # libcurl.so* => net-misc/curl
72 # libexpat.so* => dev-libs/expat
73 # libgcc_s.so => >=sys-devel/gcc-4
74 # libstdc++.so* => >=sys-devel/gcc-4
75 # libpcre.so* => dev-libs/libpcre
76 # libpng12* => media-libs/libpng:1.2
77 # libQt*.so* => dev-qt/qtcore dev-qt/qtgui
78 # libsqlite3.so* => dev-db/sqlite:3
79 # libssh2.so* => net-libs/libssh2
80 # libz.so* => sys-libs/zlib
81 #
82 # pycurl.so => dev-python/pycurl
83 #
84 # usr/lib/SpiderOak/py pyexpat.so => dev-lang/python:2.7
85 #
86 if use system-libs; then
87 for lib in \
88 libcrypto.so.$SSL_SLOT \
89 libssl.so.$SSL_SLOT \
90 libcurl.so* \
91 libexpat.so* \
92 libgcc_s.so* \
93 libpcre.so* \
94 libpng12* \
95 libQt*.so* \
96 libsqlite3.so* \
97 libssh2.so* \
98 libstdc++.so* \
99 libz.so* \
100 pycurl.so \
101 pyexpat.so
102 do
103 rm usr/lib/SpiderOak/$lib || die "rm $lib failed"
104 done
105
106 # Remove bundled python interpreter => dev-lang/python:2.7
107 rm usr/lib/SpiderOak/py || die "rm py failed"
108 fi
109 }
110
111 src_install() {
112 #install the executable script
113 exeinto /usr/bin
114 doexe usr/bin/SpiderOak
115
116 #install the prebundled libraries
117 dodir /opt
118 cp -pPR usr/lib/SpiderOak "${ED}"/opt/
119
120 #install the config files
121 rm -rf etc/apt
122 use dbus || rm -rf etc/dbus-1
123 insinto /
124 doins -r etc
125
126 #install the changelog
127 dodoc usr/share/doc/spideroak/changelog.gz
128
129 if ! use headless ; then
130 domenu usr/share/applications/spideroak.desktop
131 doicon usr/share/pixmaps/spideroak.png
132 fi
133 }
134
135 pkg_postinst() {
136 if use headless; then
137 einfo "For instructions on running SpiderOak without a GUI, please read the FAQ:"
138 einfo " https://spideroak.com/faq/questions/62/how_do_i_install_spideroak_on_a_headless_linux_server/"
139 einfo " https://spideroak.com/faq/questions/67/how_can_i_use_spideroak_from_the_commandline/"
140 fi
141 if use system-libs; then
142 einfo "You have chosen to use your system libraries rather than the precompiled libraries that"
143 einfo "SpiderOak bundles with their software. While upstream discourages this (see bug #398313),"
144 einfo "there are advantages to using the system libraries, like reducing the size of the package"
145 einfo "on your hard drive. For more reasons why bundled librars are not a good idea, see"
146 einfo " https://fedoraproject.org/wiki/Packaging:No_Bundled_Libraries"
147 fi
148 }

  ViewVC Help
Powered by ViewVC 1.1.20