/[gentoo-x86]/app-emacs/bbdb/bbdb-2.35-r1.ebuild
Gentoo

Contents of /app-emacs/bbdb/bbdb-2.35-r1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.9 - (show annotations) (download)
Sat Aug 2 17:38:12 2014 UTC (2 months, 2 weeks ago) by armin76
Branch: MAIN
CVS Tags: HEAD
Changes since 1.8: +2 -2 lines
Drop alpha keywords

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 0xF6AD3240)

1 # Copyright 1999-2014 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/app-emacs/bbdb/bbdb-2.35-r1.ebuild,v 1.8 2014/08/02 15:42:13 armin76 Exp $
4
5 EAPI=4
6
7 inherit elisp
8
9 DESCRIPTION="The Insidious Big Brother Database"
10 HOMEPAGE="http://bbdb.sourceforge.net/"
11 SRC_URI="http://bbdb.sourceforge.net/${P}.tar.gz
12 http://www.mit.edu/afs/athena/contrib/emacs-contrib/Fin/point-at.el
13 http://www.mit.edu/afs/athena/contrib/emacs-contrib/Fin/dates.el"
14
15 LICENSE="GPL-2+ Texinfo-manual"
16 SLOT="0"
17 KEYWORDS="amd64 ppc x86 ~amd64-linux ~x86-linux ~ppc-macos ~sparc-solaris"
18 IUSE="tex"
19
20 RDEPEND="tex? ( virtual/tex-base )"
21
22 SITEFILE="50${PN}-gentoo.el"
23 TEXMF="/usr/share/texmf-site"
24
25 src_prepare() {
26 sed -i -e '0,/^--- bbdb-mail-folders.el ---$/d;/^--- end ---$/,$d' \
27 bits/bbdb-mail-folders.el || die "sed failed"
28 sed -i -e '/^;/,$!d' bits/bbdb-sort-mailrc.el || die "sed failed"
29 cp "${DISTDIR}"/{dates,point-at}.el bits || die "cp failed"
30 }
31
32 src_configure() {
33 default
34 }
35
36 src_compile() {
37 emake -j1
38 BYTECOMPFLAGS="-L bits -L lisp" elisp-compile bits/*.el || die
39 }
40
41 src_install() {
42 elisp-install ${PN} lisp/*.el{,c} || die
43 elisp-install ${PN}/bits bits/*.el{,c} || die
44 elisp-site-file-install "${FILESDIR}/${SITEFILE}" || die
45 doinfo texinfo/*.info*
46 dodoc ChangeLog INSTALL README bits/*.txt
47 newdoc bits/README README.bits
48 if use tex; then
49 insinto "${TEXMF}"/tex/plain/bbdb
50 doins tex/*.tex
51 fi
52 }
53
54 pkg_postinst() {
55 elisp-site-regen
56 use tex && texconfig rehash
57
58 elog "If you use encryption or signing, you may specify the encryption"
59 elog "method by customising variable \"bbdb/pgp-method\". For details,"
60 elog "see the documentation of this variable. Depending on the Emacs"
61 elog "version, installation of additional packages like app-emacs/gnus"
62 elog "or app-emacs/mailcrypt may be required."
63 }
64
65 pkg_postrm() {
66 elisp-site-regen
67 use tex && texconfig rehash
68 }

  ViewVC Help
Powered by ViewVC 1.1.20