/[gentoo-x86]/net-im/amsn/amsn-0.98.4-r1.ebuild
Gentoo

Contents of /net-im/amsn/amsn-0.98.4-r1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.10 - (show annotations) (download)
Sun Oct 23 16:05:20 2011 UTC (2 years, 11 months ago) by armin76
Branch: MAIN
Changes since 1.9: +2 -2 lines
Drop alpha keywords

(Portage version: 2.1.10.11/cvs/Linux ia64)

1 # Copyright 1999-2011 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/net-im/amsn/amsn-0.98.4-r1.ebuild,v 1.9 2011/10/15 10:41:15 xarthisius Exp $
4
5 EAPI=4
6 inherit autotools eutils fdo-mime gnome2-utils toolchain-funcs
7
8 MY_P=${P/_rc/RC}
9
10 DESCRIPTION="aMSN Messenger client"
11 SRC_URI="mirror://sourceforge/${PN}/${PN}/${PV}/${MY_P}-src.tar.bz2"
12 HOMEPAGE="http://www.amsn-project.net"
13
14 LICENSE="GPL-2"
15 SLOT="0"
16 KEYWORDS="amd64 hppa ppc -sparc x86"
17 IUSE="debug"
18
19 DEPEND=">=dev-lang/tcl-8.4
20 >=dev-lang/tk-8.4
21 virtual/jpeg
22 media-libs/libpng
23 >=dev-tcltk/snack-2.2.10
24 >=net-libs/gupnp-igd-0.1.3
25 media-libs/libv4l
26 media-libs/imlib"
27 # >=net-libs/farsight2-0.0.14
28 # >=media-libs/gstreamer-0.10.23
29 # >=media-libs/gst-plugins-base-0.10.23
30
31 RDEPEND="${DEPEND}
32 >=dev-tcltk/tls-1.5
33 virtual/ffmpeg[encode]"
34 # >=media-libs/gst-plugins-good-0.10.15
35 # >=media-libs/gst-plugins-bad-0.10.13
36 # >=media-plugins/gst-plugins-ffmpeg-0.10.7
37
38 # The tests are interactive
39 RESTRICT="test"
40
41 S=${WORKDIR}/${MY_P}
42
43 DOCS=( AGREEMENT TODO README FAQ CREDITS )
44
45 src_prepare() {
46 epatch \
47 "${FILESDIR}"/${PN}-0.98-noautoupdate.patch \
48 "${FILESDIR}"/${PN}-0.98.4-v4l2.patch \
49 "${FILESDIR}"/${PN}-0.98.4-amsnplus-ldflags.patch
50
51 # The NetBSD patch kills backwards compability, see http://bugs.gentoo.org/376407
52 has_version '>=media-libs/libpng-1.5:0' && epatch "${FILESDIR}"/${PN}-0.98.4-libpng15.patch
53
54 # only portage should strip files, bug 285682
55 sed -i -e "s/LDFLAGS += -s/LDFLAGS += /" Makefile.in || die "sed failed"
56 # Ships with a 32-bit binary, we want to rebuild it
57 rm -f plugins/amsnplus/snapshot || die
58 eautoreconf
59 }
60
61 src_configure() {
62 tc-export CC
63 econf $(use_enable debug)
64 }
65
66 src_install() {
67 emake -C plugins/amsnplus
68 default
69
70 domenu amsn.desktop
71 sed -i -e s:.png:: "${D}"/usr/share/applications/amsn.desktop || die
72
73 pushd desktop-icons
74 local res
75 for res in 22 32 48 64 72 96 128; do
76 insinto /usr/share/icons/hicolor/${res}x${res}/apps
77 doins ${res}x${res}/apps/amsn.png
78 done
79 popd
80 }
81
82 pkg_preinst() {
83 gnome2_icon_savelist
84 }
85
86 pkg_postinst() {
87 fdo-mime_desktop_database_update
88 gnome2_icon_cache_update
89 }
90
91 pkg_postrm() {
92 fdo-mime_desktop_database_update
93 gnome2_icon_cache_update
94 }

  ViewVC Help
Powered by ViewVC 1.1.20