/[gentoo-x86]/media-libs/openimageio/openimageio-1.0.8.ebuild
Gentoo

Contents of /media-libs/openimageio/openimageio-1.0.8.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.5 - (show annotations) (download)
Sat Nov 24 21:23:12 2012 UTC (19 months, 3 weeks ago) by ssuominen
Branch: MAIN
CVS Tags: HEAD
Changes since 1.4: +1 -1 lines
FILE REMOVED
old

(Portage version: 2.2.0_alpha142/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

1 # Copyright 1999-2012 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/media-libs/openimageio/openimageio-1.0.8.ebuild,v 1.4 2012/09/29 15:30:34 blueness Exp $
4
5 EAPI=4
6
7 PYTHON_DEPEND="python? 2:2.7"
8
9 inherit cmake-utils multilib python
10
11 DESCRIPTION="A library for reading and writing images"
12 HOMEPAGE="http://sites.google.com/site/openimageio/ http://github.com/OpenImageIO"
13 SRC_URI="http://github.com/OpenImageIO/oiio/tarball/Release-${PV} -> ${P}.tar.gz"
14
15 LICENSE="BSD"
16 SLOT="0"
17 KEYWORDS="~amd64 ~ppc64 ~x86"
18 IUSE="jpeg2k opengl python qt4 tbb"
19
20 RESTRICT=test #431412
21
22 RDEPEND="dev-libs/boost[python?]
23 dev-libs/pugixml
24 media-libs/glew
25 media-libs/ilmbase
26 media-libs/libpng:0
27 media-libs/libwebp
28 media-libs/openexr
29 media-libs/tiff:0
30 sci-libs/hdf5
31 sys-libs/zlib
32 virtual/jpeg
33 jpeg2k? ( media-libs/openjpeg )
34 opengl? (
35 virtual/glu
36 virtual/opengl
37 )
38 qt4? (
39 x11-libs/qt-core:4
40 x11-libs/qt-gui:4
41 x11-libs/qt-opengl:4
42 )
43 tbb? ( dev-cpp/tbb )"
44 DEPEND="${RDEPEND}"
45
46 S=${WORKDIR}/${P}/src
47
48 pkg_setup() {
49 if use python; then
50 python_set_active_version 2
51 python_pkg_setup
52 fi
53 }
54
55 src_unpack() {
56 unpack ${A}
57 mv OpenImageIO-* "${WORKDIR}"/${P}
58 }
59
60 src_prepare() {
61 # remove bundled code to make it build
62 # https://github.com/OpenImageIO/oiio/issues/403
63 rm */pugixml* || die
64
65 # fix man page building
66 # https://github.com/OpenImageIO/oiio/issues/404
67 use qt4 || sed -i -e '/cli_tools/s:iv ::' doc/CMakeLists.txt
68 }
69
70 src_configure() {
71 local mycmakeargs=(
72 -DLIB_INSTALL_DIR=/usr/$(get_libdir)
73 -DBUILDSTATIC=OFF
74 -DLINKSTATIC=OFF
75 $(use python && echo -DPYLIB_INSTALL_DIR=$(python_get_sitedir))
76 -DUSE_EXTERNAL_PUGIXML=ON
77 -DUSE_FIELD3D=OFF # missing in Portage
78 -DUSE_OCIO=OFF # missing in Portage
79 $(cmake-utils_use_use opengl)
80 $(cmake-utils_use_use jpeg2k OPENJPEG)
81 $(cmake-utils_use_use python)
82 $(cmake-utils_use_use qt4 QT)
83 $(cmake-utils_use_use tbb)
84 )
85
86 cmake-utils_src_configure
87 }
88
89 src_install() {
90 cmake-utils_src_install
91
92 dodoc ../{CHANGES,CREDITS,README} doc/CLA-{CORPORATE,INDIVIDUAL}
93
94 docinto pdf
95 dodoc doc/openimageio.pdf
96 }

  ViewVC Help
Powered by ViewVC 1.1.20