net-dns/avahi/avahi-0.6.30-r3.ebuild

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-dns/avahi/avahi-0.6.30-r3.ebuild,v 1.15 2012/10/07 14:33:51 armin76 Exp $

EAPI="3"

PYTHON_DEPEND="python? 2"
PYTHON_USE_WITH="gdbm"
PYTHON_USE_WITH_OPT="python"

WANT_AUTOMAKE=1.11

inherit autotools eutils mono python multilib flag-o-matic user

DESCRIPTION="System which facilitates service discovery on a local network"
HOMEPAGE="http://avahi.org/"
SRC_URI="http://avahi.org/download/${P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="alpha amd64 arm hppa ia64 ~mips ppc ppc64 s390 sh sparc x86 ~amd64-fbsd ~x86-fbsd ~x86-linux"
IUSE="autoipd bookmarks dbus doc gdbm gtk gtk3 howl-compat +introspection ipv6
kernel_linux mdnsresponder-compat mono python qt4 test utils"

DBUS_DEPEND=">=sys-apps/dbus-0.30"
COMMON_DEPEND=">=dev-libs/libdaemon-0.14
        dev-libs/expat
        dev-libs/glib:2
        gdbm? ( sys-libs/gdbm )
        qt4? ( dev-qt/qtcore:4 )
        gtk? ( >=x11-libs/gtk+-2.14.0:2 )
        gtk3? ( x11-libs/gtk+:3 )
        dbus? (
                ${DBUS_DEPEND}
                python? ( dev-python/dbus-python )
        )
        mono? (
                >=dev-lang/mono-1.1.10
                gtk? ( >=dev-dotnet/gtk-sharp-2 )
        )
        howl-compat? ( ${DBUS_DEPEND} )
        introspection? ( >=dev-libs/gobject-introspection-0.9.5 )
        mdnsresponder-compat? ( ${DBUS_DEPEND} )
        python? (
                gtk? ( >=dev-python/pygtk-2 )
        )
        bookmarks? (
                dev-python/twisted
                dev-python/twisted-web
        )
        kernel_linux? ( sys-libs/libcap )"
DEPEND="${COMMON_DEPEND}
        >=dev-util/intltool-0.40.5
        virtual/pkgconfig
        doc? (
                app-doc/doxygen
                mono? ( >=virtual/monodoc-1.1.8 )
        )"
RDEPEND="${COMMON_DEPEND}
        howl-compat? ( !net-misc/howl )
        mdnsresponder-compat? ( !net-misc/mDNSResponder )"

pkg_setup() {
        if use python; then
                python_set_active_version 2
                python_pkg_setup
        fi

        if use python && ! use dbus && ! use gtk; then
                ewarn "For proper python support you should also enable the dbus and gtk USE flags!"
        fi

        # FIXME: Use REQUIRED_USE once python.eclass gets EAPI 4 support, bug 372255
        if use utils && ! { use gtk || use gtk3; }; then
                ewarn "To install the avahi utilities, USE='gtk utils' or USE='gtk3 utils''"
        fi
}

pkg_preinst() {
        enewgroup netdev
        enewgroup avahi
        enewuser avahi -1 -1 -1 avahi

        if use autoipd; then
                enewgroup avahi-autoipd
                enewuser avahi-autoipd -1 -1 -1 avahi-autoipd
        fi
}

src_prepare() {
        if use ipv6; then
                sed -i \
                        -e s/use-ipv6=no/use-ipv6=yes/ \
                        avahi-daemon/avahi-daemon.conf || die
        fi

        sed -i\
                -e "s:\\.\\./\\.\\./\\.\\./doc/avahi-docs/html/:../../../doc/${PF}/html/:" \
                doxygen_to_devhelp.xsl || die

        # Make gtk utils optional
        epatch "${FILESDIR}/${PN}-0.6.30-optional-gtk-utils.patch"

        # Fix init scripts for >=openrc-0.9.0 (bug #383641)
        epatch "${FILESDIR}/${PN}-0.6.x-openrc-0.9.x-init-scripts-fixes.patch"

        # Drop DEPRECATED flags, bug #384743
        sed -i -e 's:-D[A-Z_]*DISABLE_DEPRECATED=1::g' avahi-ui/Makefile.am || die

        # Prevent .pyc files in DESTDIR
        >py-compile

        epatch "${FILESDIR}"/${P}-automake-1.11.2.patch #397477
        epatch "${FILESDIR}"/${P}-parallel.patch #411351

        eautoreconf
}

