/[gentoo-x86]/app-text/poppler/poppler-0.26.2.ebuild
Gentoo

Contents of /app-text/poppler/poppler-0.26.2.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.2 - (show annotations) (download)
Sun Jul 13 10:39:44 2014 UTC (5 months ago) by johu
Branch: MAIN
Changes since 1.1: +2 -9 lines
Remove workaround on freetype, this is fixed in current stable dev-util/cmake-2.8.12.2, bug #459394.

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0xF3CFD2BD)

1 # Copyright 1999-2014 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/app-text/poppler/poppler-0.26.2.ebuild,v 1.1 2014/06/22 18:57:56 dilfridge Exp $
4
5 EAPI=5
6
7 inherit cmake-utils toolchain-funcs
8
9 if [[ "${PV}" == "9999" ]] ; then
10 inherit git-r3
11 EGIT_REPO_URI="git://git.freedesktop.org/git/${PN}/${PN}"
12 KEYWORDS=""
13 SLOT="0/9999"
14 else
15 SRC_URI="http://poppler.freedesktop.org/${P}.tar.xz"
16 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
17 SLOT="0/46"
18 fi
19
20 DESCRIPTION="PDF rendering library based on the xpdf-3.0 code base"
21 HOMEPAGE="http://poppler.freedesktop.org/"
22
23 LICENSE="GPL-2"
24 IUSE="cairo cjk curl cxx debug doc +introspection +jpeg jpeg2k +lcms png qt4 qt5 tiff +utils"
25
26 # No test data provided
27 RESTRICT="test"
28
29 COMMON_DEPEND="
30 >=media-libs/fontconfig-2.6.0
31 >=media-libs/freetype-2.3.9
32 sys-libs/zlib
33 cairo? (
34 dev-libs/glib:2
35 >=x11-libs/cairo-1.10.0
36 introspection? ( >=dev-libs/gobject-introspection-1.32.1 )
37 )
38 curl? ( net-misc/curl )
39 jpeg? ( virtual/jpeg:0 )
40 jpeg2k? ( media-libs/openjpeg:0 )
41 lcms? ( media-libs/lcms:2 )
42 png? ( media-libs/libpng:0= )
43 qt4? (
44 dev-qt/qtcore:4
45 dev-qt/qtgui:4
46 )
47 qt5? (
48 dev-qt/qtcore:5
49 dev-qt/qtgui:5
50 dev-qt/qtxml:5
51 )
52 tiff? ( media-libs/tiff:0 )
53 "
54 DEPEND="${COMMON_DEPEND}
55 virtual/pkgconfig
56 "
57 RDEPEND="${COMMON_DEPEND}
58 cjk? ( >=app-text/poppler-data-0.4.4 )
59 "
60
61 DOCS=(AUTHORS NEWS README README-XPDF TODO)
62
63 PATCHES=( "${FILESDIR}/${PN}-0.26.0-qt5-dependencies.patch" )
64
65 src_configure() {
66 local mycmakeargs=(
67 -DBUILD_GTK_TESTS=OFF
68 -DBUILD_QT4_TESTS=OFF
69 -DBUILD_QT5_TESTS=OFF
70 -DBUILD_CPP_TESTS=OFF
71 -DENABLE_SPLASH=ON
72 -DENABLE_ZLIB=ON
73 -DENABLE_XPDF_HEADERS=ON
74 $(cmake-utils_use_enable curl LIBCURL)
75 $(cmake-utils_use_enable cxx CPP)
76 $(cmake-utils_use_enable jpeg2k LIBOPENJPEG)
77 $(cmake-utils_use_enable utils)
78 $(cmake-utils_use_with cairo)
79 $(cmake-utils_use_with introspection GObjectIntrospection)
80 $(cmake-utils_use_with jpeg)
81 $(cmake-utils_use_with png)
82 $(cmake-utils_use_with qt4)
83 $(cmake-utils_use_find_package qt5 Qt5Core)
84 $(cmake-utils_use_with tiff)
85 )
86 if use lcms; then
87 mycmakeargs+=(-DENABLE_CMS=lcms2)
88 else
89 mycmakeargs+=(-DENABLE_CMS=)
90 fi
91
92 cmake-utils_src_configure
93 }
94
95 src_install() {
96 cmake-utils_src_install
97
98 if use cairo && use doc; then
99 # For now install gtk-doc there
100 insinto /usr/share/gtk-doc/html/poppler
101 doins -r "${S}"/glib/reference/html/*
102 fi
103 }

  ViewVC Help
Powered by ViewVC 1.1.20