/[gentoo-x86]/app-emulation/open-vm-tools-kmod/open-vm-tools-kmod-2013.09.16.1328054.ebuild
Gentoo

Contents of /app-emulation/open-vm-tools-kmod/open-vm-tools-kmod-2013.09.16.1328054.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.6 - (show annotations) (download)
Sun Aug 10 16:18:12 2014 UTC (2 months, 1 week ago) by floppym
Branch: MAIN
CVS Tags: HEAD
Changes since 1.5: +6 -4 lines
Add use flag to control building of vmhgfs module.

(Portage version: 2.2.11-r1/cvs/Linux x86_64, signed Manifest commit with key 0BBEEA1FEA4843A4)

1 # Copyright 1999-2014 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/app-emulation/open-vm-tools-kmod/open-vm-tools-kmod-2013.09.16.1328054.ebuild,v 1.5 2013/10/22 22:21:05 floppym Exp $
4
5 EAPI="5"
6
7 inherit eutils linux-mod versionator udev
8
9 MY_PN="${PN/-kmod}"
10 MY_PV="$(replace_version_separator 3 '-')"
11 MY_P="${MY_PN}-${MY_PV}"
12
13 DESCRIPTION="Opensourced tools for VMware guests"
14 HOMEPAGE="http://open-vm-tools.sourceforge.net/"
15 SRC_URI="mirror://sourceforge/${MY_PN}/${MY_P}.tar.gz"
16
17 LICENSE="LGPL-2"
18 SLOT="0"
19 KEYWORDS="~amd64 ~x86"
20 IUSE="vmhgfs"
21
22 S="${WORKDIR}/${MY_P}"
23
24 pkg_setup() {
25 CONFIG_CHECK="~DRM_VMWGFX ~VMWARE_BALLOON ~VMWARE_PVSCSI ~VMXNET3
26 !UIDGID_STRICT_TYPE_CHECKS"
27
28 # See logic in configure.ac.
29 local MODULES="vmxnet"
30
31 use vmhgfs && MODULES+=" vmhgfs"
32
33 if kernel_is -lt 3 9; then
34 MODULES+=" vmci vsock"
35 else
36 CONFIG_CHECK+=" VMWARE_VMCI ~VMWARE_VMCI_VSOCKETS"
37 fi
38
39 if kernel_is -lt 3; then
40 MODULES+=" vmblock vmsync"
41 else
42 CONFIG_CHECK+=" ~FUSE_FS"
43 fi
44
45 local mod
46 for mod in ${MODULES}; do
47 MODULE_NAMES+=" ${mod}(ovt:modules/linux/${mod})"
48 done
49
50 linux-mod_pkg_setup
51 }
52
53 src_prepare() {
54 epatch "${FILESDIR}/vmhgfs-linux-3.11.patch"
55 epatch_user
56 }
57
58 src_configure() {
59 BUILD_TARGETS="auto-build"
60 export OVT_SOURCE_DIR="${S}"
61 export LINUXINCLUDE="${KV_OUT_DIR}/include"
62 }
63
64 src_install() {
65 linux-mod_src_install
66 udev_dorules "${FILESDIR}/60-vmware.rules"
67 }

  ViewVC Help
Powered by ViewVC 1.1.20