/[gentoo-x86]/games-arcade/gunocide2ex/gunocide2ex-1.0.ebuild
Gentoo

Contents of /games-arcade/gunocide2ex/gunocide2ex-1.0.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.15 - (show annotations) (download)
Sun Feb 5 06:20:50 2012 UTC (2 years, 6 months ago) by vapier
Branch: MAIN
CVS Tags: HEAD
Changes since 1.14: +3 -3 lines
Move to new unpacker eclass for unpack_makeself.

(Portage version: 2.2.0_alpha84/cvs/Linux x86_64)

1 # Copyright 1999-2012 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/games-arcade/gunocide2ex/gunocide2ex-1.0.ebuild,v 1.14 2009/06/17 23:32:42 nyhm Exp $
4
5 EAPI=2
6 inherit eutils unpacker toolchain-funcs games
7
8 DESCRIPTION="fast-paced 2D shoot'em'up"
9 HOMEPAGE="http://www.polyfrag.com/content/product_gunocide.html"
10 SRC_URI="mirror://sourceforge/g2ex/g2ex-setup.run"
11
12 LICENSE="GPL-2"
13 SLOT="0"
14 KEYWORDS="ppc x86 ~x86-fbsd"
15 IUSE=""
16
17 DEPEND="media-libs/libsdl[video]
18 media-libs/sdl-ttf
19 media-libs/sdl-mixer[vorbis]"
20
21 S=${WORKDIR}
22
23 src_unpack() {
24 unpack_makeself
25 mkdir binary
26 }
27
28 src_prepare() {
29 epatch \
30 "${FILESDIR}"/${P}-build.patch \
31 "${FILESDIR}"/${P}-glibc2.10.patch
32 edos2unix config.cfg
33 sed -i \
34 -e "s:/usr/local/games/gunocide2ex/config\.cfg:${GAMES_SYSCONFDIR}/${PN}.cfg:" \
35 -e "s:/usr/local/games/gunocide2ex/hscore\.dat:${GAMES_STATEDIR}/${PN}-hscore.dat:" \
36 -e "s:memleaks.log:/dev/null:" \
37 src/*.{h,cpp} \
38 || die "sed failed"
39 sed -i \
40 -e "s:/usr/local/games:${GAMES_DATADIR}:" \
41 src/*.{h,cpp} $(find gfx -name '*.txt') \
42 || die "sed failed"
43 }
44
45 src_compile() {
46 cd src
47 emake CXXFLAGS="$CXXFLAGS $(sdl-config --cflags)" $(echo *.cpp | sed 's/\.cpp/.o/g') \
48 || die "emake failed"
49 $(tc-getCXX) ${CXXFLAGS} ${LDFLAGS} -o ${PN} *.o -lpthread -lSDL -lSDL_ttf -lSDL_mixer \
50 || die "cxx failed"
51 }
52
53 src_install() {
54 dogamesbin src/${PN} || die "dogamesbin failed"
55 dosym ${PN} "${GAMES_BINDIR}/g2ex" || die "dosym failed"
56 insinto "${GAMES_DATADIR}/${PN}"
57 doins -r gfx sfx lvl credits arial.ttf || die "doins failed"
58 insinto "${GAMES_SYSCONFDIR}"
59 newins config.cfg ${PN}.cfg || die "newins failed (cfg)"
60 insinto "${GAMES_STATEDIR}"
61 newins hscore.dat ${PN}-hscore.dat || die "newins failed (hscore)"
62 dodoc history doc/MANUAL_DE || die "dodoc failed"
63 dohtml doc/manual_de.html || die "dohtml failed"
64 newicon g2icon.xpm ${PN}.xpm
65 make_desktop_entry ${PN} "Gunocide II EX"
66 prepgamesdirs
67 }

  ViewVC Help
Powered by ViewVC 1.1.20