/[gentoo-x86]/media-video/vlc/vlc-9999.ebuild
Gentoo

Contents of /media-video/vlc/vlc-9999.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.69 - (show annotations) (download)
Fri Apr 23 16:18:09 2010 UTC (4 years, 4 months ago) by aballier
Branch: MAIN
Changes since 1.68: +25 -16 lines
Simplify vlc_use_enable_force here too, fix some useflags deps, require dbus on avahi for avahi-client
(Portage version: 2.2_rc67/cvs/Linux x86_64)

1 # Copyright 1999-2010 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/media-video/vlc/vlc-1.1.0_pre2.ebuild,v 1.1 2010/04/22 19:26:40 aballier Exp $
4
5 EAPI="2"
6
7 SCM=""
8 if [ "${PV%9999}" != "${PV}" ] ; then
9 SCM=git
10 EGIT_BOOTSTRAP="bootstrap"
11 EGIT_BRANCH=master
12 EGIT_PROJECT=${P}
13 if [ "${PV%.9999}" != "${PV}" ] ; then
14 EGIT_REPO_URI="git://git.videolan.org/vlc/vlc-${PV%.9999}.git"
15 else
16 EGIT_REPO_URI="git://git.videolan.org/vlc.git"
17 fi
18 fi
19
20 inherit eutils multilib autotools toolchain-funcs gnome2 nsplugins qt4 flag-o-matic ${SCM}
21
22 MY_PV="${PV/_/-}"
23 MY_PV="${MY_PV/-beta/-test}"
24 MY_P="${PN}-${MY_PV}"
25 VLC_SNAPSHOT_TIME="0013"
26
27 PATCHLEVEL="85"
28 DESCRIPTION="VLC media player - Video player and streamer"
29 HOMEPAGE="http://www.videolan.org/vlc/"
30 if [ "${PV%9999}" != "${PV}" ] ; then # Live ebuild
31 SRC_URI=""
32 elif [[ "${P}" == *_alpha* ]]; then # Snapshots taken from nightlies.videolan.org
33 SRC_URI="http://nightlies.videolan.org/build/source/trunk-${PV/*_alpha/}-${VLC_SNAPSHOT_TIME}/${PN}-snapshot-${PV/*_alpha/}.tar.bz2"
34 MY_P="${P/_alpha*/}-git"
35 elif [[ "${MY_P}" == "${P}" ]]; then
36 SRC_URI="http://download.videolan.org/pub/videolan/${PN}/${PV}/${P}.tar.bz2"
37 else
38 SRC_URI="http://download.videolan.org/pub/videolan/testing/${MY_P}/${MY_P}.tar.bz2"
39 fi
40
41 SRC_URI="${SRC_URI}
42 mirror://gentoo/${PN}-patches-${PATCHLEVEL}.tar.bz2"
43
44 LICENSE="GPL-2"
45 SLOT="0"
46
47 KEYWORDS=""
48 IUSE="a52 aac aalib alsa altivec atmo avahi bidi cdda cddb dbus dc1394
49 debug dirac directfb dts dvb dvd elibc_glibc fbcon fluidsynth +ffmpeg flac fontconfig
50 +gcrypt ggi gnome gnutls httpd id3tag ieee1394 jack kate kde libass libcaca
51 libnotify libproxy libtiger libv4l libv4l2 lirc live lua matroska mmx
52 modplug mp3 mpeg mtp musepack ncurses nsplugin ogg opengl optimisememory oss
53 png projectm pulseaudio pvr +qt4 remoteosd rtsp run-as-root samba
54 schroedinger sdl sdl-image shine shout skins speex sqlite sse stream
55 svg svga taglib theora truetype twolame udev upnp v4l v4l2 vcdx vlm
56 vorbis win32codecs wma-fixed x264 +xcb xml xosd xv zvbi"
57
58 RDEPEND="
59 !!<=media-video/vlc-1.0.99999
60 sys-libs/zlib
61 >=media-libs/libdvbpsi-0.1.6
62 a52? ( >=media-libs/a52dec-0.7.4-r3 )
63 aalib? ( media-libs/aalib )
64 aac? ( >=media-libs/faad2-2.6.1 )
65 alsa? ( media-libs/alsa-lib )
66 avahi? ( >=net-dns/avahi-0.6[dbus] )
67 bidi? ( >=dev-libs/fribidi-0.10.4 )
68 cdda? ( cddb? ( >=media-libs/libcddb-1.2.0 ) )
69 dbus? ( >=sys-apps/dbus-1.0.2 )
70 dc1394? ( >=sys-libs/libraw1394-2.0.1
71 >=media-libs/libdc1394-2.0.2 )
72 dirac? ( >=media-video/dirac-0.10.0 )
73 directfb? ( dev-libs/DirectFB sys-libs/zlib )
74 dts? ( media-libs/libdca )
75 dvd? ( media-libs/libdvdread
76 >=media-libs/libdvdnav-0.1.9
77 media-libs/libdvdplay )
78 elibc_glibc? ( >=sys-libs/glibc-2.8 )
79 ffmpeg? ( >=media-video/ffmpeg-0.4.9_p20090201 )
80 flac? ( media-libs/libogg
81 >=media-libs/flac-1.1.2 )
82 fluidsynth? ( media-sound/fluidsynth )
83 fontconfig? ( media-libs/fontconfig )
84 gcrypt? ( >=dev-libs/libgcrypt-1.2.0 )
85 ggi? ( media-libs/libggi )
86 gnome? ( gnome-base/gnome-vfs )
87 gnutls? ( >=net-libs/gnutls-1.7.4 )
88 id3tag? ( media-libs/libid3tag sys-libs/zlib )
89 ieee1394? ( >=sys-libs/libraw1394-2.0.1 >=sys-libs/libavc1394-0.5.3 )
90 jack? ( >=media-sound/jack-audio-connection-kit-0.99.0-r1 )
91 kate? ( >=media-libs/libkate-0.1.1 )
92 libass? ( >=media-libs/libass-0.9.6 media-libs/fontconfig )
93 libcaca? ( >=media-libs/libcaca-0.99_beta14 )
94 libnotify? ( x11-libs/libnotify )
95 libproxy? ( net-libs/libproxy )
96 libtiger? ( media-libs/libtiger )
97 lirc? ( app-misc/lirc )
98 live? ( >=media-plugins/live-2008.07.06 )
99 lua? ( >=dev-lang/lua-5.1 )
100 matroska? (
101 >=dev-libs/libebml-0.7.6
102 >=media-libs/libmatroska-0.8.0 )
103 modplug? ( >=media-libs/libmodplug-0.8 )
104 mp3? ( media-libs/libmad )
105 mpeg? ( >=media-libs/libmpeg2-0.3.2 )
106 mtp? ( >=media-libs/libmtp-0.3.0 )
107 musepack? ( >=media-sound/musepack-tools-444 )
108 ncurses? ( sys-libs/ncurses )
109 nsplugin? ( >=net-libs/xulrunner-1.9.2 x11-libs/libXpm x11-libs/libXt )
110 ogg? ( media-libs/libogg )
111 opengl? ( virtual/opengl )
112 png? ( media-libs/libpng sys-libs/zlib )
113 projectm? ( media-libs/libprojectm )
114 pulseaudio? ( >=media-sound/pulseaudio-0.9.11 )
115 qt4? ( x11-libs/qt-gui:4 x11-libs/qt-core:4 x11-libs/libX11 )
116 remoteosd? ( >=dev-libs/libgcrypt-1.2.0 )
117 samba? ( || ( >=net-fs/samba-3.4.6[smbclient]
118 <net-fs/samba-3.4 ) )
119 schroedinger? ( >=media-libs/schroedinger-1.0.6 )
120 sdl? ( >=media-libs/libsdl-1.2.8
121 sdl-image? ( media-libs/sdl-image sys-libs/zlib ) )
122 shout? ( media-libs/libshout )
123 skins? (
124 x11-libs/qt-gui:4 x11-libs/qt-core:4
125 x11-libs/libXext x11-libs/libX11
126 media-libs/freetype media-fonts/dejavu
127 )
128 speex? ( media-libs/speex )
129 sqlite? ( >=dev-db/sqlite-3.6.0:3 )
130 svg? ( >=gnome-base/librsvg-2.9.0 )
131 svga? ( media-libs/svgalib )
132 taglib? ( >=media-libs/taglib-1.5 sys-libs/zlib )
133 theora? ( >=media-libs/libtheora-1.0_beta3 )
134 truetype? ( media-libs/freetype
135 media-fonts/dejavu )
136 twolame? ( media-sound/twolame )
137 udev? ( >=sys-fs/udev-142 )
138 upnp? ( net-libs/libupnp )
139 v4l2? ( libv4l2? ( media-libs/libv4l ) )
140 v4l? ( libv4l? ( media-libs/libv4l ) )
141 vcdx? ( >=dev-libs/libcdio-0.78.2 >=media-video/vcdimager-0.7.22 )
142 vorbis? ( media-libs/libvorbis )
143 win32codecs? ( media-libs/win32codecs )
144 x264? ( >=media-libs/x264-0.0.20090923 )
145 xcb? ( x11-libs/libxcb x11-libs/xcb-util )
146 xml? ( dev-libs/libxml2 )
147 xosd? ( x11-libs/xosd )
148 zvbi? ( >=media-libs/zvbi-0.2.25 )
149 "
150
151 DEPEND="${RDEPEND}
152 dvb? ( sys-kernel/linux-headers )
153 kde? ( >=kde-base/kdelibs-4 )
154 v4l? ( sys-kernel/linux-headers )
155 v4l2? ( >=sys-kernel/linux-headers-2.6.25 )
156 xcb? ( x11-proto/xproto )
157 dev-util/pkgconfig"
158
159 S="${WORKDIR}/${MY_P}"
160
161 # Displays a warning if the first use flag is set but the second is not
162 vlc_use_needs() {
163 use $1 && use !$2 && ewarn "USE=$1 requires $2, $1 will be disabled."
164 }
165
166 # Notify the user that some useflag have been forced on
167 vlc_use_force() {
168 use $1 && use !$2 && ewarn "USE=$1 requires $2, $2 will be enabled."
169 }
170
171 # Use when $1 depends strictly on $2
172 # if use $1 then enable $2
173 vlc_use_enable_force() {
174 use $1 && echo "--enable-$2"
175 }
176
177 pkg_setup() {
178 if has_version '<=media-video/vlc-1.0.99999'; then
179 eerror "Please unmerge vlc-1.0.x first before installing ${P}"
180 eerror "If you don't do that, some plugins will get linked against"
181 eerror "the old ${PN} version and will not work."
182 die "Unmerge vlc 1.0.x first"
183 fi
184
185 # Useflags we need to forcefuly enable
186 vlc_use_force remoteosd gcrypt
187 vlc_use_force skins truetype
188 vlc_use_force skins qt4
189 vlc_use_force vlm stream
190
191 # Useflags that will be automagically discarded if deps are not met
192 vlc_use_needs bidi truetype
193 vlc_use_needs cddb cdda
194 vlc_use_needs fontconfig truetype
195 vlc_use_needs libv4l2 v4l2
196 vlc_use_needs libv4l v4l
197 vlc_use_needs libtiger kate
198 vlc_use_needs xv xcb
199
200 if use qt4 || use skins ; then
201 qt4_pkg_setup
202 else
203 ewarn "You have disabled the qt4 useflag, ${PN} will not have any"
204 ewarn "graphical interface. Maybe that is not what you want..."
205 fi
206 }
207
208 src_unpack() {
209 unpack ${A}
210 if [ "${PV%9999}" != "${PV}" ] ; then
211 git_src_unpack
212 fi
213 }
214
215 src_prepare() {
216 if [ "${PV%9999}" != "${PV}" ] ; then
217 git_src_prepare
218 fi
219 # Make it build with libtool 1.5
220 rm -f m4/lt* m4/libtool.m4
221
222 EPATCH_SUFFIX="patch" epatch "${WORKDIR}/patches"
223 eautoreconf
224 }
225
226 src_configure() {
227
228 # It would fail if -fforce-addr is used due to too few registers...
229 use x86 && filter-flags -fforce-addr
230
231 econf \
232 $(use_enable a52) \
233 $(use_enable aalib aa) \
234 $(use_enable aac faad) \
235 $(use_enable alsa) \
236 $(use_enable altivec) \
237 --disable-asademux \
238 $(use_enable atmo) \
239 $(use_enable avahi bonjour) \
240 $(use_enable bidi fribidi) \
241 $(use_enable cdda vcd) \
242 $(use_enable cddb libcddb) \
243 $(use_enable dbus) $(use_enable dbus dbus-control) \
244 $(use_enable dirac) \
245 $(use_enable directfb) \
246 $(use_enable dc1394) \
247 $(use_enable debug) \
248 $(use_enable dts dca) \
249 $(use_enable dvb) \
250 $(use_enable dvd dvdread) $(use_enable dvd dvdnav) \
251 $(use_enable fbcon fb) \
252 $(use_enable ffmpeg avcodec) $(use_enable ffmpeg avformat) $(use_enable ffmpeg swscale) $(use_enable ffmpeg postproc) \
253 $(use_enable flac) \
254 $(use_enable fluidsynth) \
255 $(use_enable fontconfig) \
256 $(use_enable ggi) \
257 $(use_enable gnome gnomevfs) \
258 $(use_enable gnutls) \
259 $(use_enable httpd) \
260 $(use_enable id3tag) \
261 $(use_enable ieee1394 dv) \
262 $(use_enable jack) \
263 $(use_enable kate) \
264 $(use_with kde kde-solid) \
265 $(use_enable libass) \
266 $(use_enable libcaca caca) \
267 $(use_enable gcrypt libgcrypt) \
268 $(use_enable libnotify notify) \
269 $(use_enable libproxy) \
270 --disable-libtar \
271 $(use_enable libtiger tiger) \
272 $(use_enable libv4l) \
273 $(use_enable libv4l2) \
274 $(use_enable lirc) \
275 $(use_enable live live555) \
276 $(use_enable lua) \
277 $(use_enable matroska mkv) \
278 $(use_enable mmx) \
279 $(use_enable modplug mod) \
280 $(use_enable mp3 mad) \
281 $(use_enable mpeg libmpeg2) \
282 $(use_enable mtp) \
283 $(use_enable musepack mpc) \
284 $(use_enable ncurses) \
285 $(use_enable nsplugin mozilla) --with-mozilla-pkg=libxul \
286 $(use_enable ogg) \
287 $(use_enable opengl glx) $(use_enable opengl) \
288 $(use_enable optimisememory optimize-memory) \
289 $(use_enable oss) \
290 $(use_enable png) \
291 --disable-portaudio \
292 $(use_enable projectm) \
293 $(use_enable pulseaudio pulse) \
294 $(use_enable pvr) \
295 $(use_enable qt4) \
296 $(use_enable remoteosd) \
297 $(use_enable rtsp realrtsp) \
298 $(use_enable run-as-root) \
299 $(use_enable samba smb) \
300 $(use_enable schroedinger) \
301 $(use_enable sdl) \
302 $(use_enable sdl-image) \
303 $(use_enable shine) \
304 $(use_enable shout) \
305 $(use_enable skins skins2) \
306 $(use_enable speex) \
307 $(use_enable sqlite) \
308 $(use_enable sse) \
309 $(use_enable stream sout) \
310 $(use_enable svg) \
311 $(use_enable svga svgalib) \
312 $(use_enable taglib) \
313 $(use_enable theora) \
314 $(use_enable truetype freetype) \
315 $(use_enable twolame) \
316 $(use_enable udev) \
317 $(use_enable upnp) \
318 $(use_enable v4l) \
319 $(use_enable v4l2) \
320 $(use_enable vcdx) \
321 $(use_enable vlm) \
322 $(use_enable vorbis) \
323 $(use_enable win32codecs loader) \
324 $(use_enable wma-fixed) \
325 $(use_enable x264) \
326 $(use_enable xcb) \
327 $(use_enable xml libxml2) \
328 $(use_enable xosd) \
329 $(use_enable xv xvideo) \
330 $(use_enable zvbi) $(use_enable !zvbi telx) \
331 --disable-snapshot \
332 --disable-growl \
333 --disable-optimizations \
334 --enable-fast-install \
335 $(vlc_use_enable_force vlm sout) \
336 $(vlc_use_enable_force skins qt4) \
337 $(vlc_use_enable_force skins freetype) \
338 $(vlc_use_enable_force remoteosd libgcrypt)
339 }
340
341 src_install() {
342 emake DESTDIR="${D}" install || die "make install failed"
343
344 dodoc AUTHORS HACKING THANKS NEWS README \
345 doc/fortunes.txt doc/intf-vcd.txt
346
347 rm -rf "${D}/usr/share/doc/vlc" \
348 "${D}"/usr/share/vlc/vlc{16x16,32x32,48x48,128x128}.{png,xpm,ico}
349
350 if use nsplugin; then
351 dodir "/usr/$(get_libdir)/${PLUGINS_DIR}"
352 mv "${D}"/usr/$(get_libdir)/mozilla/plugins/* \
353 "${D}/usr/$(get_libdir)/${PLUGINS_DIR}/"
354 fi
355
356 use skins || rm -rf "${D}/usr/share/vlc/skins2"
357
358 for res in 16 32 48; do
359 insinto /usr/share/icons/hicolor/${res}x${res}/apps/
360 newins "${S}"/share/vlc${res}x${res}.png vlc.png
361 done
362 }
363
364 pkg_postinst() {
365 gnome2_pkg_postinst
366
367 if [ "$ROOT" = "/" ] && [ -x "/usr/$(get_libdir)/vlc/vlc-cache-gen" ] ; then
368 einfo "Running /usr/$(get_libdir)/vlc/vlc-cache-gen on /usr/$(get_libdir)/vlc/plugins/"
369 "/usr/$(get_libdir)/vlc/vlc-cache-gen" "/usr/$(get_libdir)/vlc/plugins/"
370 else
371 ewarn "We cannot run vlc-cache-gen (most likely ROOT!=/)"
372 ewarn "Please run /usr/$(get_libdir)/vlc/vlc-cache-gen manually"
373 ewarn "If you do not do it, vlc will take a long time to load."
374 fi
375 }

  ViewVC Help
Powered by ViewVC 1.1.20