kde-base/plasma-workspace/plasma-workspace-4.9.0.ebuild

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/plasma-workspace/plasma-workspace-4.9.0.ebuild,v 1.2 2012/08/08 12:01:09 kensington Exp $

EAPI=4

KDE_HANDBOOK="optional"
KMNAME="kde-workspace"
KMMODULE="plasma"
PYTHON_DEPEND="python? 2"
inherit python kde4-meta

DESCRIPTION="Plasma: KDE desktop framework"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="debug google-gadgets gps python qalculate +rss semantic-desktop"

COMMONDEPEND="
        $(add_kdebase_dep kactivities)
        $(add_kdebase_dep kdelibs 'semantic-desktop=')
        $(add_kdebase_dep kephal)
        $(add_kdebase_dep ksysguard)
        $(add_kdebase_dep libkworkspace)
        $(add_kdebase_dep libplasmagenericshell)
        $(add_kdebase_dep libtaskmanager)
        $(add_kdebase_dep solid)
        x11-libs/libXcomposite
        x11-libs/libXdamage
        x11-libs/libXfixes
        x11-libs/libXrender
        google-gadgets? ( >=x11-misc/google-gadgets-0.11.0[qt4] )
        gps? ( >=sci-geosciences/gpsd-2.37 )
        python? (
                >=dev-python/PyQt4-4.4.0[X]
                >=dev-python/sip-4.7.1
                $(add_kdebase_dep pykde4)
        )
        qalculate? ( sci-libs/libqalculate )
        rss? (
                $(add_kdebase_dep kdepimlibs 'semantic-desktop=')
                $(add_kdebase_dep libplasmaclock 'holidays')
        )
        !rss? ( $(add_kdebase_dep libplasmaclock '-holidays') )
"
DEPEND="${COMMONDEPEND}
        rss? ( dev-libs/boost )
        x11-proto/compositeproto
        x11-proto/damageproto
        x11-proto/fixesproto
        x11-proto/renderproto
"
RDEPEND="${COMMONDEPEND}
        $(add_kdebase_dep plasma-runtime)
"

KMEXTRA="
        statusnotifierwatcher/
"
KMEXTRACTONLY="
        krunner/dbus/org.freedesktop.ScreenSaver.xml
        krunner/dbus/org.kde.krunner.App.xml
        ksmserver/org.kde.KSMServerInterface.xml
        libs/kephal/
        libs/kworkspace/
        libs/taskmanager/
        libs/plasmagenericshell/
        libs/ksysguard/
        ksysguard/
"

KMLOADLIBS="libkworkspace libplasmaclock libplasmagenericshell libtaskmanager"

pkg_setup() {
        python_set_active_version 2
        python_pkg_setup
        kde4-meta_pkg_setup
}

src_unpack() {
        if use handbook; then
                KMEXTRA+=" doc/plasma-desktop"
        fi

        kde4-meta_src_unpack
}

src_configure() {
        mycmakeargs=(
                $(cmake-utils_use_with google-gadgets Googlegadgets)
                $(cmake-utils_use_with gps libgps)
                $(cmake-utils_use_with python SIP)
                $(cmake-utils_use_with python PyQt4)
                $(cmake-utils_use_with python PyKDE4)
                $(cmake-utils_use_with qalculate)
                $(cmake-utils_use_with rss KdepimLibs)
                $(cmake-utils_use_with semantic-desktop Akonadi)
                $(cmake-utils_use_with semantic-desktop Nepomuk)
                $(cmake-utils_use_with semantic-desktop Soprano)
                -DWITH_Xmms=OFF
        )

        kde4-meta_src_configure
}

