/[gentoo-x86]/dev-lang/v8/v8-3.17.15.3.ebuild
Gentoo

Contents of /dev-lang/v8/v8-3.17.15.3.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.5 - (show annotations) (download)
Fri May 24 18:28:14 2013 UTC (16 months, 1 week ago) by ago
Branch: MAIN
CVS Tags: HEAD
Changes since 1.4: +1 -1 lines
FILE REMOVED
Remove old

(Portage version: 2.1.12.1/cvs/Linux x86_64, signed Manifest commit with key 7194459F)

1 # Copyright 1999-2013 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/dev-lang/v8/v8-3.17.15.3.ebuild,v 1.4 2013/04/10 19:44:03 phajdan.jr Exp $
4
5 EAPI="5"
6 PYTHON_COMPAT=( python2_{6,7} )
7
8 inherit chromium eutils multilib multiprocessing pax-utils python-any-r1 \
9 toolchain-funcs versionator
10
11 DESCRIPTION="Google's open source JavaScript engine"
12 HOMEPAGE="http://code.google.com/p/v8"
13 SRC_URI="https://commondatastorage.googleapis.com/chromium-browser-official/${P}.tar.bz2"
14 LICENSE="BSD"
15
16 soname_version="${PV}"
17 SLOT="0/${soname_version}"
18 KEYWORDS="~amd64 ~arm ~x86 ~x86-fbsd ~x64-macos ~x86-macos"
19 IUSE="readline"
20
21 RDEPEND="readline? ( sys-libs/readline:0 )"
22 DEPEND="${PYTHON_DEPS}
23 ${RDEPEND}"
24
25 src_configure() {
26 tc-export AR CC CXX RANLIB
27 export LINK=${CXX}
28
29 local myconf=""
30
31 # Always build v8 as a shared library with proper SONAME.
32 myconf+=" -Dcomponent=shared_library -Dsoname_version=${soname_version}"
33
34 # Use target arch detection logic from bug #354601.
35 case ${CHOST} in
36 i?86-*) myconf+=" -Dv8_target_arch=ia32" ;;
37 x86_64-*)
38 if [[ $ABI = x86 ]] ; then
39 myconf+=" -Dv8_target_arch=ia32"
40 else
41 myconf+=" -Dv8_target_arch=x64"
42 fi ;;
43 arm*-hardfloat-*)
44 myconf+=" -Dv8_target_arch=arm -Dv8_use_arm_eabi_hardfloat=true" ;;
45 arm*-*) myconf+=" -Dv8_target_arch=arm" ;;
46 *) die "Unrecognized CHOST: ${CHOST}"
47 esac
48
49 myconf+=" $(gyp_use readline console readline dumb)"
50
51 # Make sure that -Werror doesn't get added to CFLAGS by the build system.
52 # Depending on GCC version the warnings are different and we don't
53 # want the build to fail because of that.
54 myconf+=" -Dwerror="
55
56 EGYP_CHROMIUM_COMMAND=build/gyp_v8 egyp_chromium ${myconf} || die
57 }
58
59 src_compile() {
60 local makeargs=(
61 -C out
62 builddir="${S}/out/Release"
63 V=1
64 BUILDTYPE=Release
65 )
66
67 # Build mksnapshot so we can pax-mark it.
68 emake "${makeargs[@]}" mksnapshot
69 pax-mark m out/Release/mksnapshot
70
71 # Build everything else.
72 emake "${makeargs[@]}"
73 pax-mark m out/Release/{cctest,d8}
74 }
75
76 src_test() {
77 LD_LIBRARY_PATH=out/Release/lib.target tools/run-tests.py \
78 -j$(makeopts_jobs) \
79 --no-presubmit \
80 --outdir=out \
81 --buildbot \
82 --arch=native \
83 --mode=Release \
84 --progress=dots || die
85 }
86
87 src_install() {
88 insinto /usr
89 doins -r include
90
91 if [[ ${CHOST} == *-darwin* ]] ; then
92 # buildsystem is too horrific to get this built correctly
93 mkdir -p out/Release/lib.target || die
94 mv out/Release/libv8.so.${soname_version} \
95 out/Release/lib.target/libv8$(get_libname ${soname_version}) || die
96 install_name_tool \
97 -id "${EPREFIX}"/usr/$(get_libdir)/libv8$(get_libname) \
98 out/Release/lib.target/libv8$(get_libname ${soname_version}) \
99 || die
100 install_name_tool \
101 -change \
102 /usr/local/lib/libv8.so.${soname_version} \
103 "${EPREFIX}"/usr/$(get_libdir)/libv8$(get_libname) \
104 out/Release/d8 || die
105 fi
106
107 dobin out/Release/d8
108 pax-mark m "${ED}usr/bin/d8"
109
110 dolib out/Release/lib.target/libv8$(get_libname ${soname_version})
111 dosym libv8$(get_libname ${soname_version}) /usr/$(get_libdir)/libv8$(get_libname)
112
113 dodoc AUTHORS ChangeLog || die
114 }
115
116 # TODO: remove functions below after they are removed from chromium.eclass'
117 # EXPORT_FUNCTIONS .
118
119 pkg_preinst() {
120 return
121 }
122
123 pkg_postinst() {
124 return
125 }
126
127 pkg_postrm() {
128 return
129 }

  ViewVC Help
Powered by ViewVC 1.1.20