dev-vcs/git/git-1.7.3.3.ebuild

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-vcs/git/git-1.7.3.3.ebuild,v 1.3 2010/12/28 17:35:53 mr_bones_ Exp $

EAPI=3

GENTOO_DEPEND_ON_PERL=no
inherit toolchain-funcs eutils elisp-common perl-module bash-completion
[ "$PV" == "9999" ] && inherit git

MY_PV="${PV/_rc/.rc}"
MY_P="${PN}-${MY_PV}"

DOC_VER=${MY_PV}

DESCRIPTION="GIT - the stupid content tracker, the revision control system heavily used by the Linux kernel team"
HOMEPAGE="http://www.git-scm.com/"
if [ "$PV" != "9999" ]; then
        SRC_URI="mirror://kernel/software/scm/git/${MY_P}.tar.bz2
                        mirror://kernel/software/scm/git/${PN}-manpages-${DOC_VER}.tar.bz2
                        doc? ( mirror://kernel/software/scm/git/${PN}-htmldocs-${DOC_VER}.tar.bz2 )"
        KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~sparc-fbsd ~x86-fbsd ~x86-freebsd ~ia64-hpux ~x86-interix ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
else
        SRC_URI=""
        EGIT_BRANCH="master"
        EGIT_REPO_URI="git://git.kernel.org/pub/scm/git/git.git"
        # EGIT_REPO_URI="http://www.kernel.org/pub/scm/git/git.git"
        KEYWORDS=""
fi

LICENSE="GPL-2"
SLOT="0"
IUSE="+blksha1 +curl cgi doc emacs gtk iconv +perl ppcsha1 tk +threads +webdav xinetd cvs subversion"

# Common to both DEPEND and RDEPEND
CDEPEND="
        !blksha1? ( dev-libs/openssl )
        sys-libs/zlib
        perl?   ( dev-lang/perl[-build] )
        tk?     ( dev-lang/tk )
        curl?   (
                net-misc/curl
                webdav? ( dev-libs/expat )
        )
        emacs?  ( virtual/emacs )"

RDEPEND="${CDEPEND}
        perl? ( dev-perl/Error
                        dev-perl/Net-SMTP-SSL
                        dev-perl/Authen-SASL
                        cgi? ( virtual/perl-CGI )
                        cvs? ( >=dev-vcs/cvsps-2.1 dev-perl/DBI dev-perl/DBD-SQLite )
                        subversion? ( dev-vcs/subversion[-dso,perl] dev-perl/libwww-perl dev-perl/TermReadKey )
                        )
        gtk?
        (
                >=dev-python/pygtk-2.8
                || ( dev-python/pygtksourceview:2  dev-python/gtksourceview-python )
        )"

# This is how info docs are created with Git:
#   .txt/asciidoc --(asciidoc)---------> .xml/docbook
#   .xml/docbook  --(docbook2texi.pl)--> .texi
#   .texi         --(makeinfo)---------> .info
DEPEND="${CDEPEND}
        app-arch/cpio
        doc?    (
                app-text/asciidoc
                app-text/docbook2X
                sys-apps/texinfo
        )"

# Live ebuild builds man pages and HTML docs, additionally
if [ "$PV" == "9999" ]; then
        DEPEND="${DEPEND}
                app-text/asciidoc
                app-text/xmlto"
fi

SITEFILE=50${PN}-gentoo.el
S="${WORKDIR}/${MY_P}"

pkg_setup() {
        if ! use perl ; then
                use cgi && ewarn "gitweb needs USE=perl, ignoring USE=cgi"
                use cvs && ewarn "CVS integration needs USE=perl, ignoring USE=cvs"
                use subversion && ewarn "git-svn needs USE=perl, it won't work"
        fi
        if use webdav && ! use curl ; then
                ewarn "USE=webdav needs USE=curl. Ignoring"
        fi
        if use subversion && has_version dev-vcs/subversion && built_with_use --missing false dev-vcs/subversion dso ; then
                ewarn "Per Gentoo bugs #223747, #238586, when subversion is built"
                ewarn "with USE=dso, there may be weird crashes in git-svn. You"
                ewarn "have been warned."
        fi
}

# This is needed because for some obscure reasons future calls to make don't
# pick up these exports if we export them in src_unpack()
exportmakeopts() {
        local myopts

        if use blksha1 ; then
                myopts="${myopts} BLK_SHA1=YesPlease"
        elif use ppcsha1 ; then
                myopts="${myopts} PPC_SHA1=YesPlease"
        fi

        if use curl ; then
                use webdav || myopts="${myopts} NO_EXPAT=YesPlease"
        else
                myopts="${myopts} NO_CURL=YesPlease"
        fi

        # broken assumptions, because of broken build system ...
        myopts="${myopts} NO_FINK=YesPlease NO_DARWIN_PORTS=YesPlease"
        myopts="${myopts} INSTALL=install TAR=tar"
        myopts="${myopts} SHELL_PATH=${EPREFIX}/bin/sh"
        myopts="${myopts} SANE_TOOL_PATH="
        myopts="${myopts} OLD_ICONV="
        myopts="${myopts} NO_EXTERNAL_GREP="

        # can't define this to null, since the entire makefile depends on it
        sed -i -e '/\/usr\/local/s/BASIC_/#BASIC_/' Makefile

        use iconv \
                || einfo "Forcing iconv for ${PVR} due to bugs #321895, #322205."
        #       || myopts="${myopts} NO_ICONV=YesPlease"
        # because, above, we need to do this unconditionally (no "&& use iconv")
        use !elibc_glibc && myopts="${myopts} NEEDS_LIBICONV=YesPlease"

        use tk \
                || myopts="${myopts} NO_TCLTK=YesPlease"
        use perl \
                && myopts="${myopts} INSTALLDIRS=vendor" \
                || myopts="${myopts} NO_PERL=YesPlease"
        use threads \
                && myopts="${myopts} THREADED_DELTA_SEARCH=YesPlease"
        use subversion \
                || myopts="${myopts} NO_SVN_TESTS=YesPlease"
# Disabled until ~m68k-mint can be keyworded again
#       if [[ ${CHOST} == *-mint* ]] ; then
#               myopts="${myopts} NO_MMAP=YesPlease"
#               myopts="${myopts} NO_IPV6=YesPlease"
#               myopts="${myopts} NO_STRLCPY=YesPlease"
#               myopts="${myopts} NO_MEMMEM=YesPlease"
#               myopts="${myopts} NO_MKDTEMP=YesPlease"
#               myopts="${myopts} NO_MKSTEMPS=YesPlease"
#       fi
        if [[ ${CHOST} == ia64-*-hpux* ]]; then
                myopts="${myopts} NO_NSEC=YesPlease"
        fi

        has_version '>=app-text/asciidoc-8.0' \
                && myopts="${myopts} ASCIIDOC8=YesPlease"
        myopts="${myopts} ASCIIDOC_NO_ROFF=YesPlease"

        # Bug 290465:
        # builtin-fetch-pack.c:816: error: 'struct stat' has no member named 'st_mtim'
        [[ "${CHOST}" == *-uclibc* ]] && \
                myopts="${myopts} NO_NSEC=YesPlease"

        export MY_MAKEOPTS="${myopts}"
}

src_unpack() {
        if [ "${PV}" != "9999" ]; then
                unpack ${MY_P}.tar.bz2
                cd "${S}"
                unpack ${PN}-manpages-${DOC_VER}.tar.bz2
                use doc && \
                        cd "${S}"/Documentation && \
                        unpack ${PN}-htmldocs-${DOC_VER}.tar.bz2
                cd "${S}"
        else
                git_src_unpack
                cd "${S}"
                #cp "${FILESDIR}"/GIT-VERSION-GEN .
        fi

}

src_prepare() {
        # Noperl is being merged to upstream as of 2009/04/05
        #epatch "${FILESDIR}"/20090305-git-1.6.2-noperl.patch

        # GetOpt-Long v2.38 is strict
        # Merged in 1.6.3 final 2009/05/07
        #epatch "${FILESDIR}"/20090505-git-1.6.2.5-getopt-fixes.patch

        # JS install fixup
        epatch "${FILESDIR}"/git-1.7.2-always-install-js.patch

        # USE=-iconv causes segfaults, fixed post 1.7.1
        # Gentoo bug #321895
        #epatch "${FILESDIR}"/git-1.7.1-noiconv-segfault-fix.patch

        # Fix false positives with t3404 due to SHELL=/bin/false for the portage
        # user.
        epatch "${FILESDIR}"/git-1.7.3.4-avoid-shell-issues.patch

        sed -i \
                -e 's:^\(CFLAGS =\).*$:\1 $(OPTCFLAGS) -Wall:' \
                -e 's:^\(LDFLAGS =\).*$:\1 $(OPTLDFLAGS):' \
                -e 's:^\(CC = \).*$:\1$(OPTCC):' \
                -e 's:^\(AR = \).*$:\1$(OPTAR):' \
                -e "s:\(PYTHON_PATH = \)\(.*\)$:\1${EPREFIX}\2:" \
                -e "s:\(PERL_PATH = \)\(.*\)$:\1${EPREFIX}\2:" \
                Makefile || die "sed failed"

        # Never install the private copy of Error.pm (bug #296310)
        sed -i \
                -e '/private-Error.pm/s,^,#,' \
                perl/Makefile.PL

        # Fix docbook2texi command
        sed -i 's/DOCBOOK2X_TEXI=docbook2x-texi/DOCBOOK2X_TEXI=docbook2texi.pl/' \
                Documentation/Makefile || die "sed failed"

        # bug #318289
        epatch "${FILESDIR}"/git-1.7.3.2-interix.patch
}

git_emake() {
        emake ${MY_MAKEOPTS} \
                DESTDIR="${D}" \
                OPTCFLAGS="${CFLAGS}" \
                OPTLDFLAGS="${LDFLAGS}" \
                OPTCC="$(tc-getCC)" \
                OPTAR="$(tc-getAR)" \
                prefix="${EPREFIX}"/usr \
                htmldir="${EPREFIX}"/usr/share/doc/${PF}/html \
                sysconfdir="${EPREFIX}"/etc \
                "$@"
}

src_configure() {
        exportmakeopts
}

src_compile() {
        git_emake || die "emake failed"

        if use emacs ; then
                elisp-compile contrib/emacs/git{,-blame}.el \
                        || die "emacs modules failed"
        fi

        if use perl && use cgi ; then
                git_emake \
                        gitweb/gitweb.cgi \
                        || die "emake gitweb/gitweb.cgi failed"
        fi

        cd "${S}"/Documentation
        if [[ "$PV" == "9999" ]] ; then
                git_emake man \
                        || die "emake man failed"
                if use doc ; then
                        git_emake info html \
                                || die "emake info html failed"
                fi
        else
                if use doc ; then
                        git_emake info \
                                || die "emake info html failed"
                fi
        fi
}

src_install() {
        git_emake \
                install || \
                die "make install failed"

        # Depending on the tarball and manual rebuild of the documentation, the
        # manpages may exist in either OR both of these directories.
        find man?/*.[157] >/dev/null 2>&1 && doman man?/*.[157]
        find Documentation/*.[157] >/dev/null 2>&1 && doman Documentation/*.[157]

        dodoc README Documentation/{SubmittingPatches,CodingGuidelines}
        use doc && dodir /usr/share/doc/${PF}/html
        for d in / /howto/ /technical/ ; do
                docinto ${d}
                dodoc Documentation${d}*.txt
                use doc && dohtml -p ${d} Documentation${d}*.html
        done
        docinto /
        # Upstream does not ship this pre-built :-(
        use doc && doinfo Documentation/{git,gitman}.info

        dobashcompletion contrib/completion/git-completion.bash ${PN}

        if use emacs ; then
                elisp-install ${PN} contrib/emacs/git.{el,elc} || die
                elisp-install ${PN} contrib/emacs/git-blame.{el,elc} || die
                #elisp-install ${PN}/compat contrib/emacs/vc-git.{el,elc} || die
                # don't add automatically to the load-path, so the sitefile
                # can do a conditional loading
                touch "${ED}${SITELISP}/${PN}/compat/.nosearch"
                elisp-site-file-install "${FILESDIR}"/${SITEFILE} || die
        fi

        if use gtk ; then
                dobin "${S}"/contrib/gitview/gitview
                dodoc "${S}"/contrib/gitview/gitview.txt
        fi

        dobin contrib/fast-import/git-p4
        dodoc contrib/fast-import/git-p4.txt
        newbin contrib/fast-import/import-tars.perl import-tars
        newbin contrib/git-resurrect.sh git-resurrect

        dodir /usr/share/${PN}/contrib
        # The following are excluded:
        # completion - installed above
        # emacs - installed above
        # examples - these are stuff that is not used in Git anymore actually
        # gitview - installed above
        # p4import - excluded because fast-import has a better one
        # patches - stuff the Git guys made to go upstream to other places
        # svnimport - use git-svn
        # thunderbird-patch-inline - fixes thunderbird
        for i in \
                blameview buildsystems ciabot continuous convert-objects fast-import \
                hg-to-git hooks remotes2config.sh remotes2config.sh rerere-train.sh \
                stats svn-fe vim workdir \
                ; do
                cp -rf \
                        "${S}"/contrib/${i} \
                        "${ED}"/usr/share/${PN}/contrib \
                        || die "Failed contrib ${i}"
        done

        if use perl && use cgi ; then
                exeinto /usr/share/${PN}/gitweb
                doexe "${S}"/gitweb/gitweb.cgi
                insinto /usr/share/${PN}/gitweb/static
                doins "${S}"/gitweb/static/gitweb.css
                js=gitweb.js
                [ -f "${S}"/gitweb/static/gitweb.min.js ] && js=gitweb.min.js
                doins "${S}"/gitweb/static/${js}
                doins "${S}"/gitweb/static/git-{favicon,logo}.png

                # INSTALL discusses configuration issues, not just installation
                docinto /
                newdoc  "${S}"/gitweb/INSTALL INSTALL.gitweb
                newdoc  "${S}"/gitweb/README README.gitweb

                find "${ED}"/usr/lib64/perl5/ \
                        -name .packlist \
                        -exec rm \{\} \;
        fi
        if ! use subversion ; then
                rm -f "${ED}"/usr/libexec/git-core/git-svn \
                        "${ED}"/usr/share/man/man1/git-svn.1*
        fi

        if use xinetd ; then
                insinto /etc/xinetd.d
                newins "${FILESDIR}"/git-daemon.xinetd git-daemon
        fi

        newinitd "${FILESDIR}"/git-daemon.initd git-daemon
        newconfd "${FILESDIR}"/git-daemon.confd git-daemon

        fixlocalpod
}

src_test() {
        local disabled=""
        local tests_cvs="t9200-git-cvsexportcommit.sh \
                                        t9400-git-cvsserver-server.sh \
                                        t9401-git-cvsserver-crlf.sh \
                                        t9600-cvsimport.sh \
                                        t9601-cvsimport-vendor-branch.sh \
                                        t9602-cvsimport-branches-tags.sh \
                                        t9603-cvsimport-patchsets.sh"
        local tests_perl="t5502-quickfetch.sh \
                                        t5512-ls-remote.sh \
                                        t5520-pull.sh"
        # Bug #225601 - t0004 is not suitable for root perm
        # Bug #219839 - t1004 is not suitable for root perm
        # t0001-init.sh - check for init notices EPERM*  fails
        local tests_nonroot="t0001-init.sh \
                t0004-unwritable.sh \
                t1004-read-tree-m-u-wf.sh \
                t3700-add.sh \
                t7300-clean.sh"

        # Unzip is used only for the testcase code, not by any normal parts of Git.
        if ! has_version app-arch/unzip ; then
                einfo "Disabling tar-tree tests"
                disabled="${disabled} t5000-tar-tree.sh"
        fi

        cvs=0
        use cvs && let cvs=$cvs+1
        if [[ ${EUID} -eq 0 ]]; then
                if [[ $cvs -eq 1 ]]; then
                        ewarn "Skipping CVS tests because CVS does not work as root!"
                        ewarn "You should retest with FEATURES=userpriv!"
                        disabled="${disabled} ${tests_cvs}"
                fi
                einfo "Skipping other tests that require being non-root"
                disabled="${disabled} ${tests_nonroot}"
        else
                [[ $cvs -gt 0 ]] && \
                        has_version dev-vcs/cvs && \
                        let cvs=$cvs+1
                [[ $cvs -gt 1 ]] && \
                        built_with_use dev-vcs/cvs server && \
                        let cvs=$cvs+1
                if [[ $cvs -lt 3 ]]; then
                        einfo "Disabling CVS tests (needs dev-vcs/cvs[USE=server])"
                        disabled="${disabled} ${tests_cvs}"
                fi
        fi

        if ! use perl ; then
                einfo "Disabling tests that need Perl"
                disabled="${disabled} ${tests_perl}"
        fi

        # Reset all previously disabled tests
        cd "${S}/t"
        for i in *.sh.DISABLED ; do
                [[ -f "${i}" ]] && mv -f "${i}" "${i%.DISABLED}"
        done
        einfo "Disabled tests:"
        for i in ${disabled} ; do
                [[ -f "${i}" ]] && mv -f "${i}" "${i}.DISABLED" && einfo "Disabled $i"
        done
        cd "${S}"
        # Now run the tests
        einfo "Start test run"
        git_emake \
                test || die "tests failed"
}

showpkgdeps() {
        local pkg=$1
        shift
        elog "  $(printf "%-17s:" ${pkg}) ${@}"
}

pkg_postinst() {
        use emacs && elisp-site-regen
        if use subversion && has_version dev-vcs/subversion && ! built_with_use --missing false dev-vcs/subversion perl ; then
                ewarn "You must build dev-vcs/subversion with USE=perl"
                ewarn "to get the full functionality of git-svn!"
        fi
        elog "These additional scripts need some dependencies:"
        echo
        showpkgdeps git-quiltimport "dev-util/quilt"
        showpkgdeps git-instaweb \
                "|| ( www-servers/lighttpd www-servers/apache )"
        echo
}

pkg_postrm() {
        use emacs && elisp-site-regen
}
1	# Copyright 1999-2010 Gentoo Foundation
2	# Distributed under the terms of the GNU General Public License v2
3	# $Header: /var/cvsroot/gentoo-x86/dev-vcs/git/git-1.7.3.3.ebuild,v 1.3 2010/12/28 17:35:53 mr_bones_ Exp $
4
5	EAPI=3
6
7	GENTOO_DEPEND_ON_PERL=no
8	inherit toolchain-funcs eutils elisp-common perl-module bash-completion
9	[ "$PV" == "9999" ] && inherit git
10
11	MY_PV="${PV/_rc/.rc}"
12	MY_P="${PN}-${MY_PV}"
13
14	DOC_VER=${MY_PV}
15
16	DESCRIPTION="GIT - the stupid content tracker, the revision control system heavily used by the Linux kernel team"
17	HOMEPAGE="http://www.git-scm.com/"
18	if [ "$PV" != "9999" ]; then
19	SRC_URI="mirror://kernel/software/scm/git/${MY_P}.tar.bz2
20	mirror://kernel/software/scm/git/${PN}-manpages-${DOC_VER}.tar.bz2
21	doc? ( mirror://kernel/software/scm/git/${PN}-htmldocs-${DOC_VER}.tar.bz2 )"
22	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~sparc-fbsd ~x86-fbsd ~x86-freebsd ~ia64-hpux ~x86-interix ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
23	else
24	SRC_URI=""
25	EGIT_BRANCH="master"
26	EGIT_REPO_URI="git://git.kernel.org/pub/scm/git/git.git"
27	# EGIT_REPO_URI="http://www.kernel.org/pub/scm/git/git.git"
28	KEYWORDS=""
29	fi
30
31	LICENSE="GPL-2"
32	SLOT="0"
33	IUSE="+blksha1 +curl cgi doc emacs gtk iconv +perl ppcsha1 tk +threads +webdav xinetd cvs subversion"
34
35	# Common to both DEPEND and RDEPEND
36	CDEPEND="
37	!blksha1? ( dev-libs/openssl )
38	sys-libs/zlib
39	perl? ( dev-lang/perl[-build] )
40	tk? ( dev-lang/tk )
41	curl? (
42	net-misc/curl
43	webdav? ( dev-libs/expat )
44	)
45	emacs? ( virtual/emacs )"
46
47	RDEPEND="${CDEPEND}
48	perl? ( dev-perl/Error
49	dev-perl/Net-SMTP-SSL
50	dev-perl/Authen-SASL
51	cgi? ( virtual/perl-CGI )
52	cvs? ( >=dev-vcs/cvsps-2.1 dev-perl/DBI dev-perl/DBD-SQLite )
53	subversion? ( dev-vcs/subversion[-dso,perl] dev-perl/libwww-perl dev-perl/TermReadKey )
54	)
55	gtk?
56	(
57	>=dev-python/pygtk-2.8
58	\|\| ( dev-python/pygtksourceview:2 dev-python/gtksourceview-python )
59	)"
60
61	# This is how info docs are created with Git:
62	# .txt/asciidoc --(asciidoc)---------> .xml/docbook
63	# .xml/docbook --(docbook2texi.pl)--> .texi
64	# .texi --(makeinfo)---------> .info
65	DEPEND="${CDEPEND}
66	app-arch/cpio
67	doc? (
68	app-text/asciidoc
69	app-text/docbook2X
70	sys-apps/texinfo
71	)"
72
73	# Live ebuild builds man pages and HTML docs, additionally
74	if [ "$PV" == "9999" ]; then
75	DEPEND="${DEPEND}
76	app-text/asciidoc
77	app-text/xmlto"
78	fi
79
80	SITEFILE=50${PN}-gentoo.el
81	S="${WORKDIR}/${MY_P}"
82
83	pkg_setup() {
84	if ! use perl ; then
85	use cgi && ewarn "gitweb needs USE=perl, ignoring USE=cgi"
86	use cvs && ewarn "CVS integration needs USE=perl, ignoring USE=cvs"
87	use subversion && ewarn "git-svn needs USE=perl, it won't work"
88	fi
89	if use webdav && ! use curl ; then
90	ewarn "USE=webdav needs USE=curl. Ignoring"
91	fi
92	if use subversion && has_version dev-vcs/subversion && built_with_use --missing false dev-vcs/subversion dso ; then
93	ewarn "Per Gentoo bugs #223747, #238586, when subversion is built"
94	ewarn "with USE=dso, there may be weird crashes in git-svn. You"
95	ewarn "have been warned."
96	fi
97	}
98
99	# This is needed because for some obscure reasons future calls to make don't
100	# pick up these exports if we export them in src_unpack()
101	exportmakeopts() {
102	local myopts
103
104	if use blksha1 ; then
105	myopts="${myopts} BLK_SHA1=YesPlease"
106	elif use ppcsha1 ; then
107	myopts="${myopts} PPC_SHA1=YesPlease"
108	fi
109
110	if use curl ; then
111	use webdav \|\| myopts="${myopts} NO_EXPAT=YesPlease"
112	else
113	myopts="${myopts} NO_CURL=YesPlease"
114	fi
115
116	# broken assumptions, because of broken build system ...
117	myopts="${myopts} NO_FINK=YesPlease NO_DARWIN_PORTS=YesPlease"
118	myopts="${myopts} INSTALL=install TAR=tar"
119	myopts="${myopts} SHELL_PATH=${EPREFIX}/bin/sh"
120	myopts="${myopts} SANE_TOOL_PATH="
121	myopts="${myopts} OLD_ICONV="
122	myopts="${myopts} NO_EXTERNAL_GREP="
123
124	# can't define this to null, since the entire makefile depends on it
125	sed -i -e '/\/usr\/local/s/BASIC_/#BASIC_/' Makefile
126
127	use iconv \
128	\|\| einfo "Forcing iconv for ${PVR} due to bugs #321895, #322205."
129	# \|\| myopts="${myopts} NO_ICONV=YesPlease"
130	# because, above, we need to do this unconditionally (no "&& use iconv")
131	use !elibc_glibc && myopts="${myopts} NEEDS_LIBICONV=YesPlease"
132
133	use tk \
134	\|\| myopts="${myopts} NO_TCLTK=YesPlease"
135	use perl \
136	&& myopts="${myopts} INSTALLDIRS=vendor" \
137	\|\| myopts="${myopts} NO_PERL=YesPlease"
138	use threads \
139	&& myopts="${myopts} THREADED_DELTA_SEARCH=YesPlease"
140	use subversion \
141	\|\| myopts="${myopts} NO_SVN_TESTS=YesPlease"
142	# Disabled until ~m68k-mint can be keyworded again
143	# if [[ ${CHOST} == -mint ]] ; then
144	# myopts="${myopts} NO_MMAP=YesPlease"
145	# myopts="${myopts} NO_IPV6=YesPlease"
146	# myopts="${myopts} NO_STRLCPY=YesPlease"
147	# myopts="${myopts} NO_MEMMEM=YesPlease"
148	# myopts="${myopts} NO_MKDTEMP=YesPlease"
149	# myopts="${myopts} NO_MKSTEMPS=YesPlease"
150	# fi
151	if [[ ${CHOST} == ia64--hpux ]]; then
152	myopts="${myopts} NO_NSEC=YesPlease"
153	fi
154
155	has_version '>=app-text/asciidoc-8.0' \
156	&& myopts="${myopts} ASCIIDOC8=YesPlease"
157	myopts="${myopts} ASCIIDOC_NO_ROFF=YesPlease"
158
159	# Bug 290465:
160	# builtin-fetch-pack.c:816: error: 'struct stat' has no member named 'st_mtim'
161	[[ "${CHOST}" == -uclibc ]] && \
162	myopts="${myopts} NO_NSEC=YesPlease"
163
164	export MY_MAKEOPTS="${myopts}"
165	}
166
167	src_unpack() {
168	if [ "${PV}" != "9999" ]; then
169	unpack ${MY_P}.tar.bz2
170	cd "${S}"
171	unpack ${PN}-manpages-${DOC_VER}.tar.bz2
172	use doc && \
173	cd "${S}"/Documentation && \
174	unpack ${PN}-htmldocs-${DOC_VER}.tar.bz2
175	cd "${S}"
176	else
177	git_src_unpack
178	cd "${S}"
179	#cp "${FILESDIR}"/GIT-VERSION-GEN .
180	fi
181
182	}
183
184	src_prepare() {
185	# Noperl is being merged to upstream as of 2009/04/05
186	#epatch "${FILESDIR}"/20090305-git-1.6.2-noperl.patch
187
188	# GetOpt-Long v2.38 is strict
189	# Merged in 1.6.3 final 2009/05/07
190	#epatch "${FILESDIR}"/20090505-git-1.6.2.5-getopt-fixes.patch
191
192	# JS install fixup
193	epatch "${FILESDIR}"/git-1.7.2-always-install-js.patch
194
195	# USE=-iconv causes segfaults, fixed post 1.7.1
196	# Gentoo bug #321895
197	#epatch "${FILESDIR}"/git-1.7.1-noiconv-segfault-fix.patch
198
199	# Fix false positives with t3404 due to SHELL=/bin/false for the portage
200	# user.
201	epatch "${FILESDIR}"/git-1.7.3.4-avoid-shell-issues.patch
202
203	sed -i \
204	-e 's:^\(CFLAGS =\).*$:\1 $(OPTCFLAGS) -Wall:' \
205	-e 's:^\(LDFLAGS =\).*$:\1 $(OPTLDFLAGS):' \
206	-e 's:^\(CC = \).*$:\1$(OPTCC):' \
207	-e 's:^\(AR = \).*$:\1$(OPTAR):' \
208	-e "s:\(PYTHON_PATH = \)\(.*\)$:\1${EPREFIX}\2:" \
209	-e "s:\(PERL_PATH = \)\(.*\)$:\1${EPREFIX}\2:" \
210	Makefile \|\| die "sed failed"
211
212	# Never install the private copy of Error.pm (bug #296310)
213	sed -i \
214	-e '/private-Error.pm/s,^,#,' \
215	perl/Makefile.PL
216
217	# Fix docbook2texi command
218	sed -i 's/DOCBOOK2X_TEXI=docbook2x-texi/DOCBOOK2X_TEXI=docbook2texi.pl/' \
219	Documentation/Makefile \|\| die "sed failed"
220
221	# bug #318289
222	epatch "${FILESDIR}"/git-1.7.3.2-interix.patch
223	}
224
225	git_emake() {
226	emake ${MY_MAKEOPTS} \
227	DESTDIR="${D}" \
228	OPTCFLAGS="${CFLAGS}" \
229	OPTLDFLAGS="${LDFLAGS}" \
230	OPTCC="$(tc-getCC)" \
231	OPTAR="$(tc-getAR)" \
232	prefix="${EPREFIX}"/usr \
233	htmldir="${EPREFIX}"/usr/share/doc/${PF}/html \
234	sysconfdir="${EPREFIX}"/etc \
235	"$@"
236	}
237
238	src_configure() {
239	exportmakeopts
240	}
241
242	src_compile() {
243	git_emake \|\| die "emake failed"
244
245	if use emacs ; then
246	elisp-compile contrib/emacs/git{,-blame}.el \
247	\|\| die "emacs modules failed"
248	fi
249
250	if use perl && use cgi ; then
251	git_emake \
252	gitweb/gitweb.cgi \
253	\|\| die "emake gitweb/gitweb.cgi failed"
254	fi
255
256	cd "${S}"/Documentation
257	if [[ "$PV" == "9999" ]] ; then
258	git_emake man \
259	\|\| die "emake man failed"
260	if use doc ; then
261	git_emake info html \
262	\|\| die "emake info html failed"
263	fi
264	else
265	if use doc ; then
266	git_emake info \
267	\|\| die "emake info html failed"
268	fi
269	fi
270	}
271
272	src_install() {
273	git_emake \
274	install \|\| \
275	die "make install failed"
276
277	# Depending on the tarball and manual rebuild of the documentation, the
278	# manpages may exist in either OR both of these directories.
279	find man?/.[157] >/dev/null 2>&1 && doman man?/.[157]
280	find Documentation/.[157] >/dev/null 2>&1 && doman Documentation/.[157]
281
282	dodoc README Documentation/{SubmittingPatches,CodingGuidelines}
283	use doc && dodir /usr/share/doc/${PF}/html
284	for d in / /howto/ /technical/ ; do
285	docinto ${d}
286	dodoc Documentation${d}*.txt
287	use doc && dohtml -p ${d} Documentation${d}*.html
288	done
289	docinto /
290	# Upstream does not ship this pre-built :-(
291	use doc && doinfo Documentation/{git,gitman}.info
292
293	dobashcompletion contrib/completion/git-completion.bash ${PN}
294
295	if use emacs ; then
296	elisp-install ${PN} contrib/emacs/git.{el,elc} \|\| die
297	elisp-install ${PN} contrib/emacs/git-blame.{el,elc} \|\| die
298	#elisp-install ${PN}/compat contrib/emacs/vc-git.{el,elc} \|\| die
299	# don't add automatically to the load-path, so the sitefile
300	# can do a conditional loading
301	touch "${ED}${SITELISP}/${PN}/compat/.nosearch"
302	elisp-site-file-install "${FILESDIR}"/${SITEFILE} \|\| die
303	fi
304
305	if use gtk ; then
306	dobin "${S}"/contrib/gitview/gitview
307	dodoc "${S}"/contrib/gitview/gitview.txt
308	fi
309
310	dobin contrib/fast-import/git-p4
311	dodoc contrib/fast-import/git-p4.txt
312	newbin contrib/fast-import/import-tars.perl import-tars
313	newbin contrib/git-resurrect.sh git-resurrect
314
315	dodir /usr/share/${PN}/contrib
316	# The following are excluded:
317	# completion - installed above
318	# emacs - installed above
319	# examples - these are stuff that is not used in Git anymore actually
320	# gitview - installed above
321	# p4import - excluded because fast-import has a better one
322	# patches - stuff the Git guys made to go upstream to other places
323	# svnimport - use git-svn
324	# thunderbird-patch-inline - fixes thunderbird
325	for i in \
326	blameview buildsystems ciabot continuous convert-objects fast-import \
327	hg-to-git hooks remotes2config.sh remotes2config.sh rerere-train.sh \
328	stats svn-fe vim workdir \
329	; do
330	cp -rf \
331	"${S}"/contrib/${i} \
332	"${ED}"/usr/share/${PN}/contrib \
333	\|\| die "Failed contrib ${i}"
334	done
335
336	if use perl && use cgi ; then
337	exeinto /usr/share/${PN}/gitweb
338	doexe "${S}"/gitweb/gitweb.cgi
339	insinto /usr/share/${PN}/gitweb/static
340	doins "${S}"/gitweb/static/gitweb.css
341	js=gitweb.js
342	[ -f "${S}"/gitweb/static/gitweb.min.js ] && js=gitweb.min.js
343	doins "${S}"/gitweb/static/${js}
344	doins "${S}"/gitweb/static/git-{favicon,logo}.png
345
346	# INSTALL discusses configuration issues, not just installation
347	docinto /
348	newdoc "${S}"/gitweb/INSTALL INSTALL.gitweb
349	newdoc "${S}"/gitweb/README README.gitweb
350
351	find "${ED}"/usr/lib64/perl5/ \
352	-name .packlist \
353	-exec rm \{\} \;
354	fi
355	if ! use subversion ; then
356	rm -f "${ED}"/usr/libexec/git-core/git-svn \
357	"${ED}"/usr/share/man/man1/git-svn.1*
358	fi
359
360	if use xinetd ; then
361	insinto /etc/xinetd.d
362	newins "${FILESDIR}"/git-daemon.xinetd git-daemon
363	fi
364
365	newinitd "${FILESDIR}"/git-daemon.initd git-daemon
366	newconfd "${FILESDIR}"/git-daemon.confd git-daemon
367
368	fixlocalpod
369	}
370
371	src_test() {
372	local disabled=""
373	local tests_cvs="t9200-git-cvsexportcommit.sh \
374	t9400-git-cvsserver-server.sh \
375	t9401-git-cvsserver-crlf.sh \
376	t9600-cvsimport.sh \
377	t9601-cvsimport-vendor-branch.sh \
378	t9602-cvsimport-branches-tags.sh \
379	t9603-cvsimport-patchsets.sh"
380	local tests_perl="t5502-quickfetch.sh \
381	t5512-ls-remote.sh \
382	t5520-pull.sh"
383	# Bug #225601 - t0004 is not suitable for root perm
384	# Bug #219839 - t1004 is not suitable for root perm
385	# t0001-init.sh - check for init notices EPERM* fails
386	local tests_nonroot="t0001-init.sh \
387	t0004-unwritable.sh \
388	t1004-read-tree-m-u-wf.sh \
389	t3700-add.sh \
390	t7300-clean.sh"
391
392	# Unzip is used only for the testcase code, not by any normal parts of Git.
393	if ! has_version app-arch/unzip ; then
394	einfo "Disabling tar-tree tests"
395	disabled="${disabled} t5000-tar-tree.sh"
396	fi
397
398	cvs=0
399	use cvs && let cvs=$cvs+1
400	if [[ ${EUID} -eq 0 ]]; then
401	if [[ $cvs -eq 1 ]]; then
402	ewarn "Skipping CVS tests because CVS does not work as root!"
403	ewarn "You should retest with FEATURES=userpriv!"
404	disabled="${disabled} ${tests_cvs}"
405	fi
406	einfo "Skipping other tests that require being non-root"
407	disabled="${disabled} ${tests_nonroot}"
408	else
409	[[ $cvs -gt 0 ]] && \
410	has_version dev-vcs/cvs && \
411	let cvs=$cvs+1
412	[[ $cvs -gt 1 ]] && \
413	built_with_use dev-vcs/cvs server && \
414	let cvs=$cvs+1
415	if [[ $cvs -lt 3 ]]; then
416	einfo "Disabling CVS tests (needs dev-vcs/cvs[USE=server])"
417	disabled="${disabled} ${tests_cvs}"
418	fi
419	fi
420
421	if ! use perl ; then
422	einfo "Disabling tests that need Perl"
423	disabled="${disabled} ${tests_perl}"
424	fi
425
426	# Reset all previously disabled tests
427	cd "${S}/t"
428	for i in *.sh.DISABLED ; do
429	[[ -f "${i}" ]] && mv -f "${i}" "${i%.DISABLED}"
430	done
431	einfo "Disabled tests:"
432	for i in ${disabled} ; do
433	[[ -f "${i}" ]] && mv -f "${i}" "${i}.DISABLED" && einfo "Disabled $i"
434	done
435	cd "${S}"
436	# Now run the tests
437	einfo "Start test run"
438	git_emake \
439	test \|\| die "tests failed"
440	}
441
442	showpkgdeps() {
443	local pkg=$1
444	shift
445	elog " $(printf "%-17s:" ${pkg}) ${@}"
446	}
447
448	pkg_postinst() {
449	use emacs && elisp-site-regen
450	if use subversion && has_version dev-vcs/subversion && ! built_with_use --missing false dev-vcs/subversion perl ; then
451	ewarn "You must build dev-vcs/subversion with USE=perl"
452	ewarn "to get the full functionality of git-svn!"
453	fi
454	elog "These additional scripts need some dependencies:"
455	echo
456	showpkgdeps git-quiltimport "dev-util/quilt"
457	showpkgdeps git-instaweb \
458	"\|\| ( www-servers/lighttpd www-servers/apache )"
459	echo
460	}
461
462	pkg_postrm() {
463	use emacs && elisp-site-regen
464	}