/[gentoo-x86]/dev-lang/jimtcl/jimtcl-9999.ebuild
Gentoo

Contents of /dev-lang/jimtcl/jimtcl-9999.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.9 - (show annotations) (download)
Thu Aug 14 01:45:51 2014 UTC (4 months ago) by vapier
Branch: MAIN
CVS Tags: HEAD
Changes since 1.8: +46 -18 lines
Rewrite ebuild to fix many errors & merge the live/release versions.

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key D2E96200)

1 # Copyright 1999-2014 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/dev-lang/jimtcl/jimtcl-9999.ebuild,v 1.8 2013/09/17 19:16:49 hwoarang Exp $
4
5 EAPI="5"
6
7 inherit multiprocessing eutils
8
9 if [[ ${PV} == "9999" ]] ; then
10 EGIT_REPO_URI="http://repo.or.cz/r/jimtcl.git"
11 inherit git-2
12 else
13 inherit vcs-snapshot
14 SRC_URI="https://github.com/msteveb/jimtcl/zipball/${PV} -> ${P}.zip"
15 KEYWORDS="~amd64 ~arm ~arm64 ~m68k ~mips ~s390 ~sh ~x86"
16 fi
17
18 DESCRIPTION="Small footprint implementation of Tcl programming language"
19 HOMEPAGE="http://jim.tcl.tk/"
20
21 LICENSE="LGPL-2"
22 SLOT="0"
23 IUSE="doc static-libs"
24
25 RDEPEND=""
26 DEPEND="doc? ( app-text/asciidoc )
27 app-arch/unzip"
28
29 src_unpack() {
30 if [[ ${PV} == "9999" ]] ; then
31 git-2_src_unpack
32 else
33 default
34 cd "${WORKDIR}"/msteveb-jimtcl-*
35 S=${PWD}
36 fi
37 }
38
39 src_prepare() {
40 epatch "${FILESDIR}"/${PN}-0.75-bootstrap.patch
41 }
42
43 src_configure() {
44 multijob_init
45 CCACHE=None multijob_child_init econf --with-jim-shared
46 if use static-libs ; then
47 # The build does not support doing both simultaneously.
48 mkdir static-libs
49 cd static-libs
50 CCACHE=None ECONF_SOURCE=${S} multijob_child_init econf
51 fi
52 multijob_finish
53 }
54
55 src_compile() {
56 # Must build static-libs first.
57 use static-libs && emake -C static-libs libjim.a
58 emake all
59 use doc && emake docs
60 }
61
62 src_install() {
63 dobin jimsh
64 use static-libs && dolib.a static-libs/libjim.a
65 ln -sf libjim.so.* libjim.so
66 dolib.so libjim.so*
67 insinto /usr/include
68 doins jim.h jimautoconf.h jim-subcmd.h jim-signal.h \
69 jim-win32compat.h jim-eventloop.h jim-config.h
70 dodoc AUTHORS README TODO
71 use doc && dohtml Tcl.html
72 }

  ViewVC Help
Powered by ViewVC 1.1.20