/[gentoo-x86]/dev-lang/v8/v8-2.5.2.ebuild
Gentoo

Contents of /dev-lang/v8/v8-2.5.2.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.2 - (show annotations) (download)
Fri Dec 10 17:08:38 2010 UTC (3 years, 9 months ago) by phajdan.jr
Branch: MAIN
CVS Tags: HEAD
Changes since 1.1: +1 -1 lines
FILE REMOVED
Version bump. Remove old.

(Portage version: 2.1.9.24/cvs/Linux i686)

1 # Copyright 1999-2010 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/dev-lang/v8/v8-2.5.2.ebuild,v 1.1 2010/11/03 17:54:27 phajdan.jr Exp $
4
5 EAPI="2"
6
7 inherit eutils flag-o-matic multilib scons-utils subversion toolchain-funcs
8
9 ESVN_REPO_URI="http://v8.googlecode.com/svn/tags/${PV}"
10
11 DESCRIPTION="Google's open source JavaScript engine"
12 HOMEPAGE="http://code.google.com/p/v8"
13 LICENSE="BSD"
14
15 SLOT="0"
16 KEYWORDS="~amd64 ~x86"
17 IUSE="readline"
18
19 RDEPEND="readline? ( >=sys-libs/readline-6.1 )"
20 DEPEND="${RDEPEND}"
21
22 EXTRA_ESCONS="library=shared soname=on"
23
24 pkg_setup() {
25 tc-export AR CC CXX RANLIB
26 }
27
28 src_prepare() {
29 # Stop -Werror from breaking the build.
30 epatch "${FILESDIR}"/${PN}-no-werror-r0.patch
31
32 # Respect the user's CFLAGS, including the optimization level.
33 epatch "${FILESDIR}"/${PN}-no-O3-r0.patch
34
35 # Remove a test that is known to fail:
36 # http://groups.google.com/group/v8-users/browse_thread/thread/b8a3f42b5aa18d06
37 rm test/mjsunit/debug-script.js || die
38 }
39
40 src_configure() {
41 # GCC issues multiple warnings about strict-aliasing issues in v8 code.
42 append-flags -fno-strict-aliasing
43 }
44
45 src_compile() {
46 local myconf=""
47
48 # Use target arch detection logic from bug #296917.
49 local myarch="$ABI"
50 [[ $myarch = "" ]] && myarch="$ARCH"
51
52 if [[ $myarch = amd64 ]] ; then
53 myconf+=" arch=x64"
54 elif [[ $myarch = x86 ]] ; then
55 myconf+=" arch=ia32"
56 else
57 die "Failed to determine target arch, got '$myarch'."
58 fi
59
60 escons $(use_scons readline console readline dumb) ${myconf} . || die
61 }
62
63 src_install() {
64 insinto /usr
65 doins -r include || die
66
67 dobin d8 || die
68
69 dolib libv8-${PV}.so || die
70 dosym libv8-${PV}.so /usr/$(get_libdir)/libv8.so || die
71
72 dodoc AUTHORS ChangeLog || die
73 }
74
75 src_test() {
76 tools/test.py --no-build -p dots --shell d8 || die
77 }

  ViewVC Help
Powered by ViewVC 1.1.20