/[gentoo-x86]/media-video/totem/totem-2.32.0-r2.ebuild
Gentoo

Contents of /media-video/totem/totem-2.32.0-r2.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.12 - (show annotations) (download)
Sat May 5 08:58:51 2012 UTC (2 years, 4 months ago) by jdhore
Branch: MAIN
Changes since 1.11: +2 -2 lines
dev-util/pkgconfig -> virtual/pkgconfig

(Portage version: 2.2.0_alpha101/cvs/Linux i686)

1 # Copyright 1999-2012 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/media-video/totem/totem-2.32.0-r2.ebuild,v 1.11 2012/03/10 16:40:08 pacho Exp $
4
5 EAPI="3"
6 GCONF_DEBUG="yes"
7 PYTHON_DEPEND="python? 2"
8 PYTHON_USE_WITH="threads"
9 PYTHON_USE_WITH_OPT="python"
10
11 inherit autotools eutils gnome2 multilib python
12
13 DESCRIPTION="Media player for GNOME"
14 HOMEPAGE="http://projects.gnome.org/totem/"
15
16 SRC_URI="${SRC_URI} http://dev.gentoo.org/~pacho/gnome/${P}-patches.tar.bz2"
17
18 LICENSE="GPL-2 LGPL-2"
19 SLOT="0"
20 KEYWORDS="alpha amd64 arm ia64 ppc ppc64 sparc x86 ~x86-fbsd"
21
22 IUSE="bluetooth debug doc iplayer lirc nautilus nsplugin python tracker upnp +youtube" #zeroconf
23
24 # TODO:
25 # Cone (VLC) plugin needs someone with the right setup (remi ?)
26 # check gmyth requirement ? -> waiting for updates in tree
27 # vala ( dev-lang/vala ) requires 0.7.5, upstream supports it better in totem-3
28 PYTHON_DEPS=">=dev-python/pygtk-2.12:2
29 dev-python/pyxdg
30 dev-python/gst-python:0.10
31 dev-python/dbus-python
32 dev-python/gconf-python:2"
33 RDEPEND=">=dev-libs/glib-2.25.11:2
34 >=x11-libs/gtk+-2.21.8:2
35 >=gnome-base/gconf-2:2
36 >=dev-libs/totem-pl-parser-2.30.2
37 >=x11-themes/gnome-icon-theme-2.16
38 x11-libs/cairo
39 >=dev-libs/libxml2-2.6:2
40 >=dev-libs/dbus-glib-0.82
41 >=media-libs/gstreamer-0.10.30:0.10
42 >=media-libs/gst-plugins-good-0.10:0.10
43 >=media-libs/gst-plugins-base-0.10.30:0.10
44 >=media-plugins/gst-plugins-gconf-0.10:0.10
45
46 >=media-plugins/gst-plugins-taglib-0.10:0.10
47 >=media-plugins/gst-plugins-gio-0.10:0.10
48 >=media-plugins/gst-plugins-pango-0.10:0.10
49 >=media-plugins/gst-plugins-x-0.10:0.10
50 >=media-plugins/gst-plugins-meta-0.10-r2:0.10
51
52 dev-libs/libunique:1
53 x11-libs/libICE
54 x11-libs/libSM
55 x11-libs/libX11
56 x11-libs/libXtst
57 >=x11-libs/libXrandr-1.1.1
58 >=x11-libs/libXxf86vm-1.0.1
59
60 bluetooth? ( net-wireless/bluez )
61 iplayer? (
62 dev-python/pygobject:2
63 dev-python/pygtk:2
64 dev-python/httplib2
65 dev-python/feedparser
66 dev-python/beautifulsoup )
67 lirc? ( app-misc/lirc )
68 nautilus? ( >=gnome-base/nautilus-2.10 )
69 nsplugin? ( media-plugins/gst-plugins-soup:0.10 )
70 python? ( ${PYTHON_DEPS} )
71 tracker? ( >=app-misc/tracker-0.8.1 )
72 upnp? ( media-video/coherence )
73 youtube? (
74 <dev-libs/libgdata-0.9
75 >=dev-libs/libgdata-0.4
76 net-libs/libsoup:2.4
77 media-plugins/gst-plugins-soup:0.10
78 >=dev-libs/totem-pl-parser-2.32.4[quvi]
79 ${PYTHON_DEPS} )"
80 # vala? ( dev-lang/vala:0.12 )"
81 # FIXME: freezes totem
82 # zeroconf? ( >=net-libs/libepc-0.3 )
83 DEPEND="${RDEPEND}
84 x11-proto/xproto
85 x11-proto/xextproto
86 x11-proto/xf86vidmodeproto
87 app-text/scrollkeeper
88 >=app-text/gnome-doc-utils-0.20.3
89 >=dev-util/intltool-0.40
90 virtual/pkgconfig
91 app-text/docbook-xml-dtd:4.5
92 gnome-base/gnome-common
93 dev-util/gtk-doc-am
94 doc? ( >=dev-util/gtk-doc-1.11 )"
95 # eautoreconf needs:
96 # gnome-base/gnome-common
97 # dev-util/gtk-doc-am
98
99 # docbook-xml-dtd is needed for user doc
100
101 pkg_setup() {
102 DOCS="AUTHORS ChangeLog NEWS README TODO"
103 G2CONF="${G2CONF}
104 --disable-scrollkeeper
105 --disable-schemas-install
106 --disable-static
107 --disable-vala
108 --with-dbus
109 --with-smclient
110 --enable-easy-codec-installation
111 $(use_enable nsplugin browser-plugins)"
112
113 # Plugin configuration
114 G2CONF="${G2CONF}
115 BROWSER_PLUGIN_DIR=/usr/$(get_libdir)/nsbrowser/plugins
116 PLUGINDIR=/usr/$(get_libdir)/totem/plugins"
117
118 local plugins="properties,thumbnail,screensaver,ontop,gromit,media-player-keys,skipto,brasero-disc-recorder,screenshot,chapters"
119 use bluetooth && plugins="${plugins},bemused"
120 use iplayer && plugins="${plugins},iplayer"
121 use lirc && plugins="${plugins},lirc"
122 use python && plugins="${plugins},opensubtitles,jamendo,pythonconsole,dbus-service"
123 use tracker && plugins="${plugins},tracker"
124 use upnp && plugins="${plugins},coherence_upnp"
125 use youtube && plugins="${plugins},youtube"
126 #use vala && plugins="${plugins},sample-vala"
127 #use zeroconf && plugins="${plugins},publish"
128
129 G2CONF="${G2CONF} --with-plugins=${plugins}"
130
131 G2CONF="${G2CONF}
132 $(use_enable debug)
133 $(use_enable nautilus)
134 $(use_enable python)"
135
136 # We need to --enable-python to make youtube plugin work as reported in bug #316409
137 # This won't be solved until upstream fixes their bug #572713
138 use youtube && G2CONF="${G2CONF} --enable-python"
139
140 python_set_active_version 2
141 }
142
143 src_prepare() {
144 # Use fixed gnome-doc-utils.make, bug #348403 (can be dropped in next bump)
145 cp -f /usr/share/gnome-doc-utils/gnome-doc-utils.make . || die
146
147 # Fix broken smclient option passing
148 epatch "${FILESDIR}/${PN}-2.32.0-smclient-target-detection.patch"
149
150 # Apply multiple backports and fixes from master and 2.32 branch
151 epatch "${WORKDIR}/${P}-patches"/*.patch
152
153 intltoolize --force --copy --automake || die "intltoolize failed"
154 eautoreconf
155
156 gnome2_src_prepare
157
158 # disable pyc compiling
159 echo > py-compile
160 }
161
162 src_configure() {
163 # FIXME: why does it need write access here, probably need to set up a fake
164 # home in /var/tmp like other pkgs do
165
166 addpredict "$(unset HOME; echo ~)/.gconf"
167 addpredict "$(unset HOME; echo ~)/.gconfd"
168 addpredict "$(unset HOME; echo ~)/.gnome2"
169
170 unset DBUS_SESSION_BUS_ADDRESS
171 gnome2_src_configure
172 }
173
174 src_install() {
175 gnome2_src_install
176 # Installed for plugins, but they're dlopen()-ed
177 # firefox, totem as well as nautilus
178 find "${ED}" -name "*.la" -delete || die "remove of la files failed"
179
180 # Fix python script shebangs
181 python_convert_shebangs 2 "${ED}"/usr/libexec/totem/totem-bugreport.py
182 }
183
184 pkg_postinst() {
185 gnome2_pkg_postinst
186 if use python; then
187 python_need_rebuild
188 python_mod_optimize /usr/$(get_libdir)/totem/plugins
189 fi
190
191 ewarn
192 ewarn "If totem doesn't play some video format, please check your"
193 ewarn "USE flags on media-plugins/gst-plugins-meta"
194 ewarn
195 }
196
197 pkg_postrm() {
198 gnome2_pkg_postrm
199 use python && python_mod_cleanup /usr/$(get_libdir)/totem/plugins
200 }

  ViewVC Help
Powered by ViewVC 1.1.20