/[gentoo-x86]/app-emulation/wine/wine-1.2.1.ebuild
Gentoo

Contents of /app-emulation/wine/wine-1.2.1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.1 - (hide annotations) (download)
Sun Nov 14 00:40:30 2010 UTC (3 years, 5 months ago) by vapier
Branch: MAIN
Version bump #342917 by Peter Volkov.

(Portage version: 2.2.0_alpha4/cvs/Linux x86_64)

1 vapier 1.1 # Copyright 1999-2010 Gentoo Foundation
2     # Distributed under the terms of the GNU General Public License v2
3     # $Header: /var/cvsroot/gentoo-x86/app-emulation/wine/wine-1.3.0.ebuild,v 1.7 2010/11/07 21:57:52 ssuominen Exp $
4    
5     EAPI="2"
6    
7     inherit eutils flag-o-matic multilib
8    
9     if [[ ${PV} == "9999" ]] ; then
10     EGIT_REPO_URI="git://source.winehq.org/git/wine.git"
11     inherit git autotools
12     SRC_URI=""
13     #KEYWORDS=""
14     else
15     AUTOTOOLS_AUTO_DEPEND="no"
16     inherit autotools
17     MY_P="${PN}-${PV/_/-}"
18     SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.bz2"
19     KEYWORDS="-* ~amd64 ~x86 ~x86-fbsd"
20     S=${WORKDIR}/${MY_P}
21     fi
22    
23     pulse_patches() { echo "$1"/winepulse-{0.36,0.35-configure.ac,0.38-winecfg}.patch ; }
24     GV="1.0.0-x86"
25     DESCRIPTION="free implementation of Windows(tm) on Unix"
26     HOMEPAGE="http://www.winehq.org/"
27     SRC_URI="${SRC_URI}
28     gecko? ( mirror://sourceforge/wine/wine_gecko-${GV}.cab )
29     pulseaudio? ( `pulse_patches http://art.ified.ca/downloads/winepulse` )"
30    
31     LICENSE="LGPL-2.1"
32     SLOT="0"
33     IUSE="alsa capi cups custom-cflags dbus esd fontconfig +gecko gnutls gphoto2 gsm hal jack jpeg lcms ldap mp3 nas ncurses openal +opengl +oss +perl png pulseaudio samba scanner ssl test +threads +truetype +win32 +win64 +X xcomposite xinerama xml"
34     RESTRICT="test" #72375
35    
36     MLIB_DEPS="amd64? (
37     truetype? ( >=app-emulation/emul-linux-x86-xlibs-2.1 )
38     X? (
39     >=app-emulation/emul-linux-x86-xlibs-2.1
40     >=app-emulation/emul-linux-x86-soundlibs-2.1
41     )
42     openal? ( app-emulation/emul-linux-x86-sdl )
43     opengl? ( app-emulation/emul-linux-x86-opengl )
44     app-emulation/emul-linux-x86-baselibs
45     >=sys-kernel/linux-headers-2.6
46     )"
47     RDEPEND="truetype? ( >=media-libs/freetype-2.0.0 media-fonts/corefonts )
48     perl? ( dev-lang/perl dev-perl/XML-Simple )
49     capi? ( net-dialup/capi4k-utils )
50     ncurses? ( >=sys-libs/ncurses-5.2 )
51     fontconfig? ( media-libs/fontconfig )
52     gphoto2? ( media-libs/libgphoto2 )
53     jack? ( media-sound/jack-audio-connection-kit )
54     openal? ( media-libs/openal )
55     dbus? ( sys-apps/dbus )
56     gnutls? ( net-libs/gnutls )
57     hal? ( sys-apps/hal )
58     X? (
59     x11-libs/libXcursor
60     x11-libs/libXrandr
61     x11-libs/libXi
62     x11-libs/libXmu
63     x11-libs/libXxf86vm
64     x11-apps/xmessage
65     )
66     xinerama? ( x11-libs/libXinerama )
67     alsa? ( media-libs/alsa-lib )
68     esd? ( media-sound/esound )
69     nas? ( media-libs/nas )
70     cups? ( net-print/cups )
71     opengl? ( virtual/opengl )
72     pulseaudio? ( media-sound/pulseaudio ${AUTOTOOLS_DEPEND} )
73     gsm? ( media-sound/gsm )
74     jpeg? ( virtual/jpeg )
75     ldap? ( net-nds/openldap )
76     lcms? ( =media-libs/lcms-1* )
77     mp3? ( >=media-sound/mpg123-1.5.0 )
78     samba? ( >=net-fs/samba-3.0.25 )
79     xml? ( dev-libs/libxml2 dev-libs/libxslt )
80     scanner? ( media-gfx/sane-backends )
81     ssl? ( dev-libs/openssl )
82     png? ( media-libs/libpng )
83     !win64? ( ${MLIB_DEPS} )
84     win32? ( ${MLIB_DEPS} )
85     xcomposite? ( x11-libs/libXcomposite ) "
86     DEPEND="${RDEPEND}
87     X? (
88     x11-proto/inputproto
89     x11-proto/xextproto
90     x11-proto/xf86vidmodeproto
91     )
92     xinerama? ( x11-proto/xineramaproto )
93     sys-devel/bison
94     sys-devel/flex"
95    
96     src_unpack() {
97     if use win64 ; then
98     [[ $(( $(gcc-major-version) * 100 + $(gcc-minor-version) )) -lt 404 ]] \
99     && die "you need gcc-4.4+ to build 64bit wine"
100     fi
101    
102     if [[ ${PV} == "9999" ]] ; then
103     git_src_unpack
104     else
105     unpack ${MY_P}.tar.bz2
106     fi
107     }
108    
109     src_prepare() {
110     if use pulseaudio ; then
111     EPATCH_OPTS=-p1 epatch `pulse_patches "${DISTDIR}"`
112     eautoreconf
113     fi
114     epatch "${FILESDIR}"/${PN}-1.1.15-winegcc.patch #260726
115     epatch_user #282735
116     sed -i '/^UPDATE_DESKTOP_DATABASE/s:=.*:=true:' tools/Makefile.in || die
117     sed -i '/^MimeType/d' tools/wine.desktop || die #117785
118     }
119    
120     do_configure() {
121     local builddir="${WORKDIR}/wine$1"
122     mkdir -p "${builddir}"
123     pushd "${builddir}" >/dev/null
124    
125     ECONF_SOURCE=${S} \
126     econf \
127     --sysconfdir=/etc/wine \
128     $(use_with alsa) \
129     $(use_with capi) \
130     $(use_with lcms cms) \
131     $(use_with cups) \
132     $(use_with ncurses curses) \
133     $(use_with esd) \
134     $(use_with fontconfig) \
135     $(use_with gnutls) \
136     $(use_with gphoto2 gphoto) \
137     $(use_with gsm) \
138     $(! use dbus && echo --without-hal || use_with hal) \
139     $(use_with jack) \
140     $(use_with jpeg) \
141     $(use_with ldap) \
142     $(use_with mp3 mpg123) \
143     $(use_with nas) \
144     $(use_with openal) \
145     $(use_with opengl) \
146     $(use_with ssl openssl) \
147     $(use_with oss) \
148     $(use_with png) \
149     $(use_with threads pthread) \
150     $(use pulseaudio && use_with pulseaudio pulse) \
151     $(use_with scanner sane) \
152     $(use_enable test tests) \
153     $(use_with truetype freetype) \
154     $(use_with X x) \
155     $(use_with xcomposite) \
156     $(use_with xinerama) \
157     $(use_with xml) \
158     $(use_with xml xslt) \
159     $2
160    
161     emake -j1 depend || die "depend"
162    
163     popd >/dev/null
164     }
165     src_configure() {
166     export LDCONFIG=/bin/true
167     use custom-cflags || strip-flags
168    
169     if use win64 ; then
170     do_configure 64 --enable-win64
171     use win32 && ABI=x86 do_configure 32 --with-wine64=../wine64
172     else
173     ABI=x86 do_configure 32 --disable-win64
174     fi
175     }
176    
177     src_compile() {
178     local b
179     for b in 64 32 ; do
180     local builddir="${WORKDIR}/wine${b}"
181     [[ -d ${builddir} ]] || continue
182     emake -C "${builddir}" all || die
183     done
184     }
185    
186     src_install() {
187     local b
188     for b in 64 32 ; do
189     local builddir="${WORKDIR}/wine${b}"
190     [[ -d ${builddir} ]] || continue
191     emake -C "${builddir}" install DESTDIR="${D}" || die
192     done
193     dodoc ANNOUNCE AUTHORS README
194     if use gecko ; then
195     insinto /usr/share/wine/gecko
196     doins "${DISTDIR}"/wine_gecko-${GV}.cab || die
197     fi
198     if ! use perl ; then
199     rm "${D}"/usr/bin/{wine{dump,maker},function_grep.pl} "${D}"/usr/share/man/man1/wine{dump,maker}.1 || die
200     fi
201     }
202    
203     pkg_postinst() {
204     paxctl -psmr "${ROOT}"/usr/bin/wine{,-preloader} 2>/dev/null #255055
205     }

  ViewVC Help
Powered by ViewVC 1.1.20