/[gentoo-x86]/gnome-base/librsvg/librsvg-2.36.4.ebuild
Gentoo

Contents of /gnome-base/librsvg/librsvg-2.36.4.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.15 - (show annotations) (download)
Sat Feb 15 11:01:50 2014 UTC (10 months, 1 week ago) by pacho
Branch: MAIN
CVS Tags: HEAD
Changes since 1.14: +1 -1 lines
FILE REMOVED
Version bump, drop old

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

1 # Copyright 1999-2013 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/gnome-base/librsvg/librsvg-2.36.4.ebuild,v 1.14 2013/09/03 22:10:11 eva Exp $
4
5 EAPI="4"
6 GNOME2_LA_PUNT="yes"
7 GCONF_DEBUG="no"
8 VALA_MIN_API_VERSION="0.18"
9 VALA_USE_DEPEND="vapigen"
10
11 inherit autotools eutils gnome2 multilib vala
12
13 DESCRIPTION="Scalable Vector Graphics (SVG) rendering library"
14 HOMEPAGE="https://live.gnome.org/LibRsvg"
15
16 LICENSE="LGPL-2"
17 SLOT="2"
18 KEYWORDS="alpha amd64 arm hppa ia64 ~mips ppc ppc64 ~s390 sh sparc x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
19 IUSE="+gtk +introspection tools vala"
20 REQUIRED_USE="vala? ( introspection )"
21
22 RDEPEND=">=dev-libs/glib-2.24:2
23 >=x11-libs/cairo-1.2
24 >=x11-libs/pango-1.16
25 >=dev-libs/libxml2-2.7:2
26 >=dev-libs/libcroco-0.6.1
27 x11-libs/gdk-pixbuf:2[introspection?]
28 gtk? (
29 >=x11-libs/gtk+-2.16:2
30 tools? ( >=x11-libs/gtk+-3:3 ) )
31 introspection? ( >=dev-libs/gobject-introspection-0.10.8 )"
32 DEPEND="${RDEPEND}
33 virtual/pkgconfig
34 dev-libs/gobject-introspection-common
35 dev-libs/vala-common
36 >=dev-util/gtk-doc-am-1.13
37 vala? ( $(vala_depend) )"
38 # >=gtk-doc-am-1.13, gobject-introspection-common, vala-common needed by eautoreconf
39
40 src_prepare() {
41 G2CONF="${G2CONF}
42 --disable-static
43 $(use_enable tools)
44 $(use_enable gtk gtk-theme)
45 $(use_enable introspection)
46 $(use_enable vala)
47 --enable-pixbuf-loader"
48 if use gtk && use tools; then
49 G2CONF="${G2CONF} --enable-rsvg-view"
50 else
51 G2CONF="${G2CONF} --disable-rsvg-view"
52 fi
53 # -Bsymbolic is not supported by the Darwin toolchain
54 [[ ${CHOST} == *-darwin* ]] && G2CONF="${G2CONF} --disable-Bsymbolic"
55
56 DOCS="AUTHORS ChangeLog README NEWS TODO"
57
58 # Make rsvg-view non-automagic
59 epatch "${FILESDIR}/${PN}-2.36.0-rsvg-view-automagic.patch"
60
61 use vala && vala_src_prepare
62
63 eautoreconf
64 gnome2_src_prepare
65 }
66
67 src_compile() {
68 # causes segfault if set, see bug #411765
69 unset __GL_NO_DSO_FINALIZER
70 gnome2_src_compile
71 }
72
73 pkg_postinst() {
74 # causes segfault if set, see bug 375615
75 unset __GL_NO_DSO_FINALIZER
76 gnome2_pkg_postinst
77 }
78
79 pkg_postrm() {
80 # causes segfault if set, see bug 375615
81 unset __GL_NO_DSO_FINALIZER
82 gnome2_pkg_postrm
83 }

  ViewVC Help
Powered by ViewVC 1.1.20