| 1 |
# Copyright 1999-2012 Gentoo Foundation |
| 2 |
# Distributed under the terms of the GNU General Public License v2 |
| 3 |
# $Header: /var/cvsroot/gentoo-x86/dev-vcs/veracity/veracity-1.1.0.10565.ebuild,v 1.1 2011/10/07 01:12:05 binki Exp $ |
| 4 |
|
| 5 |
EAPI=4 |
| 6 |
|
| 7 |
inherit bash-completion-r1 eutils cmake-utils |
| 8 |
|
| 9 |
JS_P=js-1.8.0-rc1 |
| 10 |
|
| 11 |
DESCRIPTION="A modern and featureful DVCS (distributed version control system)" |
| 12 |
HOMEPAGE="http://veracity-scm.com/" |
| 13 |
SRC_URI="http://download.sourcegear.com/Veracity/release/${PV}/${PN}-source-${PV}.tar.gz |
| 14 |
|
| 15 |
ftp://ftp.mozilla.org/pub/mozilla.org/js/${JS_P}.tar.gz |
| 16 |
http://ftp.mozilla.org/pub/mozilla.org/js/${JS_P}.tar.gz" |
| 17 |
|
| 18 |
LICENSE="Apache-2.0" |
| 19 |
SLOT="0" |
| 20 |
KEYWORDS="~amd64 ~x86 ~x86-linux" |
| 21 |
IUSE="test" |
| 22 |
|
| 23 |
S=${WORKDIR}/${PN} |
| 24 |
|
| 25 |
# Tests fail in 1.0.0.10517. |
| 26 |
RESTRICT=test |
| 27 |
|
| 28 |
# Veracity can only use the API from spidermonkey-1.8.0 which isn't |
| 29 |
# available in gentoo-x86. It seems that spidermonkey needs to be |
| 30 |
# SLOTed... because Veracity needs differing amounts of nontrivial work |
| 31 |
# to support spidermonkey-1.8.2 or any newer spidermonkey. |
| 32 |
# |
| 33 |
# || ( >=dev-lang/spidermonkey-1.8[threadsafe] >=dev-lang/spidermonkey-1.8.5 ) |
| 34 |
RDEPEND=" |
| 35 |
dev-libs/icu |
| 36 |
net-misc/curl |
| 37 |
dev-libs/nspr |
| 38 |
sys-apps/util-linux |
| 39 |
dev-db/sqlite:3 |
| 40 |
sys-libs/zlib" |
| 41 |
DEPEND="${RDEPEND} |
| 42 |
virtual/pkgconfig |
| 43 |
test? ( app-arch/unzip )" |
| 44 |
|
| 45 |
src_prepare() { |
| 46 |
epatch "${FILESDIR}"/${PN}-1.0.0.10517-werror.patch |
| 47 |
epatch "${FILESDIR}"/${PN}-1.0.0.10517-system-sqlite.patch |
| 48 |
epatch "${FILESDIR}"/${PN}-1.0.0.10517-spidermonkey-as-needed.patch |
| 49 |
|
| 50 |
rm -rf src/thirdparty || die |
| 51 |
|
| 52 |
pushd "${WORKDIR}"/js || die |
| 53 |
( |
| 54 |
EPATCH_OPTS+=" -p8" |
| 55 |
epatch "${S}"/thirdparty/patches/js-1.8.0-rc1__{jsapi.c,jscntxt.{c,h}}.patch |
| 56 |
) |
| 57 |
} |
| 58 |
|
| 59 |
src_configure() { |
| 60 |
# Convince cmake scripts that spidermonkey has been prepared. |
| 61 |
mkdir -p thirdparty/{include/spidermonkey,lib} || die |
| 62 |
|
| 63 |
local mycmakeargs=( |
| 64 |
-DVVTHIRDPARTY="${S}"/thirdparty |
| 65 |
-DSPIDERMONKEY_INCDIR="${S}"/thirdparty/include |
| 66 |
-DSPIDERMONKEY_LIB="${S}"/thirdparty/lib/libjs.a |
| 67 |
) |
| 68 |
cmake-utils_src_configure |
| 69 |
} |
| 70 |
|
| 71 |
src_compile() { |
| 72 |
einfo "Compiling embedded spidermonkey (${JS_P})." |
| 73 |
# Based on thirdparty/build_linux.sh. |
| 74 |
emake -j1 \ |
| 75 |
-C "${WORKDIR}"/js/src \ |
| 76 |
JS_DIST="${EPREFIX}"/usr \ |
| 77 |
JS_THREADSAFE=1 \ |
| 78 |
BUILD_OPT=1 \ |
| 79 |
-f Makefile.ref |
| 80 |
cp "${WORKDIR}"/js/src/{*.{h,msg,tbl},Linux_All_OPT.OBJ/*.h} thirdparty/include/spidermonkey/ \ |
| 81 |
|| die "Preparing embedded spidermonkey." |
| 82 |
cp "${WORKDIR}"/js/src/Linux_All_OPT.OBJ/libjs.a thirdparty/lib/ \ |
| 83 |
|| die "Preparing embedded spidermonkey." |
| 84 |
|
| 85 |
einfo "Compiling ${P}." |
| 86 |
cmake-utils_src_compile |
| 87 |
} |
| 88 |
|
| 89 |
src_install() { |
| 90 |
cmake-utils_src_install |
| 91 |
|
| 92 |
rm -f "${D}"/etc/bash-completion.d || die |
| 93 |
newbashcomp src/cmd/vv.bash_completion vv |
| 94 |
} |
Parent Directory
| 
Revision Log