/[gentoo-x86]/app-text/fbreader/fbreader-0.99.2.ebuild
Gentoo

Contents of /app-text/fbreader/fbreader-0.99.2.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.5 - (show annotations) (download)
Sat Jan 19 06:13:47 2013 UTC (21 months ago) by grozin
Branch: MAIN
Changes since 1.4: +1 -1 lines
Added 0.99.2 back, see bug #452636

(Portage version: 2.2.0_alpha153/cvs/Linux i686, unsigned Manifest commit)

1 # Copyright 1999-2013 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/app-text/fbreader/fbreader-0.99.2.ebuild,v 1.3 2012/12/02 10:40:37 maekke Exp $
4
5 EAPI=4
6
7 inherit eutils multilib
8
9 DESCRIPTION="E-Book Reader. Supports many e-book formats."
10 HOMEPAGE="http://www.fbreader.org/"
11 SRC_URI="http://www.fbreader.org/files/desktop/${PN}-sources-${PV}.tgz"
12
13 LICENSE="GPL-2"
14 SLOT="0"
15 KEYWORDS="~amd64 ~arm ~ppc ~x86"
16 IUSE="debug"
17
18 RDEPEND="
19 app-arch/bzip2
20 dev-libs/expat
21 dev-libs/liblinebreak
22 dev-libs/fribidi
23 dev-db/sqlite
24 net-misc/curl
25 sys-libs/zlib
26 x11-libs/qt-core:4
27 x11-libs/qt-gui:4
28 "
29 DEPEND="${RDEPEND}
30 virtual/pkgconfig
31 "
32
33 src_prepare() {
34 # Still use linebreak instead of new unibreak
35 sed -e "s:-lunibreak:-llinebreak:" \
36 -i makefiles/config.mk zlibrary/text/Makefile || die "fixing libunibreak failed"
37
38 # Let portage decide about the compiler
39 sed -e "/^CC = /d" \
40 -i makefiles/arch/desktop.mk || die "removing CC line failed"
41
42 # Respect *FLAGS
43 sed -e "s/^CFLAGS = -pipe/CFLAGS +=/" \
44 -i makefiles/arch/desktop.mk || die "CFLAGS sed failed"
45 sed -e "/^ CFLAGS +=/ d" \
46 -i makefiles/config.mk || die "CFLAGS sed failed"
47 sed -e "/^ LDFLAGS += -s$/ d" \
48 -i makefiles/config.mk || die "sed failed"
49 sed -e "/^LDFLAGS =$/ d" \
50 -i makefiles/arch/desktop.mk || die "sed failed"
51
52 echo "TARGET_ARCH = desktop" > makefiles/target.mk
53 echo "LIBDIR = /usr/$(get_libdir)" >> makefiles/target.mk
54
55 echo "UI_TYPE = qt4" >> makefiles/target.mk
56 sed -e 's:MOC = moc-qt4:MOC = /usr/bin/moc:' \
57 -i makefiles/arch/desktop.mk || die "updating desktop.mk failed"
58
59 if use debug; then
60 echo "TARGET_STATUS = debug" >> makefiles/target.mk
61 else
62 echo "TARGET_STATUS = release" >> makefiles/target.mk
63 fi
64 }
65
66 src_install() {
67 default
68 dosym /usr/bin/FBReader /usr/bin/fbreader
69 }

  ViewVC Help
Powered by ViewVC 1.1.20