/[gentoo-x86]/app-cdr/dvdisaster/dvdisaster-0.72.4.ebuild
Gentoo

Contents of /app-cdr/dvdisaster/dvdisaster-0.72.4.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.7 - (show annotations) (download)
Wed Sep 26 11:11:08 2012 UTC (2 years ago) by ssuominen
Branch: MAIN
CVS Tags: HEAD
Changes since 1.6: +2 -2 lines
ppc stable wrt #428050

(Portage version: 2.2.0_alpha128/cvs/Linux x86_64)

1 # Copyright 1999-2012 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/app-cdr/dvdisaster/dvdisaster-0.72.4.ebuild,v 1.6 2012/08/05 11:02:50 ssuominen Exp $
4
5 EAPI=4
6 inherit eutils gnome2-utils toolchain-funcs
7
8 DESCRIPTION="Data-protection and recovery tool for DVDs"
9 HOMEPAGE="http://dvdisaster.sourceforge.net/"
10 SRC_URI="mirror://debian/pool/main/${PN:0:1}/${PN}/${PN}_${PV}.orig.tar.bz2"
11
12 LICENSE="GPL-2"
13 SLOT="0"
14 KEYWORDS="amd64 ppc x86"
15 IUSE="debug nls"
16
17 dvdi_langs="cs de it pt_BR ru sv"
18 for dvdi_lang in ${dvdi_langs}; do
19 IUSE+=" linguas_${dvdi_lang}"
20 done
21 unset dvdi_lang
22
23 RDEPEND="app-arch/bzip2
24 >=dev-libs/glib-2.20
25 media-libs/libpng:0
26 sys-libs/zlib
27 >=x11-libs/gtk+-2.14:2"
28 DEPEND="${RDEPEND}
29 virtual/os-headers
30 virtual/pkgconfig"
31
32 src_configure() {
33 ./configure \
34 --prefix=/usr \
35 --bindir=/usr/bin \
36 --mandir=/usr/share/man \
37 --docdir=/usr/share/doc \
38 --docsubdir=${PF} \
39 --localedir=/usr/share/locale \
40 --buildroot="${D}" \
41 --with-nls=$(usex nls) \
42 --with-memdebug=$(usex debug) || die
43 }
44
45 src_compile() {
46 emake $(use nls && echo -j1) CC="$(tc-getCC)"
47 }
48
49 src_install() {
50 emake install
51 dobin tools/pngpack
52
53 newdoc tools/README README.pngpack
54 dodoc CHANGELOG CREDITS.en README* TODO *HOWTO
55
56 newicon contrib/${PN}48.png ${PN}.png
57 make_desktop_entry ${PN} ${PN} ${PN} 'System;Utility'
58
59 local res
60 for res in 16 32 48 64; do
61 newicon -s ${res} contrib/${PN}${res}.png ${PN}.png
62 done
63
64 local dest="${ED}"/usr/share
65
66 local dvdi_lang
67 for dvdi_lang in ${dvdi_langs}; do
68 use linguas_${dvdi_lang} || rm -rf \
69 ${dest}/doc/${PF}/${dvdi_lang} \
70 ${dest}/doc/${PF}/CREDITS.${dvdi_lang} \
71 ${dest}/man/${dvdi_lang}
72 done
73
74 rm -f "${ED}"/usr/bin/*-uninstall.sh
75 }
76
77 pkg_preinst() { gnome2_icon_savelist; }
78 pkg_postinst() { gnome2_icon_cache_update; }
79 pkg_postrm() { gnome2_icon_cache_update; }

  ViewVC Help
Powered by ViewVC 1.1.20