src_install() {
        kde4-meta_src_install

        rm -f \
                "${ED}$(python_get_sitedir)"/PyKDE4/*.py[co] \
                "${ED}"/usr/share/apps/plasma_scriptengine_python/*.py[co]
}

pkg_postinst() {
        kde4-meta_pkg_postinst

        if use python; then
                python_mod_optimize \
                        PyKDE4 \
                        /usr/share/apps/plasma_scriptengine_python
        fi
}

pkg_postrm() {
        kde4-meta_pkg_postrm

        if [[ -d ${EPREFIX}/usr/share/apps/plasma_scriptengine_python ]]; then
                python_mod_cleanup \
                        PyKDE4 \
                        /usr/share/apps/plasma_scriptengine_python
        fi
}
1	# Copyright 1999-2012 Gentoo Foundation
2	# Distributed under the terms of the GNU General Public License v2
3	# $Header: /var/cvsroot/gentoo-x86/kde-base/plasma-workspace/plasma-workspace-4.9.0.ebuild,v 1.2 2012/08/08 12:01:09 kensington Exp $
4
5	EAPI=4
6
7	KDE_HANDBOOK="optional"
8	KMNAME="kde-workspace"
9	KMMODULE="plasma"
10	PYTHON_DEPEND="python? 2"
11	inherit python kde4-meta
12
13	DESCRIPTION="Plasma: KDE desktop framework"
14	KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
15	IUSE="debug google-gadgets gps python qalculate +rss semantic-desktop"
16
17	COMMONDEPEND="
18	$(add_kdebase_dep kactivities)
19	$(add_kdebase_dep kdelibs 'semantic-desktop=')
20	$(add_kdebase_dep kephal)
21	$(add_kdebase_dep ksysguard)
22	$(add_kdebase_dep libkworkspace)
23	$(add_kdebase_dep libplasmagenericshell)
24	$(add_kdebase_dep libtaskmanager)
25	$(add_kdebase_dep solid)
26	x11-libs/libXcomposite
27	x11-libs/libXdamage
28	x11-libs/libXfixes
29	x11-libs/libXrender
30	google-gadgets? ( >=x11-misc/google-gadgets-0.11.0[qt4] )
31	gps? ( >=sci-geosciences/gpsd-2.37 )
32	python? (
33	>=dev-python/PyQt4-4.4.0[X]
34	>=dev-python/sip-4.7.1
35	$(add_kdebase_dep pykde4)
36	)
37	qalculate? ( sci-libs/libqalculate )
38	rss? (
39	$(add_kdebase_dep kdepimlibs 'semantic-desktop=')
40	$(add_kdebase_dep libplasmaclock 'holidays')
41	)
42	!rss? ( $(add_kdebase_dep libplasmaclock '-holidays') )
43	"
44	DEPEND="${COMMONDEPEND}
45	rss? ( dev-libs/boost )
46	x11-proto/compositeproto
47	x11-proto/damageproto
48	x11-proto/fixesproto
49	x11-proto/renderproto
50	"
51	RDEPEND="${COMMONDEPEND}
52	$(add_kdebase_dep plasma-runtime)
53	"
54
55	KMEXTRA="
56	statusnotifierwatcher/
57	"
58	KMEXTRACTONLY="
59	krunner/dbus/org.freedesktop.ScreenSaver.xml
60	krunner/dbus/org.kde.krunner.App.xml
61	ksmserver/org.kde.KSMServerInterface.xml
62	libs/kephal/
63	libs/kworkspace/
64	libs/taskmanager/
65	libs/plasmagenericshell/
66	libs/ksysguard/
67	ksysguard/
68	"
69
70	KMLOADLIBS="libkworkspace libplasmaclock libplasmagenericshell libtaskmanager"
71
72	pkg_setup() {
73	python_set_active_version 2
74	python_pkg_setup
75	kde4-meta_pkg_setup
76	}
77
78	src_unpack() {
79	if use handbook; then
80	KMEXTRA+=" doc/plasma-desktop"
81	fi
82
83	kde4-meta_src_unpack
84	}
85
86	src_configure() {
87	mycmakeargs=(
88	$(cmake-utils_use_with google-gadgets Googlegadgets)
89	$(cmake-utils_use_with gps libgps)
90	$(cmake-utils_use_with python SIP)
91	$(cmake-utils_use_with python PyQt4)
92	$(cmake-utils_use_with python PyKDE4)
93	$(cmake-utils_use_with qalculate)
94	$(cmake-utils_use_with rss KdepimLibs)
95	$(cmake-utils_use_with semantic-desktop Akonadi)
96	$(cmake-utils_use_with semantic-desktop Nepomuk)
97	$(cmake-utils_use_with semantic-desktop Soprano)
98	-DWITH_Xmms=OFF
99	)
100
101	kde4-meta_src_configure
102	}
103
104	src_install() {
105	kde4-meta_src_install
106
107	rm -f \
108	"${ED}$(python_get_sitedir)"/PyKDE4/*.py[co] \
109	"${ED}"/usr/share/apps/plasma_scriptengine_python/*.py[co]
110	}
111
112	pkg_postinst() {
113	kde4-meta_pkg_postinst
114
115	if use python; then
116	python_mod_optimize \
117	PyKDE4 \
118	/usr/share/apps/plasma_scriptengine_python
119	fi
120	}
121
122	pkg_postrm() {
123	kde4-meta_pkg_postrm
124
125	if [[ -d ${EPREFIX}/usr/share/apps/plasma_scriptengine_python ]]; then
126	python_mod_cleanup \
127	PyKDE4 \
128	/usr/share/apps/plasma_scriptengine_python
129	fi
130	}