/[gentoo-x86]/dev-lang/v8/v8-3.17.5.ebuild
Gentoo

Contents of /dev-lang/v8/v8-3.17.5.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.3 - (show annotations) (download)
Wed Mar 13 22:01:41 2013 UTC (18 months, 1 week ago) by phajdan.jr
Branch: MAIN
CVS Tags: HEAD
Changes since 1.2: +1 -1 lines
FILE REMOVED
Dev channel bump. Remove old.

(Portage version: 2.1.11.52/cvs/Linux i686, signed Manifest commit with key 30427902)

1 # Copyright 1999-2013 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/dev-lang/v8/v8-3.17.5.ebuild,v 1.2 2013/03/05 01:11:50 phajdan.jr Exp $
4
5 EAPI="5"
6 PYTHON_COMPAT=( python2_{6,7} )
7
8 inherit eutils multilib pax-utils python-any-r1 toolchain-funcs versionator
9
10 DESCRIPTION="Google's open source JavaScript engine"
11 HOMEPAGE="http://code.google.com/p/v8"
12 SRC_URI="http://commondatastorage.googleapis.com/chromium-browser-official/${P}.tar.bz2"
13 LICENSE="BSD"
14
15 soname_version="$(get_version_component_range 1-3)"
16 SLOT="0/${soname_version}"
17 KEYWORDS="~amd64 ~arm ~x86 ~x86-fbsd ~x64-macos ~x86-macos"
18 IUSE="readline"
19
20 RDEPEND="readline? ( sys-libs/readline:0 )"
21 DEPEND="${PYTHON_DEPS}
22 ${RDEPEND}"
23
24 src_configure() {
25 tc-export AR CC CXX RANLIB
26 export LINK=${CXX}
27
28 local hardfp=off
29
30 # Use target arch detection logic from bug #354601.
31 case ${CHOST} in
32 i?86-*) myarch=ia32 ;;
33 x86_64-*)
34 if [[ $ABI = x86 ]] ; then
35 myarch=ia32
36 else
37 myarch=x64
38 fi ;;
39 arm*-hardfloat-*)
40 hardfp=on
41 myarch=arm ;;
42 arm*-*) myarch=arm ;;
43 *) die "Unrecognized CHOST: ${CHOST}"
44 esac
45 mytarget=${myarch}.release
46
47 if use readline; then
48 console=readline
49 else
50 console=dumb
51 fi
52
53 # Generate the real Makefile.
54 emake V=1 \
55 library=shared \
56 werror=no \
57 soname_version=${soname_version} \
58 snapshot=on \
59 hardfp=${hardfp} \
60 console=${console} \
61 out/Makefile.${myarch} || die
62 }
63
64 src_compile() {
65 local makeargs=(
66 -C out
67 -f Makefile.${myarch}
68 V=1
69 BUILDTYPE=Release
70 builddir="${S}/out/${mytarget}"
71 )
72
73 # Build mksnapshot so we can pax-mark it.
74 emake "${makeargs[@]}" mksnapshot || die
75 pax-mark m out/${mytarget}/mksnapshot
76
77 # Build everything else.
78 emake "${makeargs[@]}" || die
79 pax-mark m out/${mytarget}/{cctest,d8,shell} || die
80 }
81
82 src_test() {
83 local arg testjobs
84 for arg in ${MAKEOPTS}; do
85 case ${arg} in
86 -j*) testjobs=${arg#-j} ;;
87 --jobs=*) testjobs=${arg#--jobs=} ;;
88 esac
89 done
90
91 tools/test-wrapper-gypbuild.py \
92 -j${testjobs:-1} \
93 --arch-and-mode=${mytarget} \
94 --no-presubmit \
95 --progress=dots || die
96 }
97
98 src_install() {
99 insinto /usr
100 doins -r include || die
101
102 if [[ ${CHOST} == *-darwin* ]] ; then
103 # buildsystem is too horrific to get this built correctly
104 mkdir -p out/${mytarget}/lib.target
105 mv out/${mytarget}/libv8.so.${soname_version} \
106 out/${mytarget}/lib.target/libv8$(get_libname ${soname_version}) || die
107 install_name_tool \
108 -id "${EPREFIX}"/usr/$(get_libdir)/libv8$(get_libname) \
109 out/${mytarget}/lib.target/libv8$(get_libname ${soname_version}) \
110 || die
111 install_name_tool \
112 -change \
113 /usr/local/lib/libv8.so.${soname_version} \
114 "${EPREFIX}"/usr/$(get_libdir)/libv8$(get_libname) \
115 out/${mytarget}/d8 || die
116 fi
117
118 dobin out/${mytarget}/d8 || die
119
120 dolib out/${mytarget}/lib.target/libv8$(get_libname ${soname_version}) || die
121 dosym libv8$(get_libname ${soname_version}) /usr/$(get_libdir)/libv8$(get_libname) || die
122
123 dodoc AUTHORS ChangeLog || die
124 }

  ViewVC Help
Powered by ViewVC 1.1.20