/[gentoo-x86]/media-video/vlc/vlc-9999.ebuild
Gentoo

Contents of /media-video/vlc/vlc-9999.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.87 - (show annotations) (download)
Wed Jul 21 07:52:42 2010 UTC (4 years, 4 months ago) by aballier
Branch: MAIN
Changes since 1.86: +3 -3 lines
bump ffmpeg requirement
(Portage version: 2.2_rc67/cvs/Linux x86_64)

1 # Copyright 1999-2010 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/media-video/vlc/vlc-9999.ebuild,v 1.86 2010/07/20 07:38:47 aballier Exp $
4
5 EAPI="3"
6
7 SCM=""
8 if [ "${PV%9999}" != "${PV}" ] ; then
9 SCM=git
10 EGIT_BOOTSTRAP="bootstrap"
11 EGIT_BRANCH=master
12 EGIT_PROJECT=${P}
13 if [ "${PV%.9999}" != "${PV}" ] ; then
14 EGIT_REPO_URI="git://git.videolan.org/vlc/vlc-${PV%.9999}.git"
15 else
16 EGIT_REPO_URI="git://git.videolan.org/vlc.git"
17 fi
18 fi
19
20 inherit eutils multilib autotools toolchain-funcs gnome2 nsplugins qt4 flag-o-matic ${SCM}
21
22 MY_PV="${PV/_/-}"
23 MY_PV="${MY_PV/-beta/-test}"
24 MY_P="${PN}-${MY_PV}"
25 VLC_SNAPSHOT_TIME="0013"
26
27 PATCHLEVEL="86"
28 DESCRIPTION="VLC media player - Video player and streamer"
29 HOMEPAGE="http://www.videolan.org/vlc/"
30 if [ "${PV%9999}" != "${PV}" ] ; then # Live ebuild
31 SRC_URI=""
32 elif [[ "${P}" == *_alpha* ]]; then # Snapshots taken from nightlies.videolan.org
33 SRC_URI="http://nightlies.videolan.org/build/source/trunk-${PV/*_alpha/}-${VLC_SNAPSHOT_TIME}/${PN}-snapshot-${PV/*_alpha/}.tar.bz2"
34 MY_P="${P/_alpha*/}-git"
35 elif [[ "${MY_P}" == "${P}" ]]; then
36 SRC_URI="http://download.videolan.org/pub/videolan/${PN}/${PV}/${P}.tar.bz2"
37 else
38 SRC_URI="http://download.videolan.org/pub/videolan/testing/${MY_P}/${MY_P}.tar.bz2"
39 fi
40
41 SRC_URI="${SRC_URI}
42 mirror://gentoo/${PN}-patches-${PATCHLEVEL}.tar.bz2"
43
44 LICENSE="GPL-2"
45 SLOT="0"
46
47 KEYWORDS=""
48 IUSE="a52 aac aalib alsa altivec atmo avahi bidi cdda cddb dbus dc1394
49 debug dirac directfb dts dvb dvd elibc_glibc fbcon fluidsynth +ffmpeg flac fontconfig
50 +gcrypt gnome gnutls httpd ieee1394 jack kate kde libass libcaca
51 libnotify libproxy libtiger libv4l libv4l2 lirc live lua matroska mmx
52 modplug mp3 mpeg mtp musepack ncurses nsplugin ogg opengl optimisememory oss
53 png projectm pulseaudio pvr +qt4 remoteosd rtsp run-as-root samba
54 schroedinger sdl sdl-image shine shout skins speex sqlite sse stream
55 svg taglib theora truetype twolame udev upnp v4l v4l2 vaapi vcdx vlm
56 vorbis win32codecs wma-fixed +X x264 +xcb xml xosd xv zvbi"
57
58 RDEPEND="
59 sys-libs/zlib
60 >=media-libs/libdvbpsi-0.1.6
61 a52? ( >=media-libs/a52dec-0.7.4-r3 )
62 aalib? ( media-libs/aalib )
63 aac? ( >=media-libs/faad2-2.6.1 )
64 alsa? ( media-libs/alsa-lib )
65 avahi? ( >=net-dns/avahi-0.6[dbus] )
66 bidi? ( >=dev-libs/fribidi-0.10.4 )
67 cdda? ( cddb? ( >=media-libs/libcddb-1.2.0 ) )
68 dbus? ( >=sys-apps/dbus-1.0.2 )
69 dc1394? ( >=sys-libs/libraw1394-2.0.1 >=media-libs/libdc1394-2.0.2 )
70 dirac? ( >=media-video/dirac-0.10.0 )
71 directfb? ( dev-libs/DirectFB sys-libs/zlib )
72 dts? ( media-libs/libdca )
73 dvd? ( media-libs/libdvdread >=media-libs/libdvdnav-0.1.9 )
74 elibc_glibc? ( >=sys-libs/glibc-2.8 )
75 ffmpeg? ( >=media-video/ffmpeg-0.6 )
76 flac? ( media-libs/libogg >=media-libs/flac-1.1.2 )
77 fluidsynth? ( media-sound/fluidsynth )
78 fontconfig? ( media-libs/fontconfig )
79 gcrypt? ( >=dev-libs/libgcrypt-1.2.0 )
80 gnome? ( gnome-base/gnome-vfs )
81 gnutls? ( >=net-libs/gnutls-1.7.4 >=dev-libs/libgcrypt-1.2.0 )
82 ieee1394? ( >=sys-libs/libraw1394-2.0.1 >=sys-libs/libavc1394-0.5.3 )
83 jack? ( >=media-sound/jack-audio-connection-kit-0.99.0-r1 )
84 kate? ( >=media-libs/libkate-0.1.1 )
85 libass? ( >=media-libs/libass-0.9.6 media-libs/fontconfig )
86 libcaca? ( >=media-libs/libcaca-0.99_beta14 )
87 libnotify? ( x11-libs/libnotify )
88 libproxy? ( net-libs/libproxy )
89 libtiger? ( media-libs/libtiger )
90 lirc? ( app-misc/lirc )
91 live? ( >=media-plugins/live-2008.07.06 )
92 lua? ( >=dev-lang/lua-5.1 )
93 matroska? ( >=dev-libs/libebml-0.7.6 >=media-libs/libmatroska-0.8.0 )
94 modplug? ( >=media-libs/libmodplug-0.8.8.1 )
95 mp3? ( media-libs/libmad )
96 mpeg? ( >=media-libs/libmpeg2-0.3.2 )
97 mtp? ( >=media-libs/libmtp-1.0.0 )
98 musepack? ( >=media-sound/musepack-tools-444 )
99 ncurses? ( sys-libs/ncurses )
100 nsplugin? ( >=net-libs/xulrunner-1.9.2 x11-libs/libXpm x11-libs/libXt )
101 ogg? ( media-libs/libogg )
102 opengl? ( virtual/opengl x11-libs/libX11[xcb] )
103 png? ( media-libs/libpng sys-libs/zlib )
104 projectm? ( media-libs/libprojectm )
105 pulseaudio? ( >=media-sound/pulseaudio-0.9.11
106 !X? ( >=media-sound/pulseaudio-0.9.11[-X] ) )
107 qt4? ( x11-libs/qt-gui:4 x11-libs/qt-core:4 x11-libs/libX11 )
108 remoteosd? ( >=dev-libs/libgcrypt-1.2.0 )
109 samba? ( || ( >=net-fs/samba-3.4.6[smbclient] <net-fs/samba-3.4 ) )
110 schroedinger? ( >=media-libs/schroedinger-1.0.6 )
111 sdl? ( >=media-libs/libsdl-1.2.8
112 sdl-image? ( media-libs/sdl-image sys-libs/zlib ) )
113 shout? ( media-libs/libshout )
114 skins? (
115 x11-libs/qt-gui:4 x11-libs/qt-core:4
116 x11-libs/libXext x11-libs/libX11
117 media-libs/freetype media-fonts/dejavu
118 )
119 speex? ( media-libs/speex )
120 sqlite? ( >=dev-db/sqlite-3.6.0:3 )
121 svg? ( >=gnome-base/librsvg-2.9.0 )
122 taglib? ( >=media-libs/taglib-1.5 sys-libs/zlib )
123 theora? ( >=media-libs/libtheora-1.0_beta3 )
124 truetype? ( media-libs/freetype media-fonts/dejavu )
125 twolame? ( media-sound/twolame )
126 udev? ( >=sys-fs/udev-142 )
127 upnp? ( net-libs/libupnp )
128 v4l2? ( libv4l2? ( media-libs/libv4l ) )
129 v4l? ( libv4l? ( media-libs/libv4l ) )
130 vaapi? ( x11-libs/libva >=media-video/ffmpeg-0.6 )
131 vcdx? ( >=dev-libs/libcdio-0.78.2 >=media-video/vcdimager-0.7.22 )
132 vorbis? ( media-libs/libvorbis )
133 win32codecs? ( media-libs/win32codecs )
134 X? ( x11-libs/libX11 )
135 x264? ( >=media-libs/x264-0.0.20090923 )
136 xcb? ( x11-libs/libxcb x11-libs/xcb-util )
137 xml? ( dev-libs/libxml2 )
138 xosd? ( x11-libs/xosd )
139 zvbi? ( >=media-libs/zvbi-0.2.25 )
140 "
141
142 DEPEND="${RDEPEND}
143 !!<=media-video/vlc-1.1.99999
144 dvb? ( sys-kernel/linux-headers )
145 kde? ( >=kde-base/kdelibs-4 )
146 v4l? ( sys-kernel/linux-headers )
147 v4l2? ( >=sys-kernel/linux-headers-2.6.25 )
148 xcb? ( x11-proto/xproto )
149 dev-util/pkgconfig"
150
151 S="${WORKDIR}/${MY_P}"
152
153 # Displays a warning if the first use flag is set but the second is not
154 vlc_use_needs() {
155 use $1 && use !$2 && ewarn "USE=$1 requires $2, $1 will be disabled."
156 }
157
158 # Notify the user that some useflag have been forced on
159 vlc_use_force() {
160 use $1 && use !$2 && ewarn "USE=$1 requires $2, $2 will be enabled."
161 }
162
163 # Use when $1 depends strictly on $2
164 # if use $1 then enable $2
165 vlc_use_enable_force() {
166 use $1 && echo "--enable-$2"
167 }
168
169 pkg_setup() {
170 # Useflags we need to forcefuly enable
171 vlc_use_force remoteosd gcrypt
172 vlc_use_force gnutls gcrypt
173 vlc_use_force skins truetype
174 vlc_use_force skins qt4
175 vlc_use_force vlm stream
176 vlc_use_force vaapi ffmpeg
177
178 # Useflags that will be automagically discarded if deps are not met
179 vlc_use_needs bidi truetype
180 vlc_use_needs cddb cdda
181 vlc_use_needs fontconfig truetype
182 vlc_use_needs libv4l2 v4l2
183 vlc_use_needs libv4l v4l
184 vlc_use_needs libtiger kate
185 vlc_use_needs xv xcb
186
187 if use qt4 || use skins ; then
188 qt4_pkg_setup
189 else
190 ewarn "You have disabled the qt4 useflag, ${PN} will not have any"
191 ewarn "graphical interface. Maybe that is not what you want..."
192 fi
193 }
194
195 src_unpack() {
196 unpack ${A}
197 if [ "${PV%9999}" != "${PV}" ] ; then
198 git_src_unpack
199 fi
200 }
201
202 src_prepare() {
203 if [ "${PV%9999}" != "${PV}" ] ; then
204 git_src_prepare
205 fi
206 # Make it build with libtool 1.5
207 rm -f m4/lt* m4/libtool.m4
208
209 EPATCH_SUFFIX="patch" epatch "${WORKDIR}/patches"
210 eautoreconf
211 }
212
213 src_configure() {
214
215 # It would fail if -fforce-addr is used due to too few registers...
216 use x86 && filter-flags -fforce-addr
217
218 econf \
219 $(use_enable a52) \
220 $(use_enable aalib aa) \
221 $(use_enable aac faad) \
222 $(use_enable alsa) \
223 $(use_enable altivec) \
224 --disable-asademux \
225 $(use_enable atmo) \
226 $(use_enable avahi bonjour) \
227 $(use_enable bidi fribidi) \
228 $(use_enable cdda vcd) \
229 $(use_enable cddb libcddb) \
230 $(use_enable dbus) $(use_enable dbus dbus-control) \
231 $(use_enable dirac) \
232 $(use_enable directfb) \
233 $(use_enable dc1394) \
234 $(use_enable debug) \
235 $(use_enable dts dca) \
236 $(use_enable dvb) \
237 $(use_enable dvd dvdread) $(use_enable dvd dvdnav) \
238 $(use_enable fbcon fb) \
239 $(use_enable ffmpeg avcodec) $(use_enable ffmpeg avformat) $(use_enable ffmpeg swscale) $(use_enable ffmpeg postproc) \
240 $(use_enable flac) \
241 $(use_enable fluidsynth) \
242 $(use_enable fontconfig) \
243 $(use_enable gnome gnomevfs) \
244 $(use_enable gnutls) \
245 $(use_enable httpd) \
246 $(use_enable ieee1394 dv) \
247 $(use_enable jack) \
248 $(use_enable kate) \
249 $(use_with kde kde-solid) \
250 $(use_enable libass) \
251 $(use_enable libcaca caca) \
252 $(use_enable gcrypt libgcrypt) \
253 $(use_enable libnotify notify) \
254 $(use_enable libproxy) \
255 --disable-libtar \
256 $(use_enable libtiger tiger) \
257 $(use_enable libv4l) \
258 $(use_enable libv4l2) \
259 $(use_enable lirc) \
260 $(use_enable live live555) \
261 $(use_enable lua) \
262 $(use_enable matroska mkv) \
263 $(use_enable mmx) \
264 $(use_enable modplug mod) \
265 $(use_enable mp3 mad) \
266 $(use_enable mpeg libmpeg2) \
267 $(use_enable mtp) \
268 $(use_enable musepack mpc) \
269 $(use_enable ncurses) \
270 $(use_enable nsplugin mozilla) --with-mozilla-pkg=libxul \
271 $(use_enable ogg) \
272 $(use_enable opengl glx) \
273 $(use_enable optimisememory optimize-memory) \
274 $(use_enable oss) \
275 $(use_enable png) \
276 --disable-portaudio \
277 $(use_enable projectm) \
278 $(use_enable pulseaudio pulse) \
279 $(use_enable pvr) \
280 $(use_enable qt4) \
281 $(use_enable remoteosd) \
282 $(use_enable rtsp realrtsp) \
283 $(use_enable run-as-root) \
284 $(use_enable samba smb) \
285 $(use_enable schroedinger) \
286 $(use_enable sdl) \
287 $(use_enable sdl-image) \
288 $(use_enable shine) \
289 $(use_enable shout) \
290 $(use_enable skins skins2) \
291 $(use_enable speex) \
292 $(use_enable sqlite) \
293 $(use_enable sse) \
294 $(use_enable stream sout) \
295 $(use_enable svg) \
296 $(use_enable taglib) \
297 $(use_enable theora) \
298 $(use_enable truetype freetype) \
299 $(use_enable twolame) \
300 $(use_enable udev) \
301 $(use_enable upnp) \
302 $(use_enable v4l) \
303 $(use_enable v4l2) \
304 $(use_enable vcdx) \
305 $(use_enable vaapi libva) \
306 $(use_enable vlm) \
307 $(use_enable vorbis) \
308 $(use_enable win32codecs loader) \
309 $(use_enable wma-fixed) \
310 $(use_with X x) \
311 $(use_enable x264) \
312 $(use_enable xcb) \
313 $(use_enable xml libxml2) \
314 $(use_enable xosd) \
315 $(use_enable xv xvideo) \
316 $(use_enable zvbi) $(use_enable !zvbi telx) \
317 --disable-snapshot \
318 --disable-growl \
319 --disable-optimizations \
320 --enable-fast-install \
321 $(vlc_use_enable_force vlm sout) \
322 $(vlc_use_enable_force skins qt4) \
323 $(vlc_use_enable_force skins freetype) \
324 $(vlc_use_enable_force remoteosd libgcrypt) \
325 $(vlc_use_enable_force gnutls libgcrypt) \
326 $(vlc_use_enable_force vaapi avcodec)
327 }
328
329 src_install() {
330 emake DESTDIR="${D}" install || die "make install failed"
331
332 dodoc AUTHORS HACKING THANKS NEWS README \
333 doc/fortunes.txt doc/intf-vcd.txt
334
335 rm -rf "${D}/usr/share/doc/vlc" \
336 "${D}"/usr/share/vlc/vlc{16x16,32x32,48x48,128x128}.{png,xpm,ico}
337
338 if use nsplugin; then
339 dodir "/usr/$(get_libdir)/${PLUGINS_DIR}"
340 mv "${D}"/usr/$(get_libdir)/mozilla/plugins/* \
341 "${D}/usr/$(get_libdir)/${PLUGINS_DIR}/"
342 fi
343
344 use skins || rm -rf "${D}/usr/share/vlc/skins2"
345
346 # Punt useless libtool's .la files
347 find "${D}" -name '*.la' -delete
348 }
349
350 pkg_postinst() {
351 gnome2_pkg_postinst
352
353 if [ "$ROOT" = "/" ] && [ -x "/usr/$(get_libdir)/vlc/vlc-cache-gen" ] ; then
354 einfo "Running /usr/$(get_libdir)/vlc/vlc-cache-gen on /usr/$(get_libdir)/vlc/plugins/"
355 "/usr/$(get_libdir)/vlc/vlc-cache-gen" -f "/usr/$(get_libdir)/vlc/plugins/"
356 else
357 ewarn "We cannot run vlc-cache-gen (most likely ROOT!=/)"
358 ewarn "Please run /usr/$(get_libdir)/vlc/vlc-cache-gen manually"
359 ewarn "If you do not do it, vlc will take a long time to load."
360 fi
361 }

  ViewVC Help
Powered by ViewVC 1.1.20