/[gentoo-x86]/app-emulation/wine/wine-1.5.7.ebuild
Gentoo

Contents of /app-emulation/wine/wine-1.5.7.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.1 - (show annotations) (download)
Sun Jun 24 23:23:11 2012 UTC (2 years, 6 months ago) by tetromino
Branch: MAIN
Bump, see http://www.winehq.org/announce/1.5.7 and http://www.winehq.org/announce/1.4.1 for the announcements. Enable optional native pulseaudio support for 1.5.7 (bug #421365, thanks to Lee Trager). Fix emul-linux-x86-soundlibs dependency (bug #423093, thanks to Pacho Ramos).

(Portage version: 2.2.0_alpha112/cvs/Linux x86_64)

1 # Copyright 1999-2012 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/app-emulation/wine/wine-1.5.6.ebuild,v 1.1 2012/06/10 03:24:21 tetromino Exp $
4
5 EAPI="4"
6
7 inherit autotools eutils flag-o-matic multilib pax-utils
8
9 if [[ ${PV} == "9999" ]] ; then
10 EGIT_REPO_URI="git://source.winehq.org/git/wine.git"
11 inherit git-2
12 SRC_URI=""
13 #KEYWORDS=""
14 else
15 MY_P="${PN}-${PV/_/-}"
16 SRC_URI="mirror://sourceforge/${PN}/Source/${MY_P}.tar.bz2"
17 KEYWORDS="-* ~amd64 ~x86 ~x86-fbsd"
18 S=${WORKDIR}/${MY_P}
19 fi
20
21 GV="1.6"
22 MV="0.0.4"
23 PULSE_PATCH="winepulse-2012.06.15.patch"
24 DESCRIPTION="free implementation of Windows(tm) on Unix"
25 HOMEPAGE="http://www.winehq.org/"
26 SRC_URI="${SRC_URI}
27 gecko? (
28 mirror://sourceforge/${PN}/Wine%20Gecko/${GV}/wine_gecko-${GV}-x86.msi
29 win64? ( mirror://sourceforge/${PN}/Wine%20Gecko/${GV}/wine_gecko-${GV}-x86_64.msi )
30 )
31 mono? ( mirror://sourceforge/${PN}/Wine%20Mono/${MV}/wine-mono-${MV}.msi )
32 http://source.winehq.org/patches/data/87234 -> ${PULSE_PATCH}"
33
34 LICENSE="LGPL-2.1"
35 SLOT="0"
36 IUSE="alsa capi cups custom-cflags elibc_glibc fontconfig +gecko gnutls gphoto2 gsm gstreamer hardened jpeg lcms ldap +mono mp3 ncurses nls odbc openal opencl +opengl +oss +perl png pulseaudio samba scanner selinux ssl test +threads +truetype udisks v4l +win32 +win64 +X xcomposite xinerama xml"
37 REQUIRED_USE="elibc_glibc? ( threads )
38 mono? ( || ( win32 !win64 ) )" #286560
39 RESTRICT="test" #72375
40
41 MLIB_DEPS="amd64? (
42 truetype? ( >=app-emulation/emul-linux-x86-xlibs-2.1 )
43 X? (
44 >=app-emulation/emul-linux-x86-xlibs-2.1
45 >=app-emulation/emul-linux-x86-soundlibs-2.1[pulseaudio(+)?]
46 )
47 mp3? ( app-emulation/emul-linux-x86-soundlibs )
48 odbc? ( app-emulation/emul-linux-x86-db )
49 openal? ( app-emulation/emul-linux-x86-sdl )
50 opengl? ( app-emulation/emul-linux-x86-opengl )
51 scanner? ( app-emulation/emul-linux-x86-medialibs )
52 v4l? ( app-emulation/emul-linux-x86-medialibs )
53 app-emulation/emul-linux-x86-baselibs
54 >=sys-kernel/linux-headers-2.6
55 )"
56 RDEPEND="truetype? ( >=media-libs/freetype-2.0.0 media-fonts/corefonts )
57 perl? ( dev-lang/perl dev-perl/XML-Simple )
58 capi? ( net-dialup/capi4k-utils )
59 ncurses? ( >=sys-libs/ncurses-5.2 )
60 fontconfig? ( media-libs/fontconfig )
61 gphoto2? ( media-libs/libgphoto2 )
62 openal? ( media-libs/openal )
63 udisks? (
64 sys-apps/dbus
65 sys-fs/udisks:2
66 )
67 gnutls? ( net-libs/gnutls )
68 gstreamer? ( media-libs/gstreamer media-libs/gst-plugins-base )
69 X? (
70 x11-libs/libXcursor
71 x11-libs/libXrandr
72 x11-libs/libXi
73 x11-libs/libXmu
74 x11-libs/libXxf86vm
75 x11-apps/xmessage
76 )
77 xinerama? ( x11-libs/libXinerama )
78 alsa? ( media-libs/alsa-lib )
79 cups? ( net-print/cups )
80 opencl? ( virtual/opencl )
81 opengl? ( virtual/opengl )
82 gsm? ( media-sound/gsm )
83 jpeg? ( virtual/jpeg )
84 ldap? ( net-nds/openldap )
85 lcms? ( =media-libs/lcms-1* )
86 mp3? ( >=media-sound/mpg123-1.5.0 )
87 nls? ( sys-devel/gettext )
88 odbc? ( dev-db/unixODBC )
89 pulseaudio? ( media-sound/pulseaudio )
90 samba? ( >=net-fs/samba-3.0.25 )
91 selinux? ( sec-policy/selinux-wine )
92 xml? ( dev-libs/libxml2 dev-libs/libxslt )
93 scanner? ( media-gfx/sane-backends )
94 ssl? ( dev-libs/openssl )
95 png? ( media-libs/libpng )
96 v4l? ( media-libs/libv4l )
97 !win64? ( ${MLIB_DEPS} )
98 win32? ( ${MLIB_DEPS} )
99 xcomposite? ( x11-libs/libXcomposite )"
100 DEPEND="${RDEPEND}
101 X? (
102 x11-proto/inputproto
103 x11-proto/xextproto
104 x11-proto/xf86vidmodeproto
105 )
106 xinerama? ( x11-proto/xineramaproto )
107 !hardened? ( sys-devel/prelink )
108 virtual/pkgconfig
109 virtual/yacc
110 sys-devel/flex"
111
112 src_unpack() {
113 if use win64 ; then
114 [[ $(( $(gcc-major-version) * 100 + $(gcc-minor-version) )) -lt 404 ]] \
115 && die "you need gcc-4.4+ to build 64bit wine"
116 fi
117
118 if use win32 && use opencl; then
119 [[ x$(eselect opencl show) = "xintel" ]] &&
120 die "Cannot build wine[opencl,win32]: intel-ocl-sdk is 64-bit only" # 403947
121 fi
122
123 if [[ ${PV} == "9999" ]] ; then
124 git-2_src_unpack
125 else
126 unpack ${MY_P}.tar.bz2
127 fi
128 }
129
130 src_prepare() {
131 epatch "${FILESDIR}"/${PN}-1.1.15-winegcc.patch #260726
132 epatch "${FILESDIR}"/${PN}-1.4_rc2-multilib-portage.patch #395615
133 epatch "${DISTDIR}/${PULSE_PATCH}" #421365
134 epatch_user #282735
135 eautoreconf
136 sed -i '/^UPDATE_DESKTOP_DATABASE/s:=.*:=true:' tools/Makefile.in || die
137 sed -i '/^MimeType/d' tools/wine.desktop || die #117785
138 }
139
140 do_configure() {
141 local builddir="${WORKDIR}/wine$1"
142 mkdir -p "${builddir}"
143 pushd "${builddir}" >/dev/null
144
145 ECONF_SOURCE=${S} \
146 econf \
147 --sysconfdir=/etc/wine \
148 $(use_with alsa) \
149 $(use_with capi) \
150 $(use_with lcms cms) \
151 $(use_with cups) \
152 $(use_with ncurses curses) \
153 $(use_with udisks dbus) \
154 $(use_with fontconfig) \
155 $(use_with gnutls) \
156 $(use_with gphoto2 gphoto) \
157 $(use_with gsm) \
158 $(use_with gstreamer) \
159 --without-hal \
160 $(use_with jpeg) \
161 $(use_with ldap) \
162 $(use_with mp3 mpg123) \
163 $(use_with nls gettext) \
164 $(use_with openal) \
165 $(use_with opencl) \
166 $(use_with opengl) \
167 $(use_with ssl openssl) \
168 $(use_with oss) \
169 $(use_with png) \
170 $(use_with threads pthread) \
171 $(use_with pulseaudio pulse) \
172 $(use_with scanner sane) \
173 $(use_enable test tests) \
174 $(use_with truetype freetype) \
175 $(use_with v4l) \
176 $(use_with X x) \
177 $(use_with xcomposite) \
178 $(use_with xinerama) \
179 $(use_with xml) \
180 $(use_with xml xslt) \
181 $2
182
183 emake -j1 depend
184
185 popd >/dev/null
186 }
187
188 src_configure() {
189 export LDCONFIG=/bin/true
190 use custom-cflags || strip-flags
191
192 if use win64 ; then
193 do_configure 64 --enable-win64
194 use win32 && ABI=x86 do_configure 32 --with-wine64=../wine64
195 else
196 ABI=x86 do_configure 32 --disable-win64
197 fi
198 }
199
200 src_compile() {
201 local b
202 for b in 64 32 ; do
203 local builddir="${WORKDIR}/wine${b}"
204 [[ -d ${builddir} ]] || continue
205 emake -C "${builddir}" all
206 done
207 }
208
209 src_install() {
210 local b
211 for b in 64 32 ; do
212 local builddir="${WORKDIR}/wine${b}"
213 [[ -d ${builddir} ]] || continue
214 emake -C "${builddir}" install DESTDIR="${D}"
215 done
216 dodoc ANNOUNCE AUTHORS README
217 if use gecko ; then
218 insinto /usr/share/wine/gecko
219 doins "${DISTDIR}"/wine_gecko-${GV}-x86.msi
220 use win64 && doins "${DISTDIR}"/wine_gecko-${GV}-x86_64.msi
221 fi
222 if use mono ; then
223 insinto /usr/share/wine/mono
224 doins "${DISTDIR}"/wine-mono-${MV}.msi
225 fi
226 if ! use perl ; then
227 rm "${D}"usr/bin/{wine{dump,maker},function_grep.pl} "${D}"usr/share/man/man1/wine{dump,maker}.1 || die
228 fi
229
230 if use win32 || ! use win64; then
231 pax-mark psmr "${D}"usr/bin/wine{,-preloader} #255055
232 fi
233 use win64 && pax-mark psmr "${D}"usr/bin/wine64{,-preloader}
234
235 if use win64 && ! use win32; then
236 dosym /usr/bin/wine{64,} # 404331
237 dosym /usr/bin/wine{64,}-preloader
238 fi
239 }

  ViewVC Help
Powered by ViewVC 1.1.20