/[gentoo-x86]/media-libs/libpng/libpng-1.6.1.ebuild
Gentoo

Contents of /media-libs/libpng/libpng-1.6.1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.3 - (show annotations) (download)
Sat Apr 27 05:28:23 2013 UTC (16 months ago) by ssuominen
Branch: MAIN
CVS Tags: HEAD
Changes since 1.2: +1 -1 lines
FILE REMOVED
old, broken

(Portage version: 2.2.0_alpha173/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

1 # Copyright 1999-2013 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/media-libs/libpng/libpng-1.6.1.ebuild,v 1.2 2013/04/09 20:13:51 ssuominen Exp $
4
5 EAPI=5
6
7 inherit eutils libtool multilib
8
9 DESCRIPTION="Portable Network Graphics library"
10 HOMEPAGE="http://www.libpng.org/"
11 SRC_URI="mirror://sourceforge/${PN}/${P}.tar.xz
12 apng? ( mirror://sourceforge/apng/${P}-apng.patch.gz )"
13
14 LICENSE="libpng"
15 SLOT="0/16"
16 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris ~x86-winnt"
17 IUSE="apng neon static-libs"
18
19 RDEPEND="sys-libs/zlib:="
20 DEPEND="${RDEPEND}
21 app-arch/xz-utils"
22
23 DOCS=( ANNOUNCE CHANGES libpng-manual.txt README TODO )
24
25 src_prepare() {
26 if use apng; then
27 epatch "${WORKDIR}"/${PN}-*-apng.patch
28 # Don't execute symbols check with apng patch wrt #378111
29 sed -i -e '/^check/s:scripts/symbols.chk::' Makefile.in || die
30 fi
31 elibtoolize
32 }
33
34 src_configure() {
35 econf \
36 $(use_enable static-libs static) \
37 --enable-arm-neon=$(usex neon on off)
38 }
39
40 src_install() {
41 default
42 # Even prune_libtool --all fails to remove libpng.la dead symlink wrt #436996
43 find "${ED}" -name '*.la' -exec rm -f {} +
44 }
45
46 pkg_preinst() {
47 has_version ${CATEGORY}/${PN}:1.5 && return 0
48 preserve_old_lib /usr/$(get_libdir)/libpng15$(get_libname 15)
49 }
50
51 pkg_postinst() {
52 has_version ${CATEGORY}/${PN}:1.5 && return 0
53 preserve_old_lib_notify /usr/$(get_libdir)/libpng15$(get_libname 15)
54 }

  ViewVC Help
Powered by ViewVC 1.1.20