/[gentoo-x86]/net-libs/cyassl/cyassl-2.4.0.ebuild
Gentoo

Contents of /net-libs/cyassl/cyassl-2.4.0.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.1 - (show annotations) (download)
Thu Oct 18 21:34:31 2012 UTC (23 months ago) by blueness
Branch: MAIN
Version bump

(Portage version: 2.1.11.9/cvs/Linux x86_64)

1 # Copyright 1999-2012 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/net-libs/cyassl/cyassl-2.3.0.ebuild,v 1.2 2012/09/02 13:30:51 blueness Exp $
4
5 EAPI="4"
6
7 inherit eutils
8
9 DESCRIPTION="Lightweight SSL/TLS library targeted at embedded and RTOS environments"
10 HOMEPAGE="http://www.yassl.com/yaSSL/Home.html"
11 SRC_URI="http://dev.gentoo.org/~blueness/${PN}/${P}.zip"
12
13 LICENSE="GPL-2"
14 SLOT="0"
15 KEYWORDS="~amd64 ~arm ~hppa ~mips ~ppc ~ppc64 ~x86"
16
17 #Add CRYPTO_OPTS=ecc when fixed
18 CACHE_SIZE="small big +huge"
19 CRYPTO_OPTS="aes-gcm aes-ni +hc128 md2 +psk +ripemd sha512"
20 CERT_OPTS="ocsp crl crl-monitor +sessioncerts +testcert"
21 IUSE="debug -dtls ipv6 +httpd +sniffer static-libs threads +zlib cyassl-hardening ${CACHE_SIZE} ${CRYPTO_OPTS} ${CERT_OPTS}"
22
23 #You can only pick one cach size
24 #sha512 is broken on x86
25 #Testing freezes with dtls
26 REQUIRED_USE="^^ ( small big huge )
27 test? ( !dtls )"
28
29 DEPEND="app-arch/unzip
30 sniffer? ( net-libs/libpcap )
31 zlib? ( sys-libs/zlib )"
32 RDEPEND="${DEPEND}"
33
34 src_prepare() {
35 epatch "${FILESDIR}"/${PN}-2.0.8-disable-testsuit-ifnothreads.patch
36
37 #Apply unconditionally, but only triggered if USE="aes-ni"
38 epatch "${FILESDIR}"/${PN}-2.0.8-fix-gnustack.patch
39
40 # https://sourceforge.net/tracker/?func=detail&atid=714511&aid=3576451&group_id=129181
41 epatch "${FILESDIR}"/${P}-fix-missing-DYNAMIC_TYPE_LIBZ.patch
42 }
43
44 src_configure() {
45 local myconf=()
46
47 if use threads; then
48 myconf+=( --disable-singleThreaded )
49 else
50 myconf+=( --enable-singleThreaded )
51 fi
52
53 if use amd64; then
54 myconf+=( --enable-fastmath --enable-fasthugemath --enable-bump )
55 elif use x86; then
56 #not pie friendly, sorry x86, no fast math for you :(
57 myconf+=( --disable-fastmath --disable-fasthugemath --disable-bump )
58 fi
59
60 #There are lots of options, so we'll force a few reasonable
61 #We may change this in the future, in particular ecc needs to be fixed
62 econf \
63 --enable-opensslExtra \
64 --enable-fortress \
65 --enable-keygen \
66 --enable-certgen \
67 --disable-debug \
68 --disable-ecc \
69 --disable-small \
70 --disable-ntru \
71 --disable-noFilesystem \
72 --disable-noInline \
73 $(use_enable debug) \
74 $(use_enable small smallcache) \
75 $(use_enable big bigcache) \
76 $(use_enable huge hugecache) \
77 $(use_enable aes-gcm aesgcm) \
78 $(use_enable aes-ni aesni) \
79 $(use_enable hc128) \
80 $(use_enable md2) \
81 $(use_enable psk) \
82 $(use_enable ripemd) \
83 $(use_enable sha512) \
84 $(use_enable dtls) \
85 $(use_enable ipv6) \
86 $(use_enable httpd webServer) \
87 $(use_enable ocsp) \
88 $(use_enable crl) \
89 $(use_enable crl-monitor) \
90 $(use_enable sessioncerts) \
91 $(use_enable sniffer) \
92 $(use_enable testcert) \
93 $(use_enable static-libs static) \
94 $(use_enable cyassl-hardening gcc-hardening) \
95 $(use_with zlib libz) \
96 "${myconf[@]}"
97 }
98
99 src_test() {
100 "${S}"/tests/unit
101 "${S}"/ctaocrypt/benchmark/benchmark
102 }
103
104 src_install() {
105 default
106
107 mv "${D}"/usr/share/doc/"${PN}"/* \
108 "${D}"/usr/share/doc/"${P}"/
109 rmdir "${D}"/usr/share/doc/"${PN}"/
110 }

  ViewVC Help
Powered by ViewVC 1.1.20