/[gentoo-x86]/media-gfx/nip2/nip2-7.26.2.ebuild
Gentoo

Contents of /media-gfx/nip2/nip2-7.26.2.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.2 - (show annotations) (download)
Mon Dec 12 08:49:50 2011 UTC (3 years ago) by pva
Branch: MAIN
CVS Tags: HEAD
Changes since 1.1: +1 -1 lines
FILE REMOVED
Version bump. Drop old.

(Portage version: 2.1.10.39/cvs/Linux x86_64)

1 # Copyright 1999-2011 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/media-gfx/nip2/nip2-7.26.2.ebuild,v 1.1 2011/08/14 10:55:04 pva Exp $
4
5 EAPI=2
6 inherit eutils autotools fdo-mime gnome2-utils versionator
7
8 MY_MAJ_VER=$(get_version_component_range 1-2)
9 DESCRIPTION="VIPS Image Processing Graphical User Interface"
10 SRC_URI="http://www.vips.ecs.soton.ac.uk/supported/${MY_MAJ_VER}/${P}.tar.gz"
11 HOMEPAGE="http://vips.sourceforge.net"
12
13 LICENSE="GPL-2"
14 SLOT="0"
15 KEYWORDS="~amd64 ~x86"
16 IUSE="debug fftw goffice gsl test"
17
18 RDEPEND=">=dev-libs/glib-2.14:2
19 dev-libs/libxml2
20 x11-misc/xdg-utils
21 >=media-libs/vips-${MY_MAJ_VER}
22 >=x11-libs/gtk+-2.18:2
23 goffice? ( x11-libs/goffice:0.8 )
24 gsl? ( sci-libs/gsl )
25 fftw? ( sci-libs/fftw:3.0 )"
26 DEPEND="${RDEPEND}
27 sys-devel/bison
28 sys-devel/flex
29 test? ( media-libs/vips[jpeg,lcms] )"
30
31 src_prepare() {
32 epatch "${FILESDIR}"/${PN}-7.16.4-fftw3-build.patch
33 eautoreconf
34 }
35
36 src_configure() {
37 econf \
38 --disable-update-desktop \
39 $(use_enable debug) \
40 $(use_with goffice libgoffice) \
41 $(use_with gsl) \
42 $(use_with fftw fftw3)
43 }
44
45 src_test() {
46 if ! use gsl; then
47 ewarn "Some tests require USE=gsl. Disabling test_math.ws tests."
48 rm test/workspaces/test_math.ws
49 fi
50 make check || die
51 }
52
53 src_install() {
54 emake DESTDIR="${D}" install || die
55 dodoc AUTHORS ChangeLog NEWS README* || die
56 insinto /usr/share/icons/hicolor/128x128/apps
57 newins share/nip2/data/vips-128.png nip2.png || die
58
59 mv "${D}"/usr/share/doc/${PN}/* "${D}"/usr/share/doc/${PF} || die
60 rmdir "${D}"/usr/share/doc/${PN}/ || die
61 dosym /usr/share/doc/${PF}/html /usr/share/doc/${PN}/
62 }
63
64 pkg_preinst() {
65 gnome2_icon_savelist
66 }
67
68 pkg_postinst() {
69 fdo-mime_desktop_database_update
70 fdo-mime_mime_database_update
71 gnome2_icon_cache_update
72 }
73
74 pkg_postrm() {
75 fdo-mime_desktop_database_update
76 fdo-mime_mime_database_update
77 gnome2_icon_cache_update
78 }

  ViewVC Help
Powered by ViewVC 1.1.20