/[gentoo-x86]/app-text/fbreader/fbreader-0.99.4.ebuild
Gentoo

Contents of /app-text/fbreader/fbreader-0.99.4.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.2 - (show annotations) (download)
Sat Jan 12 15:52:50 2013 UTC (17 months, 4 weeks ago) by scarabeus
Branch: MAIN
Changes since 1.1: +4 -4 lines
Stabilise latest on amd64 and x86. Drop older.

(Portage version: 2.2.0_alpha151/cvs/Linux x86_64, signed Manifest commit with key 8EEE3BE8)

1 # Copyright 1999-2013 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/app-text/fbreader/fbreader-0.99.4.ebuild,v 1.1 2013/01/12 15:50:42 scarabeus Exp $
4
5 EAPI=5
6
7 inherit eutils multilib
8
9 DESCRIPTION="E-Book Reader. Supports many e-book formats."
10 HOMEPAGE="http://www.fbreader.org/"
11 SRC_URI="http://www.fbreader.org/files/desktop/${PN}-sources-${PV}.tgz"
12
13 LICENSE="GPL-2"
14 SLOT="0"
15 KEYWORDS="amd64 ~arm ~ppc x86"
16 IUSE="debug"
17
18 RDEPEND="
19 app-arch/bzip2
20 dev-libs/expat
21 dev-libs/liblinebreak
22 dev-libs/fribidi
23 dev-db/sqlite
24 net-misc/curl
25 sys-libs/zlib
26 x11-libs/qt-core:4
27 x11-libs/qt-gui:4
28 "
29 DEPEND="${RDEPEND}
30 virtual/pkgconfig
31 "
32
33 src_prepare() {
34 # Still use linebreak instead of new unibreak
35 sed -e "s:-lunibreak:-llinebreak:" \
36 -i makefiles/config.mk zlibrary/text/Makefile || die "fixing libunibreak failed"
37
38 # Let portage decide about the compiler
39 sed -e "/^CC = /d" \
40 -i makefiles/arch/desktop.mk || die "removing CC line failed"
41
42 # let portage strip the binary
43 sed -e '/@strip/d' \
44 -i fbreader/desktop/Makefile || die
45
46 # Respect *FLAGS
47 sed -e "s/^CFLAGS = -pipe/CFLAGS +=/" \
48 -i makefiles/arch/desktop.mk || die "CFLAGS sed failed"
49 sed -e "/^ CFLAGS +=/ d" \
50 -i makefiles/config.mk || die "CFLAGS sed failed"
51 sed -e "/^ LDFLAGS += -s$/ d" \
52 -i makefiles/config.mk || die "sed failed"
53 sed -e "/^LDFLAGS =$/ d" \
54 -i makefiles/arch/desktop.mk || die "sed failed"
55
56 echo "TARGET_ARCH = desktop" > makefiles/target.mk
57 echo "LIBDIR = /usr/$(get_libdir)" >> makefiles/target.mk
58
59 echo "UI_TYPE = qt4" >> makefiles/target.mk
60 sed -e 's:MOC = moc-qt4:MOC = /usr/bin/moc:' \
61 -i makefiles/arch/desktop.mk || die "updating desktop.mk failed"
62
63 if use debug; then
64 echo "TARGET_STATUS = debug" >> makefiles/target.mk
65 else
66 echo "TARGET_STATUS = release" >> makefiles/target.mk
67 fi
68 }
69
70 src_install() {
71 default
72 dosym /usr/bin/FBReader /usr/bin/fbreader
73 }

  ViewVC Help
Powered by ViewVC 1.1.20