/[gentoo-x86]/media-video/vlc/vlc-9999.ebuild
Gentoo

Contents of /media-video/vlc/vlc-9999.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.109 - (show annotations) (download)
Wed Feb 16 16:55:07 2011 UTC (3 years, 7 months ago) by aballier
Branch: MAIN
Changes since 1.108: +4 -2 lines
Add linsys useflag

(Portage version: 2.2.0_alpha24/cvs/Linux x86_64)

1 # Copyright 1999-2011 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/media-video/vlc/vlc-9999.ebuild,v 1.108 2011/02/16 16:18:20 aballier Exp $
4
5 EAPI="4"
6
7 SCM=""
8 if [ "${PV%9999}" != "${PV}" ] ; then
9 SCM=git
10 EGIT_BOOTSTRAP="bootstrap"
11 EGIT_BRANCH=master
12 EGIT_PROJECT=${P}
13 if [ "${PV%.9999}" != "${PV}" ] ; then
14 EGIT_REPO_URI="git://git.videolan.org/vlc/vlc-${PV%.9999}.git"
15 else
16 EGIT_REPO_URI="git://git.videolan.org/vlc.git"
17 fi
18 fi
19
20 inherit eutils multilib autotools toolchain-funcs flag-o-matic ${SCM}
21
22 MY_PV="${PV/_/-}"
23 MY_PV="${MY_PV/-beta/-test}"
24 MY_P="${PN}-${MY_PV}"
25
26 PATCHLEVEL="89"
27 DESCRIPTION="VLC media player - Video player and streamer"
28 HOMEPAGE="http://www.videolan.org/vlc/"
29 if [ "${PV%9999}" != "${PV}" ] ; then # Live ebuild
30 SRC_URI=""
31 elif [[ "${MY_P}" == "${P}" ]]; then
32 SRC_URI="http://download.videolan.org/pub/videolan/${PN}/${PV}/${P}.tar.bz2"
33 else
34 SRC_URI="http://download.videolan.org/pub/videolan/testing/${MY_P}/${MY_P}.tar.bz2"
35 fi
36
37 SRC_URI="${SRC_URI}
38 mirror://gentoo/${PN}-patches-${PATCHLEVEL}.tar.bz2"
39
40 LICENSE="GPL-2"
41 SLOT="0"
42
43 if [ "${PV%9999}" = "${PV}" ] ; then
44 KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
45 else
46 KEYWORDS=""
47 fi
48 IUSE="a52 aac aalib alsa altivec atmo avahi bidi cdda cddb dbus dc1394
49 debug dirac directfb dts dvb dvd elibc_glibc +encode fbcon fluidsynth +ffmpeg flac fontconfig
50 +gcrypt gme gnome gnutls growl httpd ieee1394 jack kate kde libass libcaca
51 libnotify libproxy libtiger libv4l2 linsys lirc live lua matroska mmx
52 modplug mp3 mpeg mtp musepack ncurses ogg opengl optimisememory oss
53 png projectm pulseaudio pvr +qt4 rtsp run-as-root samba
54 schroedinger sdl sdl-image shine shout sid skins speex sqlite sse
55 svg taglib theora truetype twolame udev upnp v4l2 vaapi vcdx vlm
56 vorbis win32codecs wma-fixed +X x264 +xcb xml xosd xv zvbi"
57
58 RDEPEND="
59 sys-libs/zlib
60 >=media-libs/libdvbpsi-0.1.6
61 a52? ( >=media-libs/a52dec-0.7.4-r3 )
62 aalib? ( media-libs/aalib )
63 aac? ( >=media-libs/faad2-2.6.1 )
64 alsa? ( >=media-libs/alsa-lib-1.0.23 )
65 avahi? ( >=net-dns/avahi-0.6[dbus] )
66 bidi? ( >=dev-libs/fribidi-0.10.4 )
67 cddb? ( >=media-libs/libcddb-1.2.0 )
68 dbus? ( >=sys-apps/dbus-1.0.2 )
69 dc1394? ( >=sys-libs/libraw1394-2.0.1 >=media-libs/libdc1394-2.0.2 )
70 dirac? ( >=media-video/dirac-0.10.0 )
71 directfb? ( dev-libs/DirectFB sys-libs/zlib )
72 dts? ( media-libs/libdca )
73 dvd? ( media-libs/libdvdread >=media-libs/libdvdnav-0.1.9 )
74 elibc_glibc? ( >=sys-libs/glibc-2.8 )
75 ffmpeg? ( >=media-video/ffmpeg-0.6 )
76 flac? ( media-libs/libogg >=media-libs/flac-1.1.2 )
77 fluidsynth? ( media-sound/fluidsynth )
78 fontconfig? ( media-libs/fontconfig )
79 gcrypt? ( >=dev-libs/libgcrypt-1.2.0 )
80 gme? ( media-libs/game-music-emu )
81 gnome? ( gnome-base/gnome-vfs )
82 gnutls? ( >=net-libs/gnutls-1.7.4 )
83 ieee1394? ( >=sys-libs/libraw1394-2.0.1 >=sys-libs/libavc1394-0.5.3 )
84 jack? ( >=media-sound/jack-audio-connection-kit-0.99.0-r1 )
85 kate? ( >=media-libs/libkate-0.1.1 )
86 libass? ( >=media-libs/libass-0.9.6 media-libs/fontconfig )
87 libcaca? ( >=media-libs/libcaca-0.99_beta14 )
88 libnotify? ( x11-libs/libnotify x11-libs/gtk+:2 )
89 libproxy? ( net-libs/libproxy )
90 libtiger? ( media-libs/libtiger )
91 linsys? ( >=media-libs/zvbi-0.2.28 )
92 lirc? ( app-misc/lirc )
93 live? ( >=media-plugins/live-2010.10.15 )
94 lua? ( >=dev-lang/lua-5.1 )
95 matroska? ( >=dev-libs/libebml-1.0.0 >=media-libs/libmatroska-1.0.0 )
96 modplug? ( >=media-libs/libmodplug-0.8.8.1 )
97 mp3? ( media-libs/libmad )
98 mpeg? ( >=media-libs/libmpeg2-0.3.2 )
99 mtp? ( >=media-libs/libmtp-1.0.0 )
100 musepack? ( >=media-sound/musepack-tools-444 )
101 ncurses? ( sys-libs/ncurses )
102 ogg? ( media-libs/libogg )
103 opengl? ( virtual/opengl || ( >=x11-libs/libX11-1.3.99.901 <x11-libs/libX11-1.3.99.901[xcb] ) )
104 png? ( media-libs/libpng sys-libs/zlib )
105 projectm? ( media-libs/libprojectm )
106 pulseaudio? ( >=media-sound/pulseaudio-0.9.22 )
107 qt4? ( x11-libs/qt-gui:4 x11-libs/qt-core:4 )
108 samba? ( || ( >=net-fs/samba-3.4.6[smbclient] <net-fs/samba-3.4 ) )
109 schroedinger? ( >=media-libs/schroedinger-1.0.6 )
110 sdl? ( >=media-libs/libsdl-1.2.8
111 sdl-image? ( media-libs/sdl-image sys-libs/zlib ) )
112 shout? ( media-libs/libshout )
113 sid? ( media-libs/libsidplay:2 )
114 speex? ( media-libs/speex )
115 sqlite? ( >=dev-db/sqlite-3.6.0:3 )
116 svg? ( >=gnome-base/librsvg-2.9.0 )
117 taglib? ( >=media-libs/taglib-1.5 sys-libs/zlib )
118 theora? ( >=media-libs/libtheora-1.0_beta3 )
119 truetype? ( media-libs/freetype media-fonts/dejavu )
120 twolame? ( media-sound/twolame )
121 udev? ( >=sys-fs/udev-142 )
122 upnp? ( net-libs/libupnp )
123 libv4l2? ( media-libs/libv4l )
124 vaapi? ( x11-libs/libva )
125 vcdx? ( >=dev-libs/libcdio-0.78.2 >=media-video/vcdimager-0.7.22 )
126 vorbis? ( media-libs/libvorbis )
127 win32codecs? ( media-libs/win32codecs )
128 X? ( x11-libs/libX11 )
129 x264? ( >=media-libs/x264-0.0.20090923 )
130 xcb? ( x11-libs/libxcb x11-libs/xcb-util )
131 xml? ( dev-libs/libxml2 )
132 xosd? ( x11-libs/xosd )
133 zvbi? ( >=media-libs/zvbi-0.2.25 )
134 "
135
136 DEPEND="${RDEPEND}
137 !!<=media-video/vlc-1.1.99999
138 alsa? ( >=media-sound/alsa-headers-1.0.23 )
139 dvb? ( sys-kernel/linux-headers )
140 kde? ( >=kde-base/kdelibs-4 )
141 v4l2? ( >=sys-kernel/linux-headers-2.6.25 )
142 xcb? ( x11-proto/xproto )
143 dev-util/pkgconfig"
144
145 REQUIRED_USE="
146 bidi? ( truetype )
147 cddb? ( cdda )
148 fontconfig? ( truetype )
149 gnutls? ( gcrypt )
150 libtiger? ( kate )
151 libv4l2? ( v4l2 )
152 qt4? ( X )
153 skins? ( truetype qt4 )
154 vaapi? ( ffmpeg )
155 vlm? ( encode )
156 xv? ( xcb )
157 "
158
159 S="${WORKDIR}/${MY_P}"
160
161 src_unpack() {
162 unpack ${A}
163 if [ "${PV%9999}" != "${PV}" ] ; then
164 git_src_unpack
165 fi
166 }
167
168 src_prepare() {
169 if [ "${PV%9999}" != "${PV}" ] ; then
170 git_src_prepare
171 fi
172 # Make it build with libtool 1.5
173 rm -f m4/lt* m4/libtool.m4
174
175 EPATCH_SUFFIX="patch" epatch "${WORKDIR}/patches"
176 eautoreconf
177 }
178
179 src_configure() {
180 # needs libresid-builder from libsidplay:2 which is in another directory...
181 # FIXME!
182 use sid && append-ldflags "-L/usr/$(get_libdir)/sidplay/builders/"
183
184 econf \
185 --docdir=/usr/share/doc/${PF} \
186 $(use_enable a52) \
187 $(use_enable aalib aa) \
188 $(use_enable aac faad) \
189 $(use_enable alsa) \
190 $(use_enable altivec) \
191 $(use_enable atmo) \
192 $(use_enable avahi bonjour) \
193 $(use_enable bidi fribidi) \
194 $(use_enable cdda vcd) \
195 $(use_enable cddb libcddb) \
196 $(use_enable dbus) $(use_enable dbus dbus-control) \
197 $(use_enable dirac) \
198 $(use_enable directfb) \
199 $(use_enable dc1394) \
200 $(use_enable debug) \
201 $(use_enable dts dca) \
202 $(use_enable dvb) \
203 $(use_enable dvd dvdread) $(use_enable dvd dvdnav) \
204 $(use_enable encode sout) \
205 $(use_enable fbcon fb) \
206 $(use_enable ffmpeg avcodec) $(use_enable ffmpeg avformat) $(use_enable ffmpeg swscale) $(use_enable ffmpeg postproc) \
207 $(use_enable flac) \
208 $(use_enable fluidsynth) \
209 $(use_enable fontconfig) \
210 $(use_enable gme) \
211 $(use_enable gnome gnomevfs) \
212 $(use_enable gnutls) \
213 $(use_enable growl) \
214 $(use_enable httpd) \
215 $(use_enable ieee1394 dv) \
216 $(use_enable jack) \
217 $(use_enable kate) \
218 $(use_with kde kde-solid) \
219 $(use_enable libass) \
220 $(use_enable libcaca caca) \
221 $(use_enable gcrypt libgcrypt) \
222 $(use_enable libnotify notify) \
223 $(use_enable libproxy) \
224 --disable-libtar \
225 $(use_enable libtiger tiger) \
226 $(use_enable libv4l2) \
227 $(use_enable linsys) \
228 $(use_enable lirc) \
229 $(use_enable live live555) \
230 $(use_enable lua) \
231 $(use_enable matroska mkv) \
232 $(use_enable mmx) \
233 $(use_enable modplug mod) \
234 $(use_enable mp3 mad) \
235 $(use_enable mpeg libmpeg2) \
236 $(use_enable mtp) \
237 $(use_enable musepack mpc) \
238 $(use_enable ncurses) \
239 $(use_enable ogg) \
240 $(use_enable opengl glx) \
241 $(use_enable optimisememory optimize-memory) \
242 $(use_enable oss) \
243 $(use_enable png) \
244 --disable-portaudio \
245 $(use_enable projectm) \
246 $(use_enable pulseaudio pulse) \
247 $(use_enable pvr) \
248 $(use_enable qt4) \
249 $(use_enable rtsp realrtsp) \
250 $(use_enable run-as-root) \
251 $(use_enable samba smb) \
252 $(use_enable schroedinger) \
253 $(use_enable sdl) \
254 $(use_enable sdl-image) \
255 $(use_enable shine) \
256 $(use_enable sid) \
257 $(use_enable shout) \
258 $(use_enable skins skins2) \
259 $(use_enable speex) \
260 $(use_enable sqlite) \
261 $(use_enable sse) \
262 $(use_enable svg) \
263 $(use_enable taglib) \
264 $(use_enable theora) \
265 $(use_enable truetype freetype) \
266 $(use_enable twolame) \
267 $(use_enable udev) \
268 $(use_enable upnp) \
269 $(use_enable v4l2) \
270 $(use_enable vcdx) \
271 $(use_enable vaapi libva) \
272 $(use_enable vlm) \
273 $(use_enable vorbis) \
274 $(use_enable win32codecs loader) \
275 $(use_enable wma-fixed) \
276 $(use_with X x) \
277 $(use_enable x264) \
278 $(use_enable xcb) \
279 $(use_enable xml libxml2) \
280 $(use_enable xosd) \
281 $(use_enable xv xvideo) \
282 $(use_enable zvbi) $(use_enable !zvbi telx) \
283 --disable-snapshot \
284 --disable-optimizations \
285 --enable-fast-install
286 }
287
288 src_install() {
289 emake DESTDIR="${D}" install || die "make install failed"
290
291 dodoc AUTHORS HACKING THANKS NEWS README \
292 doc/fortunes.txt doc/intf-vcd.txt
293
294 # Punt useless libtool's .la files
295 find "${D}" -name '*.la' -delete
296 }
297
298 pkg_postinst() {
299 if [ "$ROOT" = "/" ] && [ -x "/usr/$(get_libdir)/vlc/vlc-cache-gen" ] ; then
300 einfo "Running /usr/$(get_libdir)/vlc/vlc-cache-gen on /usr/$(get_libdir)/vlc/plugins/"
301 "/usr/$(get_libdir)/vlc/vlc-cache-gen" -f "/usr/$(get_libdir)/vlc/plugins/"
302 else
303 ewarn "We cannot run vlc-cache-gen (most likely ROOT!=/)"
304 ewarn "Please run /usr/$(get_libdir)/vlc/vlc-cache-gen manually"
305 ewarn "If you do not do it, vlc will take a long time to load."
306 fi
307 }

  ViewVC Help
Powered by ViewVC 1.1.20