/[gentoo-x86]/net-im/centerim/centerim-4.22.7-r1.ebuild
Gentoo

Contents of /net-im/centerim/centerim-4.22.7-r1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.10 - (show annotations) (download)
Sat Mar 12 13:29:58 2011 UTC (3 years, 5 months ago) by swegener
Branch: MAIN
CVS Tags: HEAD
Changes since 1.9: +1 -1 lines
FILE REMOVED
Cleanup.

(Portage version: 2.2.0_alpha26/cvs/Linux x86_64)

1 # Copyright 1999-2011 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/net-im/centerim/centerim-4.22.7-r1.ebuild,v 1.9 2011/02/26 19:41:09 signals Exp $
4
5 EAPI="2"
6
7 inherit eutils
8
9 PROTOCOL_IUSE="+aim gadu +icq +irc +jabber lj +msn rss +yahoo"
10 IUSE="${PROTOCOL_IUSE} bidi nls ssl crypt jpeg otr"
11
12 DESCRIPTION="CenterIM is a fork of CenterICQ - a ncurses ICQ/Yahoo!/AIM/IRC/MSN/Jabber/GaduGadu/RSS/LiveJournal Client"
13 if [[ ${PV} = *_p* ]] # is this a snaphot?
14 then
15 SRC_URI="http://www.centerim.org/download/snapshots/${PN}-${PV/*_p/}.tar.gz"
16 else
17 SRC_URI="http://www.centerim.org/download/releases/${P}.tar.bz2"
18 fi
19 HOMEPAGE="http://www.centerim.org/"
20 SLOT="0"
21 LICENSE="GPL-2"
22 KEYWORDS="amd64 x86 ~x86-fbsd"
23
24 DEPEND=">=sys-libs/ncurses-5.2
25 bidi? ( dev-libs/fribidi )
26 ssl? ( >=dev-libs/openssl-0.9.6g )
27 jpeg? ( virtual/jpeg )
28 jabber? (
29 otr? ( net-libs/libotr )
30 crypt? ( >=app-crypt/gpgme-1.0.2 )
31 )
32 msn? (
33 || (
34 >=net-misc/curl-7.19.6[ssl]
35 >=net-misc/curl-7.19.6[gnutls]
36 >=net-misc/curl-7.19.6[nss]
37 )
38 )"
39
40 RDEPEND="${DEPEND}
41 nls? ( sys-devel/gettext )"
42
43 S="${WORKDIR}"/${P/_p*}
44
45 check_protocol_iuse() {
46 local flag
47
48 for flag in ${PROTOCOL_IUSE}
49 do
50 use ${flag#+} && return 0
51 done
52
53 return 1
54 }
55
56 pkg_setup() {
57 if ! check_protocol_iuse
58 then
59 eerror
60 eerror "Please activate at least one of the following protocol USE flags:"
61 eerror "${PROTOCOL_IUSE//+}"
62 eerror
63 die "Please activate at least one protocol USE flag!"
64 fi
65
66 if use otr && ! use jabber
67 then
68 ewarn
69 ewarn "Support for OTR is only supported with Jabber!"
70 ewarn
71 fi
72
73 if use gadu && ! use jpeg
74 then
75 ewarn
76 ewarn "You need jpeg support to be able to register Gadu-Gadu accounts!"
77 ewarn
78 fi
79 }
80
81 src_prepare() {
82 default
83
84 epatch "${FILESDIR}"/${P}-libgadu-CVE-2008-4776.patch
85
86 # Don't execute git commands, bug #228151
87 cat >"${S}"/misc/git-version-gen <<-EOF
88 #!/bin/sh
89 echo -n "${PVR}"
90 EOF
91 }
92
93 src_configure() {
94 econf \
95 $(use_with ssl) \
96 $(use_enable aim) \
97 $(use_with bidi fribidi) \
98 $(use_with jpeg libjpeg) \
99 $(use_with otr libotr) \
100 $(use_enable gadu gg) \
101 $(use_enable icq) \
102 $(use_enable irc) \
103 $(use_enable jabber) \
104 $(use_enable lj) \
105 $(use_enable msn) \
106 $(use_enable nls locales-fix) \
107 $(use_enable nls) \
108 $(use_enable rss) \
109 $(use_enable yahoo) \
110 || die "econf failed"
111 }
112
113 src_install () {
114 emake DESTDIR="${D}" install || die "emake install failed"
115
116 dodoc AUTHORS ChangeLog FAQ README THANKS TODO
117 }

  ViewVC Help
Powered by ViewVC 1.1.20