/[gentoo-x86]/app-cdr/k3b/k3b-2.0.2-r4.ebuild
Gentoo

Contents of /app-cdr/k3b/k3b-2.0.2-r4.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.5 - (show annotations) (download)
Mon Dec 10 16:56:44 2012 UTC (22 months, 2 weeks ago) by kensington
Branch: MAIN
Changes since 1.4: +2 -2 lines
Drop ppc64 keyword due to unkeyworded required dependencies. Remove unused local USE flag.

(Portage version: 2.1.11.36/cvs/Linux x86_64, signed Manifest commit with key 675D0D2C)

1 # Copyright 1999-2012 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/app-cdr/k3b/k3b-2.0.2-r4.ebuild,v 1.4 2012/10/03 10:27:18 ago Exp $
4
5 EAPI=4
6
7 MULTIMEDIA_REQUIRED="always"
8 WEBKIT_REQUIRED="always"
9 KDE_HANDBOOK="optional"
10 KDE_SCM="git"
11
12 # Translations are only in the tarballs, not in the git repo
13 if [[ ${PV} != *9999* ]]; then
14 KDE_LINGUAS="ast be bg ca ca@valencia cs csb da de el en_GB eo es et eu fi fr ga
15 gl he hi hne hr hu is it ja km ko ku lt mai nb nds nl nn oc pa pl pt pt_BR ro ru
16 se sk sl sv th tr uk zh_CN zh_TW"
17
18 SRC_URI="mirror://sourceforge/${PN}/${P/_}.tar.bz2"
19 DOCS=( FAQ PERMISSIONS README )
20 S=${WORKDIR}/${P/_*}
21 else
22 DOCS=( FAQ.txt PERMISSIONS.txt README.txt )
23 fi
24
25 inherit kde4-base
26
27 DESCRIPTION="The CD/DVD Kreator for KDE"
28 HOMEPAGE="http://www.k3b.org/"
29
30 LICENSE="GPL-2 FDL-1.2"
31 SLOT="4"
32 KEYWORDS="amd64 ~ppc x86"
33 IUSE="debug dvd emovix encode ffmpeg flac mad mp3 musepack sndfile sox taglib vcd vorbis"
34
35 DEPEND="
36 $(add_kdebase_dep libkcddb)
37 media-libs/libsamplerate
38 dvd? ( media-libs/libdvdread )
39 ffmpeg? ( virtual/ffmpeg )
40 flac? ( >=media-libs/flac-1.2[cxx] )
41 mp3? ( media-sound/lame )
42 mad? ( media-libs/libmad )
43 musepack? ( >=media-sound/musepack-tools-444 )
44 sndfile? ( media-libs/libsndfile )
45 taglib? ( >=media-libs/taglib-1.5 )
46 vorbis? ( media-libs/libvorbis )
47 "
48 RDEPEND="${DEPEND}
49 $(add_kdebase_dep kdelibs 'udev,udisks(+)')
50 app-cdr/cdrdao
51 media-sound/cdparanoia
52 virtual/cdrtools
53 dvd? (
54 >=app-cdr/dvd+rw-tools-7
55 encode? ( media-video/transcode[dvd] )
56 )
57 emovix? ( media-video/emovix )
58 sox? ( media-sound/sox )
59 vcd? ( media-video/vcdimager )
60 "
61
62 DOCS+=( ChangeLog )
63
64 PATCHES=(
65 "${FILESDIR}/${P}-ffmpeg.patch"
66 "${FILESDIR}/${P}-libavformat54.patch"
67 )
68
69 REQUIRED_USE="
70 mp3? ( encode )
71 sox? ( encode )
72 "
73
74 src_configure() {
75 mycmakeargs=(
76 -DK3B_BUILD_API_DOCS=OFF
77 -DK3B_BUILD_K3BSETUP=OFF
78 -DK3B_BUILD_WAVE_DECODER_PLUGIN=ON
79 -DK3B_ENABLE_HAL_SUPPORT=OFF
80 -DK3B_ENABLE_MUSICBRAINZ=OFF
81 $(cmake-utils_use debug K3B_DEBUG)
82 $(cmake-utils_use dvd K3B_ENABLE_DVD_RIPPING)
83 $(cmake-utils_use encode K3B_BUILD_EXTERNAL_ENCODER_PLUGIN)
84 $(cmake-utils_use ffmpeg K3B_BUILD_FFMPEG_DECODER_PLUGIN)
85 $(cmake-utils_use flac K3B_BUILD_FLAC_DECODER_PLUGIN)
86 $(cmake-utils_use mp3 K3B_BUILD_LAME_ENCODER_PLUGIN)
87 $(cmake-utils_use mad K3B_BUILD_MAD_DECODER_PLUGIN)
88 $(cmake-utils_use musepack K3B_BUILD_MUSE_DECODER_PLUGIN)
89 $(cmake-utils_use sndfile K3B_BUILD_SNDFILE_DECODER_PLUGIN)
90 $(cmake-utils_use sox K3B_BUILD_SOX_ENCODER_PLUGIN)
91 $(cmake-utils_use taglib K3B_ENABLE_TAGLIB)
92 $(cmake-utils_use vorbis K3B_BUILD_OGGVORBIS_DECODER_PLUGIN)
93 $(cmake-utils_use vorbis K3B_BUILD_OGGVORBIS_ENCODER_PLUGIN)
94 )
95 kde4-base_src_configure
96 }
97
98 pkg_postinst() {
99 kde4-base_pkg_postinst
100
101 echo
102 elog "We don't install k3bsetup anymore because Gentoo doesn't need it."
103 elog "If you get warnings on start-up, uncheck the \"Check system"
104 elog "configuration\" option in the \"Misc\" settings window."
105 echo
106
107 local group=cdrom
108 use kernel_linux || group=operator
109 elog "Make sure you have proper read/write permissions on the cdrom device(s)."
110 elog "Usually, it is sufficient to be in the ${group} group."
111 echo
112 }

  ViewVC Help
Powered by ViewVC 1.1.20