/[gentoo-x86]/media-video/nvidia-settings/nvidia-settings-173.14.31.ebuild
Gentoo

Contents of /media-video/nvidia-settings/nvidia-settings-173.14.31.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.4 - (show annotations) (download)
Tue Jul 24 17:54:10 2012 UTC (2 years, 7 months ago) by idl0r
Branch: MAIN
Changes since 1.3: +2 -2 lines
nvidia-drivers[-gtk] -> nvidia-drivers[-tools]

(Portage version: 2.2.0_alpha120/cvs/Linux x86_64)

1 # Copyright 1999-2012 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/media-video/nvidia-settings/nvidia-settings-173.14.31.ebuild,v 1.3 2012/05/05 14:37:26 idl0r Exp $
4
5 EAPI=4
6
7 inherit eutils multilib toolchain-funcs
8
9 MY_P="${PN}-1.0"
10
11 DESCRIPTION="NVIDIA Linux X11 Settings Utility"
12 HOMEPAGE="http://www.nvidia.com/"
13 SRC_URI="ftp://download.nvidia.com/XFree86/${PN}/${P}.tar.gz"
14
15 LICENSE="GPL-2"
16 SLOT="0"
17 KEYWORDS="-* ~amd64 ~x86 ~x86-fbsd"
18 IUSE="examples"
19
20 COMMON_DEPEND="x11-libs/libX11
21 x11-libs/libXext
22 x11-libs/libXxf86vm[static-libs]
23 x11-libs/gtk+:2
24 x11-libs/gdk-pixbuf[X]
25 media-libs/mesa
26 x11-libs/pango[X]
27 x11-libs/libXv
28 x11-libs/libXrandr
29 dev-libs/glib:2"
30
31 RDEPEND="=x11-drivers/nvidia-drivers-173.14*[-tools]
32 ${COMMON_DEPEND}"
33 DEPEND="${RDEPEND}
34 virtual/pkgconfig
35 x11-proto/xproto"
36
37 S="${WORKDIR}/${MY_P}"
38
39 src_prepare() {
40 epatch "${FILESDIR}/${P}-Makefile.patch"
41 }
42
43 src_compile() {
44 einfo "Building libXNVCtrl..."
45 emake -C src/libXNVCtrl/ clean # NVidia ships pre-built archives :(
46 emake -C src/libXNVCtrl/ CC="$(tc-getCC)" RANLIB="$(tc-getRANLIB)" libXNVCtrl.a
47
48 einfo "Building nvidia-settings..."
49 emake LOCAL_CFLAGS="" CC="$(tc-getCC)" LD="$(tc-getLD)"
50 }
51
52 src_install() {
53 emake prefix="${D}/usr" STRIP="$(type -P true)" install
54
55 insinto /usr/$(get_libdir)
56 doins src/libXNVCtrl/libXNVCtrl.a
57
58 insinto /usr/include/NVCtrl
59 doins src/libXNVCtrl/*.h
60
61 # doicon doc/${PN}.png
62 make_desktop_entry ${PN} "NVIDIA X Server Settings" ${PN} Application
63
64 dodoc doc/*.txt
65
66 if use examples; then
67 docinto examples/
68 dodoc samples/*.c
69 dodoc samples/README
70 fi
71 }

  ViewVC Help
Powered by ViewVC 1.1.20