src_configure() {
        use sh && replace-flags -O? -O0

        local myconf="--disable-static"

        if use python; then
                myconf+="
                        $(use_enable dbus python-dbus)
                        $(use_enable gtk pygtk)
                "
        fi

        if use mono; then
                myconf+=" $(use_enable doc monodoc)"
        fi

        # these require dbus enabled
        if use mdnsresponder-compat || use howl-compat || use mono; then
                myconf+=" --enable-dbus"
        fi

        # We need to unset DISPLAY, else the configure script might have problems detecting the pygtk module
        unset DISPLAY

        econf \
                --localstatedir="${EPREFIX}/var" \
                --with-distro=gentoo \
                --disable-python-dbus \
                --disable-pygtk \
                --disable-xmltoman \
                --disable-monodoc \
                --enable-glib \
                --enable-gobject \
                $(use_enable test tests) \
                $(use_enable autoipd) \
                $(use_enable mdnsresponder-compat compat-libdns_sd) \
                $(use_enable howl-compat compat-howl) \
                $(use_enable doc doxygen-doc) \
                $(use_enable mono) \
                $(use_enable dbus) \
                $(use_enable python) \
                $(use_enable gtk) \
                $(use_enable gtk3) \
                $(use_enable introspection) \
                $(use_enable utils gtk-utils) \
                --disable-qt3 \
                $(use_enable qt4) \
                $(use_enable gdbm) \
                ${myconf}
}

src_compile() {
        emake || die "emake failed"

        use doc && { emake avahi.devhelp || die ; }
}

src_install() {
        emake install DESTDIR="${D}" || die "make install failed"
        use bookmarks && use python && use dbus && use gtk || \
                rm -f "${ED}"/usr/bin/avahi-bookmarks

        use howl-compat && ln -s avahi-compat-howl.pc "${ED}"/usr/$(get_libdir)/pkgconfig/howl.pc
        use mdnsresponder-compat && ln -s avahi-compat-libdns_sd/dns_sd.h "${ED}"/usr/include/dns_sd.h

        if use autoipd; then
                insinto /$(get_libdir)/rcscripts/net
                doins "${FILESDIR}"/autoipd.sh || die

                insinto /$(get_libdir)/rc/net
                newins "${FILESDIR}"/autoipd-openrc.sh autoipd.sh || die
        fi

        dodoc docs/{AUTHORS,NEWS,README,TODO} || die

        if use doc; then
                dohtml -r doxygen/html/. || die
                insinto /usr/share/devhelp/books/avahi
                doins avahi.devhelp || die
        fi

        # /usr/bin/avahi-bookmarks is installed only with USE="bookmarks dbus gtk python".
        # /usr/bin/avahi-discover is installed only with USE="dbus gtk python".
        use dbus && use gtk && use python && python_convert_shebangs -r 2 "${ED}usr/bin"

        find "${ED}" -name '*.la' -exec rm -f {} +
}

pkg_postrm() {
        use python && python_mod_cleanup avahi $(use dbus && use gtk && echo avahi_discover)
}

