/[gentoo-x86]/dev-libs/gmp/gmp-4.3.2-r1.ebuild
Gentoo

Contents of /dev-libs/gmp/gmp-4.3.2-r1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.1 - (show annotations) (download)
Mon Oct 3 15:36:58 2011 UTC (3 years ago) by vapier
Branch: MAIN
Add ebuild for libgmp.so.3 ABI name.

(Portage version: 2.2.0_alpha59/cvs/Linux x86_64)

1 # Copyright 1999-2011 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/dev-libs/gmp/gmp-4.3.2.ebuild,v 1.9 2011/08/05 15:27:23 darkside Exp $
4
5 # this ebuild is only for the libgmp.so.3 ABI SONAME
6
7 EAPI="3"
8
9 inherit eutils libtool toolchain-funcs
10
11 DESCRIPTION="Library for arithmetic on arbitrary precision integers, rational numbers, and floating-point numbers"
12 HOMEPAGE="http://gmplib.org/"
13 SRC_URI="mirror://gnu/${PN}/${P}.tar.bz2"
14
15 LICENSE="LGPL-3"
16 SLOT="3"
17 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
18 IUSE=""
19
20 DEPEND="sys-devel/m4"
21 RDEPEND=""
22
23 src_prepare() {
24 epatch "${FILESDIR}"/${PN}-4.1.4-noexecstack.patch
25 epatch "${FILESDIR}"/${PN}-4.3.2-ABI-multilib.patch
26 epatch "${FILESDIR}"/${PN}-4.2.1-s390.diff
27
28 sed -i -e 's:ABI = @ABI@:GMPABI = @GMPABI@:' \
29 Makefile.in */Makefile.in */*/Makefile.in
30
31 # note: we cannot run autotools here as gcc depends on this package
32 elibtoolize
33 }
34
35 src_configure() {
36 # Because of our 32-bit userland, 1.0 is the only HPPA ABI that works
37 # http://gmplib.org/manual/ABI-and-ISA.html#ABI-and-ISA (bug #344613)
38 if [[ ${CHOST} == hppa2.0-* ]] ; then
39 export GMPABI="1.0"
40 fi
41
42 # ABI mappings (needs all architectures supported)
43 case ${ABI} in
44 32|x86) export GMPABI=32;;
45 64|amd64|n64) export GMPABI=64;;
46 o32|n32) export GMPABI=${ABI};;
47 esac
48
49 tc-export CC
50 econf \
51 --localstatedir=/var/state/gmp \
52 --disable-mpfr \
53 --disable-mpbsd \
54 --disable-static \
55 --disable-cxx
56 }
57
58 src_install() {
59 emake install-libLTLIBRARIES DESTDIR="${D}" || die
60 rm "${D}"/usr/*/libgmp.{la,so} || die
61 }

  ViewVC Help
Powered by ViewVC 1.1.20