/[gentoo-x86]/net-libs/gnutls/gnutls-3.1.4.ebuild
Gentoo

Contents of /net-libs/gnutls/gnutls-3.1.4.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.1 - (show annotations) (download)
Sat Nov 10 01:41:02 2012 UTC (22 months, 1 week ago) by flameeyes
Branch: MAIN
Version bump; a patch is needed for a test failure with USE=-dane.

(Portage version: 2.2.0_alpha142/cvs/Linux x86_64, signed Manifest commit with key 1CD13C8AD4301342)

1 # Copyright 1999-2012 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/net-libs/gnutls/gnutls-3.1.3.ebuild,v 1.3 2012/11/04 05:22:29 radhermit Exp $
4
5 EAPI=4
6
7 inherit autotools libtool eutils
8
9 DESCRIPTION="A TLS 1.2 and SSL 3.0 implementation for the GNU project"
10 HOMEPAGE="http://www.gnutls.org/"
11
12 if [[ "${PV}" == *pre* ]]; then
13 SRC_URI="http://daily.josefsson.org/${P%.*}/${P%.*}-${PV#*pre}.tar.gz"
14 else
15 SRC_URI="mirror://gnu/${PN}/${P}.tar.xz"
16 fi
17
18 # LGPL-3 for libgnutls library and GPL-3 for libgnutls-extra library.
19 LICENSE="GPL-3 LGPL-3"
20 SLOT="0"
21 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
22 IUSE="+cxx dane doc examples guile nls pkcs11 static-libs test zlib"
23
24 RDEPEND=">=dev-libs/libtasn1-2.14
25 >=dev-libs/nettle-2.5[gmp]
26 sys-devel/autogen
27 dane? ( net-dns/unbound )
28 guile? ( >=dev-scheme/guile-1.8[networking] )
29 nls? ( virtual/libintl )
30 pkcs11? ( >=app-crypt/p11-kit-0.11 )
31 zlib? ( >=sys-libs/zlib-1.2.3.1 )"
32 DEPEND="${RDEPEND}
33 virtual/pkgconfig
34 sys-devel/libtool
35 doc? ( dev-util/gtk-doc )
36 nls? ( sys-devel/gettext )
37 test? ( app-misc/datefudge )"
38
39 S=${WORKDIR}/${P%_pre*}
40
41 DOCS=( AUTHORS ChangeLog NEWS README THANKS doc/TODO )
42
43 src_prepare() {
44 local dir file
45
46 # tests/suite directory is not distributed.
47 sed -i \
48 -e ':AC_CONFIG_FILES(\[tests/suite/Makefile\]):d' \
49 -e '/^AM_INIT_AUTOMAKE/s/-Werror//' \
50 configure.ac || die
51
52 sed -i \
53 -e 's/imagesdir = $(infodir)/imagesdir = $(htmldir)/' \
54 doc/Makefile.am || die
55
56 for dir in m4 gl/m4; do
57 rm -f "${dir}/lt"* "${dir}/libtool.m4"
58 done
59 find . -name ltmain.sh -exec rm {} \;
60
61 # use system libopts
62 sed -i -e "/^enable_local_libopts/s/yes/no/" configure.ac || die
63
64 # force regeneration of autogen-ed files
65 for file in $(grep -l AutoGen-ed src/*.c) ; do
66 rm src/$(basename ${file} .c).{c,h} || die
67 done
68
69 epatch "${FILESDIR}"/${PN}-3.1.3-guile-parallelmake.patch
70 epatch "${FILESDIR}"/${P}-nodane.patch
71
72 # support user patches
73 epatch_user
74
75 eautoreconf
76
77 # Use sane .so versioning on FreeBSD.
78 elibtoolize
79 }
80
81 src_configure() {
82 # TPM needs to be tested before being enabled
83 econf \
84 --htmldir="${EPREFIX}/usr/share/doc/${PF}/html" \
85 --disable-silent-rules \
86 --disable-valgrind-tests \
87 $(use_enable cxx) \
88 $(use_enable dane libdane) \
89 $(use_enable doc gtk-doc) \
90 $(use_enable doc gtk-doc-pdf) \
91 $(use_enable guile) \
92 $(use_enable nls) \
93 $(use_enable static-libs static) \
94 $(use_with pkcs11 p11-kit) \
95 $(use_with zlib) \
96 ${myconf} \
97 --without-tpm
98 }
99
100 src_test() {
101 # let it build in parallel
102 emake check
103 }
104
105 src_install() {
106 default
107
108 find "${ED}" -name '*.la' -exec rm -f {} +
109
110 if use doc; then
111 dodoc doc/gnutls.pdf
112 dohtml doc/gnutls.html
113 fi
114
115 if use examples; then
116 docinto examples
117 dodoc doc/examples/*.c
118 fi
119 }

  ViewVC Help
Powered by ViewVC 1.1.20