/[gentoo-x86]/gnome-base/gvfs/gvfs-1.10.1.ebuild
Gentoo

Contents of /gnome-base/gvfs/gvfs-1.10.1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.17 - (show annotations) (download)
Tue Sep 25 11:46:48 2012 UTC (18 months, 2 weeks ago) by tetromino
Branch: MAIN
Changes since 1.16: +2 -2 lines
Version bump with much improved udisks support and other bugfixes. Drop old. Restore lost ChangeLog entries. Make license more precise.

(Portage version: 2.2.0_alpha132/cvs/Linux x86_64)

1 # Copyright 1999-2012 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/gnome-base/gvfs/gvfs-1.10.1.ebuild,v 1.16 2012/05/05 05:38:09 jdhore Exp $
4
5 EAPI=4
6 GCONF_DEBUG=no
7 GNOME2_LA_PUNT=yes
8
9 inherit autotools bash-completion-r1 eutils gnome2
10
11 [[ ${PV} = 9999 ]] && inherit gnome2-live
12
13 DESCRIPTION="GNOME Virtual Filesystem Layer"
14 HOMEPAGE="http://www.gnome.org"
15
16 LICENSE="LGPL-2+"
17 SLOT="0"
18
19 if [[ ${PV} = 9999 ]]; then
20 KEYWORDS=""
21 DOCS=""
22 else
23 KEYWORDS="alpha amd64 arm ia64 ~mips ppc ppc64 sh sparc x86 ~x86-fbsd"
24 DOCS="AUTHORS ChangeLog NEWS MAINTAINERS README TODO" # ChangeLog.pre-1.2 README.commits
25 fi
26
27 SRC_URI="${SRC_URI}
28 http://dev.gentoo.org/~tetromino/distfiles/aclocal/libgcrypt.m4.bz2"
29
30 IUSE="afp archive avahi bluetooth bluray cdda doc fuse gdu gnome-keyring gphoto2 +http ios samba +udev"
31
32 RDEPEND=">=dev-libs/glib-2.29.14
33 sys-apps/dbus
34 dev-libs/libxml2
35 net-misc/openssh
36 afp? ( >=dev-libs/libgcrypt-1.2.2 )
37 archive? ( app-arch/libarchive )
38 avahi? ( >=net-dns/avahi-0.6 )
39 bluetooth? (
40 >=app-mobilephone/obex-data-server-0.4.5
41 dev-libs/dbus-glib
42 net-wireless/bluez
43 dev-libs/expat )
44 bluray? ( media-libs/libbluray )
45 fuse? ( >=sys-fs/fuse-2.8.0 )
46 gdu? ( || (
47 >=gnome-base/libgdu-3.0.2
48 =sys-apps/gnome-disk-utility-3.0.2-r300
49 =sys-apps/gnome-disk-utility-3.0.2-r200 ) )
50 gnome-keyring? ( >=gnome-base/gnome-keyring-1.0 )
51 gphoto2? ( >=media-libs/libgphoto2-2.4.7 )
52 ios? (
53 >=app-pda/libimobiledevice-1.1.0
54 >=app-pda/libplist-1 )
55 udev? (
56 cdda? ( >=dev-libs/libcdio-0.78.2[-minimal] )
57 || ( >=sys-fs/udev-171[gudev] >=sys-fs/udev-164-r2[extras] ) )
58 http? ( >=net-libs/libsoup-gnome-2.26.0 )
59 samba? ( >=net-fs/samba-3.4.6[smbclient] )"
60 DEPEND="${RDEPEND}
61 >=dev-util/intltool-0.40
62 virtual/pkgconfig
63 dev-util/gtk-doc-am
64 doc? ( >=dev-util/gtk-doc-1 )"
65
66 REQUIRED_USE="cdda? ( udev )"
67
68 pkg_setup() {
69 G2CONF="${G2CONF}
70 --disable-bash-completion
71 --disable-hal
72 --disable-schemas-compile
73 --with-dbus-service-dir=/usr/share/dbus-1/services
74 $(use_enable afp)
75 $(use_enable archive)
76 $(use_enable avahi)
77 $(use_enable bluetooth obexftp)
78 $(use_enable bluray)
79 $(use_enable cdda)
80 $(use_enable fuse)
81 $(use_enable gdu)
82 $(use_enable gphoto2)
83 $(use_enable ios afc)
84 $(use_enable udev)
85 $(use_enable udev gudev)
86 $(use_enable http)
87 $(use_enable gnome-keyring keyring)
88 $(use_enable samba)"
89 }
90
91 src_prepare() {
92 # Patch from 1.11 for building against glib-2.31, bug #401539
93 epatch "${FILESDIR}/${P}-unneeded-include.patch"
94
95 # Conditional patching purely to avoid eautoreconf
96 use gphoto2 && epatch "${FILESDIR}"/${PN}-1.2.2-gphoto2-stricter-checks.patch
97
98 if use archive; then
99 epatch "${FILESDIR}"/${PN}-1.2.2-expose-archive-backend.patch
100 echo mount-archive.desktop.in >> po/POTFILES.in
101 echo mount-archive.desktop.in.in >> po/POTFILES.in
102 fi
103
104 if ! use udev; then
105 sed -i -e 's/gvfsd-burn/ /' daemon/Makefile.am || die
106 sed -i -e 's/burn.mount.in/ /' daemon/Makefile.am || die
107 sed -i -e 's/burn.mount/ /' daemon/Makefile.am || die
108 fi
109
110 # bug #410411, https://bugzilla.gnome.org/show_bug.cgi?id=672693
111 use ios && epatch "${FILESDIR}/${PN}-1.10.1-libimobiledevice-1.1.2.patch"
112
113 if use gphoto2 || use archive || ! use udev || use ios; then
114 # libgcrypt.m4 needed for eautoreconf, bug #399043
115 mv "${WORKDIR}/libgcrypt.m4" "${S}"/ || die
116
117 AT_M4DIR=. eautoreconf
118 fi
119
120 gnome2_src_prepare
121 }
122
123 src_install() {
124 gnome2_src_install
125 newbashcomp programs/gvfs-bash-completion.sh ${PN}
126 }

  ViewVC Help
Powered by ViewVC 1.1.20