/[gentoo-x86]/app-forensics/ovaldi/ovaldi-5.9.1.ebuild
Gentoo

Contents of /app-forensics/ovaldi/ovaldi-5.9.1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.1 - (show annotations) (download)
Thu Jun 16 09:30:07 2011 UTC (3 years, 2 months ago) by hwoarang
Branch: MAIN
Initial commit. Moved from sunrise. Thanks to Anton Bolshakov for the original ebuild and LABBE Corentin for proxy-maintaining it. Bug #225065

(Portage version: 2.2.0_alpha41/cvs/Linux x86_64)

1 # Copyright 1999-2011 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: $
4
5 EAPI=3
6
7 inherit eutils
8
9 DESCRIPTION="Free implementation of OVAL"
10 HOMEPAGE="http://oval.mitre.org/language/interpreter.html"
11 SRC_URI="mirror://sourceforge/${PN}/${P}-src.tar.bz2"
12
13 LICENSE="BSD"
14 SLOT="0"
15 KEYWORDS="~amd64 ~x86"
16 IUSE="ldap rpm"
17
18 DEPEND="rpm? ( app-arch/rpm )
19 dev-libs/libgcrypt
20 dev-libs/libpcre
21 dev-libs/xalan-c
22 dev-libs/xerces-c
23 ldap? ( net-nds/openldap )"
24 RDEPEND="${DEPEND}"
25
26 S="${WORKDIR}/${P}-src"
27
28 src_prepare() {
29 epatch "${FILESDIR}"/${P}-xerces3.patch
30 epatch "${FILESDIR}"/${P}-strnicmp.patch
31 if ! use ldap ; then
32 einfo "Disabling LDAP probes"
33 epatch "${FILESDIR}"/${P}-disable-ldap-probes.patch
34 rm src/probes/independent/LDAPProbe.{cpp,h} || die
35 fi
36
37 # rpm probes support is build dependant only on the presence of the rpm binary
38 if use rpm ; then
39 #Same problems as bug 274679, so i do a local copy of the header and patch it
40 cp /usr/include/rpm/rpmdb.h src/probes/linux/ || die
41 epatch "${FILESDIR}"/use_local_rpmdb.patch
42 epatch "${FILESDIR}"/rpmdb.patch
43 else
44 einfo "Disabling rpm probes"
45 sed -i 's/^PACKAGE_RPM/#PACKAGE_RPM/' project/linux/Makefile || die
46 fi
47 # same thing for dpkg, but package dpkg is not sufficient, needs app-arch/apt-pkg that is not on tree
48 einfo "Disabling dpkg probes"
49 sed -i 's/^PACKAGE_DPKG/#PACKAGE_DPKG/' project/linux/Makefile || die
50 }
51
52 src_compile () {
53 emake -C project/linux || die
54 }
55
56 src_install () {
57 # no make install in Makefile
58 dosbin project/linux/Release/ovaldi project/linux/ovaldi.sh || die
59 dodir /var/log/${PN} || die
60 insinto /usr/share/${PN}
61 doins xml/* || die
62 dodoc docs/{README.txt,version.txt} || die
63 doman docs/ovaldi.1 || die
64 }

  ViewVC Help
Powered by ViewVC 1.1.20