/[gentoo-x86]/dev-util/meld/meld-1.6.1.ebuild
Gentoo

Contents of /dev-util/meld/meld-1.6.1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.1 - (show annotations) (download)
Sat Oct 27 11:53:02 2012 UTC (21 months, 3 weeks ago) by pacho
Branch: MAIN
Version bump, drop old.

(Portage version: 2.1.11.30/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

1 # Copyright 1999-2012 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/dev-util/meld/meld-1.6.0.ebuild,v 1.7 2012/10/16 04:27:53 blueness Exp $
4
5 EAPI="4"
6 GCONF_DEBUG="no"
7 PYTHON_DEPEND="2:2.5"
8
9 inherit python gnome2 eutils multilib
10
11 DESCRIPTION="A graphical diff and merge tool"
12 HOMEPAGE="http://meldmerge.org/"
13
14 LICENSE="GPL-2"
15 SLOT="0"
16 KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
17 IUSE="gnome"
18
19 RDEPEND=">=dev-python/pygtk-2.14:2
20 >=dev-python/pygobject-2.8:2
21 gnome? ( >=dev-python/gconf-python-2.22:2 )"
22 DEPEND="${RDEPEND}
23 dev-util/gtk-doc-am
24 dev-util/intltool
25 app-text/scrollkeeper"
26
27 pkg_setup() {
28 # Needed for optimizing python modules against proper interpreter
29 python_set_active_version 2
30 python_pkg_setup
31 }
32
33 src_prepare() {
34 DOCS="NEWS"
35
36 # fix the prefix so its not in */local/*
37 sed -e "s:/usr/local:${EPREFIX}/usr:" \
38 -e "s:\$(prefix)/lib:\$(prefix)/$(get_libdir):" \
39 -i INSTALL || die "sed 1 failed"
40
41 # don't install anything to /usr/share/doc/meld
42 sed -e "s:\$(docdir)/meld:\$(docdir)/${PF}:" \
43 -i INSTALL || die "sed 2 failed"
44
45 # let the python eclass handle python objects
46 sed -e '/$(PYTHON) .* .import compileall;/s/\t/&#/g' \
47 -i Makefile || die "sed 3 failed"
48
49 # don't run scrollkeeper (with the wrong path),
50 # leave that to gnome2.eclass #145833
51 sed -e '/scrollkeeper-update/s/\t/&#/' \
52 -i help/*/Makefile || die "sed 4 failed"
53
54 # replace all calls to python by specific major version
55 sed -e "s/\(PYTHON ?= \).*/\1$(PYTHON -2)/" \
56 -i INSTALL || die "sed 6 failed"
57 python_convert_shebangs 2 "${S}"/tools/*
58
59 strip-linguas -i "${S}/po"
60 local mylinguas=""
61 for x in ${LINGUAS}; do
62 mylinguas="${mylinguas} ${x}.po"
63 done
64
65 if [ -n "${mylinguas}" ]; then
66 sed -e "s/PO:=.*/PO:=${mylinguas}/" \
67 -i po/Makefile || die "sed 5 failed"
68 fi
69
70 # Fix .desktop entry, upstream bug #686978
71 sed -i -e '/Encoding/d' data/meld.desktop.in || die
72
73 gnome2_src_prepare
74 }
75
76 src_configure() {
77 :
78 }
79
80 src_install() {
81 gnome2_src_install
82 python_convert_shebangs 2 "${ED}"usr/bin/meld
83 }
84
85 pkg_postinst() {
86 gnome2_pkg_postinst
87 python_mod_optimize /usr/$(get_libdir)/meld
88 }
89
90 pkg_postrm() {
91 gnome2_pkg_postrm
92 python_mod_cleanup /usr/$(get_libdir)/meld
93 }

  ViewVC Help
Powered by ViewVC 1.1.20