/[gentoo-x86]/app-misc/mc/mc-4.8.2-r1.ebuild
Gentoo

Contents of /app-misc/mc/mc-4.8.2-r1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.3 - (show annotations) (download)
Tue Mar 27 16:54:22 2012 UTC (2 years, 5 months ago) by slyfox
Branch: MAIN
CVS Tags: HEAD
Changes since 1.2: +1 -1 lines
FILE REMOVED
Fix bug #409365 by Marcin Mirosław (broken permissions when attempt to save file on top of directory). Patch picked from upstream.

(Portage version: 2.2.0_alpha91/cvs/Linux x86_64)

1 # Copyright 1999-2012 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/app-misc/mc/mc-4.8.2-r1.ebuild,v 1.2 2012/03/22 14:37:17 wired Exp $
4
5 EAPI=4
6
7 inherit flag-o-matic
8
9 MY_P=${P/_/-}
10
11 DESCRIPTION="GNU Midnight Commander is a text based file manager"
12 HOMEPAGE="http://www.midnight-commander.org"
13 SRC_URI="http://www.midnight-commander.org/downloads/${MY_P}.tar.xz"
14
15 LICENSE="GPL-3"
16 SLOT="0"
17 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~x86-interix ~amd64-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x86-solaris"
18 IUSE="+edit gpm mclib nls samba +slang test X +xdg"
19
20 RDEPEND=">=dev-libs/glib-2.8:2
21 gpm? ( sys-libs/gpm )
22 kernel_linux? ( sys-fs/e2fsprogs )
23 samba? ( net-fs/samba )
24 slang? ( >=sys-libs/slang-2 )
25 !slang? ( sys-libs/ncurses )
26 X? ( x11-libs/libX11
27 x11-libs/libICE
28 x11-libs/libXau
29 x11-libs/libXdmcp
30 x11-libs/libSM )"
31 DEPEND="${RDEPEND}
32 app-arch/xz-utils
33 dev-util/pkgconfig
34 nls? ( sys-devel/gettext )
35 test? ( dev-libs/check )
36 "
37
38 S=${WORKDIR}/${MY_P}
39
40 src_prepare() {
41 cp "${FILESDIR}"/${P}-missing-do_panel_cd_stub_env.c \
42 tests/src/filemanager/do_panel_cd_stub_env.c || die
43
44 # bug 409107
45 epatch "${FILESDIR}"/"${P}"-mcedit-without-file-param-fix.patch
46 }
47
48 src_configure() {
49 local myscreen=ncurses
50 use slang && myscreen=slang
51 [[ ${CHOST} == *-solaris* ]] && append-ldflags "-lnsl -lsocket"
52
53 local homedir=".mc"
54 use xdg && homedir="XDG"
55
56 econf \
57 --disable-dependency-tracking \
58 $(use_enable nls) \
59 --enable-vfs \
60 $(use_enable kernel_linux vfs-undelfs) \
61 --enable-charset \
62 $(use_with X x) \
63 $(use_enable samba vfs-smb) \
64 $(use_with gpm gpm-mouse) \
65 --with-screen=${myscreen} \
66 $(use_with edit) \
67 $(use_enable mclib) \
68 $(use_enable test tests) \
69 --with-homedir=${homedir}
70 }
71
72 src_install() {
73 emake DESTDIR="${D}" install
74 dodoc AUTHORS README NEWS
75
76 # fix bug #334383
77 if use kernel_linux && [[ ${EUID} == 0 ]] ; then
78 fowners root:tty /usr/libexec/mc/cons.saver
79 fperms g+s /usr/libexec/mc/cons.saver
80 fi
81 }
82
83 pkg_postinst() {
84 elog "To enable exiting to latest working directory,"
85 elog "put this into your ~/.bashrc:"
86 elog ". ${EPREFIX}/usr/libexec/mc/mc.sh"
87 }

  ViewVC Help
Powered by ViewVC 1.1.20