/[gentoo-x86]/games-strategy/openra/openra-20121019.ebuild
Gentoo

Contents of /games-strategy/openra/openra-20121019.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.1 - (show annotations) (download)
Sun Oct 21 00:09:36 2012 UTC (21 months ago) by hasufell
Branch: MAIN
version bump

(Portage version: 2.2.0_alpha140/cvs/Linux x86_64, signed Manifest commit with key E73C35B3)

1 # Copyright 1999-2012 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/games-strategy/openra/openra-20120504.ebuild,v 1.2 2012/05/04 17:31:14 hasufell Exp $
4
5 EAPI=4
6
7 inherit eutils mono gnome2-utils vcs-snapshot games
8
9 DESCRIPTION="A free RTS engine supporting games like Command & Conquer and Red Alert"
10 HOMEPAGE="http://open-ra.org/"
11 SRC_URI="https://github.com/OpenRA/OpenRA/tarball/release-${PV} -> ${P}.tar.gz"
12
13 LICENSE="GPL-3"
14 SLOT="0"
15 KEYWORDS="~amd64 ~x86"
16 IUSE="cg"
17
18 DEPEND="dev-dotnet/libgdiplus
19 dev-lang/mono
20 media-libs/freetype:2[X]
21 media-libs/libsdl[X,opengl,video]
22 media-libs/openal
23 virtual/jpeg
24 virtual/opengl
25 cg? ( >=media-gfx/nvidia-cg-toolkit-2.1.0017 )"
26 RDEPEND="${DEPEND}"
27
28 src_unpack() {
29 vcs-snapshot_src_unpack
30 }
31
32 src_prepare() {
33 # register game-version
34 sed \
35 -e "/Version/s/{DEV_VERSION}/release-${PV}/" \
36 -i mods/{ra,cnc,d2k}/mod.yaml || die
37 }
38
39 src_install() {
40 emake \
41 datadir="${GAMES_DATADIR}" \
42 bindir="${GAMES_BINDIR}" \
43 libdir="$(games_get_libdir)/${PN}" \
44 DESTDIR="${D}" \
45 install
46
47 # icons
48 insinto /usr/share/icons/
49 doins -r packaging/linux/hicolor
50
51 # desktop entries
52 local myrenderer=$(usex cg Cg Gl)
53 make_desktop_entry "${PN} Game.Mods=cnc Graphics.Renderer=${myrenderer}" \
54 "OpenRA CNC" ${PN}
55 make_desktop_entry "${PN} Game.Mods=ra Graphics.Renderer=${myrenderer}" \
56 "OpenRA RA" ${PN}
57 make_desktop_entry "${PN} Game.Mods=d2k Graphics.Renderer=${myrenderer}" \
58 "OpenRA Dune2k" ${PN}
59 make_desktop_entry "${PN}-editor" "OpenRA Map Editor" ${PN}
60
61 dodoc "${FILESDIR}"/README.gentoo README HACKING CHANGELOG
62
63 # file permissions
64 prepgamesdirs
65 }
66
67 pkg_preinst() {
68 games_pkg_preinst
69 gnome2_icon_savelist
70 }
71
72 pkg_postinst() {
73 games_pkg_postinst
74 gnome2_icon_cache_update
75
76 if ! use cg ; then
77 elog "If you have problems starting the game consider switching"
78 elog "to Graphics.Renderer=Cg in openra*.desktop or manually"
79 elog "run:"
80 elog "${PN} Game.Mods=\$mod Graphics.Renderer=Cg"
81 fi
82 }
83
84 pkg_postrm() {
85 gnome2_icon_cache_update
86 }

  ViewVC Help
Powered by ViewVC 1.1.20