pkg_postinst() {
        use python && python_mod_optimize avahi $(use dbus && use gtk && echo avahi_discover)

        if use autoipd; then
                echo
                elog "To use avahi-autoipd to configure your interfaces with IPv4LL (RFC3927)"
                elog "addresses, just set config_<interface>=( autoipd ) in /etc/conf.d/net!"
        fi

        if use dbus; then
                echo
                elog "If this is your first install of avahi please reload your dbus config"
                elog "with /etc/init.d/dbus reload before starting avahi-daemon!"
        fi
}
1	# Copyright 1999-2013 Gentoo Foundation
2	# Distributed under the terms of the GNU General Public License v2
3	# $Header: /var/cvsroot/gentoo-x86/net-dns/avahi/avahi-0.6.30-r3.ebuild,v 1.15 2012/10/07 14:33:51 armin76 Exp $
4
5	EAPI="3"
6
7	PYTHON_DEPEND="python? 2"
8	PYTHON_USE_WITH="gdbm"
9	PYTHON_USE_WITH_OPT="python"
10
11	WANT_AUTOMAKE=1.11
12
13	inherit autotools eutils mono python multilib flag-o-matic user
14
15	DESCRIPTION="System which facilitates service discovery on a local network"
16	HOMEPAGE="http://avahi.org/"
17	SRC_URI="http://avahi.org/download/${P}.tar.gz"
18
19	LICENSE="LGPL-2.1"
20	SLOT="0"
21	KEYWORDS="alpha amd64 arm hppa ia64 ~mips ppc ppc64 s390 sh sparc x86 ~amd64-fbsd ~x86-fbsd ~x86-linux"
22	IUSE="autoipd bookmarks dbus doc gdbm gtk gtk3 howl-compat +introspection ipv6
23	kernel_linux mdnsresponder-compat mono python qt4 test utils"
24
25	DBUS_DEPEND=">=sys-apps/dbus-0.30"
26	COMMON_DEPEND=">=dev-libs/libdaemon-0.14
27	dev-libs/expat
28	dev-libs/glib:2
29	gdbm? ( sys-libs/gdbm )
30	qt4? ( dev-qt/qtcore:4 )
31	gtk? ( >=x11-libs/gtk+-2.14.0:2 )
32	gtk3? ( x11-libs/gtk+:3 )
33	dbus? (
34	${DBUS_DEPEND}
35	python? ( dev-python/dbus-python )
36	)
37	mono? (
38	>=dev-lang/mono-1.1.10
39	gtk? ( >=dev-dotnet/gtk-sharp-2 )
40	)
41	howl-compat? ( ${DBUS_DEPEND} )
42	introspection? ( >=dev-libs/gobject-introspection-0.9.5 )
43	mdnsresponder-compat? ( ${DBUS_DEPEND} )
44	python? (
45	gtk? ( >=dev-python/pygtk-2 )
46	)
47	bookmarks? (
48	dev-python/twisted
49	dev-python/twisted-web
50	)
51	kernel_linux? ( sys-libs/libcap )"
52	DEPEND="${COMMON_DEPEND}
53	>=dev-util/intltool-0.40.5
54	virtual/pkgconfig
55	doc? (
56	app-doc/doxygen
57	mono? ( >=virtual/monodoc-1.1.8 )
58	)"
59	RDEPEND="${COMMON_DEPEND}
60	howl-compat? ( !net-misc/howl )
61	mdnsresponder-compat? ( !net-misc/mDNSResponder )"
62
63	pkg_setup() {
64	if use python; then
65	python_set_active_version 2
66	python_pkg_setup
67	fi
68
69	if use python && ! use dbus && ! use gtk; then
70	ewarn "For proper python support you should also enable the dbus and gtk USE flags!"
71	fi
72
73	# FIXME: Use REQUIRED_USE once python.eclass gets EAPI 4 support, bug 372255
74	if use utils && ! { use gtk \|\| use gtk3; }; then
75	ewarn "To install the avahi utilities, USE='gtk utils' or USE='gtk3 utils''"
76	fi
77	}
78
79	pkg_preinst() {
80	enewgroup netdev
81	enewgroup avahi
82	enewuser avahi -1 -1 -1 avahi
83
84	if use autoipd; then
85	enewgroup avahi-autoipd
86	enewuser avahi-autoipd -1 -1 -1 avahi-autoipd
87	fi
88	}
89
90	src_prepare() {
91	if use ipv6; then
92	sed -i \
93	-e s/use-ipv6=no/use-ipv6=yes/ \
94	avahi-daemon/avahi-daemon.conf \|\| die
95	fi
96
97	sed -i\
98	-e "s:\\.\\./\\.\\./\\.\\./doc/avahi-docs/html/:../../../doc/${PF}/html/:" \
99	doxygen_to_devhelp.xsl \|\| die
100
101	# Make gtk utils optional
102	epatch "${FILESDIR}/${PN}-0.6.30-optional-gtk-utils.patch"
103
104	# Fix init scripts for >=openrc-0.9.0 (bug #383641)
105	epatch "${FILESDIR}/${PN}-0.6.x-openrc-0.9.x-init-scripts-fixes.patch"
106
107	# Drop DEPRECATED flags, bug #384743
108	sed -i -e 's:-D[A-Z_]*DISABLE_DEPRECATED=1::g' avahi-ui/Makefile.am \|\| die
109
110	# Prevent .pyc files in DESTDIR
111	>py-compile
112
113	epatch "${FILESDIR}"/${P}-automake-1.11.2.patch #397477
114	epatch "${FILESDIR}"/${P}-parallel.patch #411351
115
116	eautoreconf
117	}
118
119	src_configure() {
120	use sh && replace-flags -O? -O0
121
122	local myconf="--disable-static"
123
124	if use python; then
125	myconf+="
126	$(use_enable dbus python-dbus)
127	$(use_enable gtk pygtk)
128	"
129	fi
130
131	if use mono; then
132	myconf+=" $(use_enable doc monodoc)"
133	fi
134
135	# these require dbus enabled
136	if use mdnsresponder-compat \|\| use howl-compat \|\| use mono; then
137	myconf+=" --enable-dbus"
138	fi
139
140	# We need to unset DISPLAY, else the configure script might have problems detecting the pygtk module
141	unset DISPLAY
142
143	econf \
144	--localstatedir="${EPREFIX}/var" \
145	--with-distro=gentoo \
146	--disable-python-dbus \
147	--disable-pygtk \
148	--disable-xmltoman \
149	--disable-monodoc \
150	--enable-glib \
151	--enable-gobject \
152	$(use_enable test tests) \
153	$(use_enable autoipd) \
154	$(use_enable mdnsresponder-compat compat-libdns_sd) \
155	$(use_enable howl-compat compat-howl) \
156	$(use_enable doc doxygen-doc) \
157	$(use_enable mono) \
158	$(use_enable dbus) \
159	$(use_enable python) \
160	$(use_enable gtk) \
161	$(use_enable gtk3) \
162	$(use_enable introspection) \
163	$(use_enable utils gtk-utils) \
164	--disable-qt3 \
165	$(use_enable qt4) \
166	$(use_enable gdbm) \
167	${myconf}
168	}
169
170	src_compile() {
171	emake \|\| die "emake failed"
172
173	use doc && { emake avahi.devhelp \|\| die ; }
174	}
175
176	src_install() {
177	emake install DESTDIR="${D}" \|\| die "make install failed"
178	use bookmarks && use python && use dbus && use gtk \|\| \
179	rm -f "${ED}"/usr/bin/avahi-bookmarks
180
181	use howl-compat && ln -s avahi-compat-howl.pc "${ED}"/usr/$(get_libdir)/pkgconfig/howl.pc
182	use mdnsresponder-compat && ln -s avahi-compat-libdns_sd/dns_sd.h "${ED}"/usr/include/dns_sd.h
183
184	if use autoipd; then
185	insinto /$(get_libdir)/rcscripts/net
186	doins "${FILESDIR}"/autoipd.sh \|\| die
187
188	insinto /$(get_libdir)/rc/net
189	newins "${FILESDIR}"/autoipd-openrc.sh autoipd.sh \|\| die
190	fi
191
192	dodoc docs/{AUTHORS,NEWS,README,TODO} \|\| die
193
194	if use doc; then
195	dohtml -r doxygen/html/. \|\| die
196	insinto /usr/share/devhelp/books/avahi
197	doins avahi.devhelp \|\| die
198	fi
199
200	# /usr/bin/avahi-bookmarks is installed only with USE="bookmarks dbus gtk python".
201	# /usr/bin/avahi-discover is installed only with USE="dbus gtk python".
202	use dbus && use gtk && use python && python_convert_shebangs -r 2 "${ED}usr/bin"
203
204	find "${ED}" -name '*.la' -exec rm -f {} +
205	}
206
207	pkg_postrm() {
208	use python && python_mod_cleanup avahi $(use dbus && use gtk && echo avahi_discover)
209	}
210
211	pkg_postinst() {
212	use python && python_mod_optimize avahi $(use dbus && use gtk && echo avahi_discover)
213
214	if use autoipd; then
215	echo
216	elog "To use avahi-autoipd to configure your interfaces with IPv4LL (RFC3927)"
217	elog "addresses, just set config_<interface>=( autoipd ) in /etc/conf.d/net!"
218	fi
219
220	if use dbus; then
221	echo
222	elog "If this is your first install of avahi please reload your dbus config"
223	elog "with /etc/init.d/dbus reload before starting avahi-daemon!"
224	fi
225	}