/[gentoo-x86]/games-fps/alephone/alephone-20100424.ebuild
Gentoo

Contents of /games-fps/alephone/alephone-20100424.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.7 - (show annotations) (download)
Mon Oct 15 08:50:20 2012 UTC (23 months ago) by tupone
Branch: MAIN
CVS Tags: HEAD
Changes since 1.6: +5 -6 lines
Fix build with gcc-4.7 Bug #423037

(Portage version: 2.1.11.26/cvs/Linux i686)

1 # Copyright 1999-2012 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/games-fps/alephone/alephone-20100424.ebuild,v 1.6 2012/06/23 04:25:39 ssuominen Exp $
4
5 EAPI=4
6 inherit autotools eutils games
7
8 MY_P=AlephOne-${PV}
9 DESCRIPTION="An enhanced version of the game engine from the classic Mac game, Marathon"
10 HOMEPAGE="http://source.bungie.org/"
11 SRC_URI="mirror://sourceforge/marathon/${MY_P}.tar.bz2"
12
13 LICENSE="GPL-2 BitstreamVera"
14 SLOT="0"
15 KEYWORDS="amd64 ~ppc ~ppc64 x86"
16 IUSE="alsa mad mpeg sndfile speex truetype vorbis"
17
18 RDEPEND="media-libs/sdl-net
19 media-libs/sdl-image
20 media-libs/libsdl[video]
21 dev-libs/expat
22 dev-libs/zziplib
23 media-libs/libpng:0
24 alsa? ( media-libs/alsa-lib )
25 mad? ( media-libs/libmad )
26 mpeg? ( media-libs/smpeg )
27 virtual/opengl
28 virtual/glu
29 sndfile? ( media-libs/libsndfile )
30 speex? ( media-libs/speex )
31 truetype? ( media-libs/sdl-ttf )
32 vorbis? ( media-libs/libvorbis )"
33 DEPEND="${RDEPEND}
34 dev-libs/boost"
35
36 S=${WORKDIR}/${MY_P}
37
38 src_prepare() {
39 sed "s:GAMES_DATADIR:${GAMES_DATADIR}:g" \
40 "${FILESDIR}"/${PN}.sh > "${T}"/${PN}.sh \
41 || die
42
43 # try using the system expat - bug #251108
44 sed -i \
45 -e '/SUBDIRS/ s/Expat//' \
46 -e 's/Expat\/libexpat.a/-lexpat/' \
47 Source_Files/Makefile.am \
48 || die
49 sed -i \
50 -e '/Expat/d' \
51 configure.ac \
52 || die
53 rm -rf Source_Files/Expat
54
55 # for automake 1.12 compability - bug #422557
56 sed -i -e 's:AC_PROG_CC:&\nAC_PROG_OBJCXX:' configure.ac || die
57
58 epatch \
59 "${FILESDIR}"/${P}-boost_145.patch \
60 "${FILESDIR}"/${P}-gcc47.patch \
61 "${FILESDIR}"/${P}-png15.patch
62
63 eautoreconf
64 }
65
66 src_configure() {
67 egamesconf \
68 --enable-lua \
69 $(use_enable alsa) \
70 $(use_enable mad) \
71 $(use_enable mpeg smpeg) \
72 --enable-opengl \
73 $(use_enable sndfile) \
74 $(use_enable speex) \
75 $(use_enable truetype ttf) \
76 $(use_enable vorbis)
77 }
78
79 src_install() {
80 default
81 dogamesbin "${T}"/${PN}.sh
82 doman docs/${PN}.6
83 dohtml docs/*.html
84 prepgamesdirs
85 }
86
87 pkg_postinst() {
88 games_pkg_postinst
89 echo
90 elog "Read the docs and install the data files accordingly to play."
91 echo
92 elog "If you only want to install one scenario, read"
93 elog "http://traxus.bungie.org/index.php/Aleph_One_install_guide#Single_scenario_3"
94 elog "If you want to install multiple scenarios, read"
95 elog "http://traxus.bungie.org/index.php/Aleph_One_install_guide#Multiple_scenarios_3"
96 echo
97 }

  ViewVC Help
Powered by ViewVC 1.1.20