/[gentoo-x86]/net-libs/qmf/qmf-2.0_p201209.ebuild
Gentoo

Contents of /net-libs/qmf/qmf-2.0_p201209.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.2 - (show annotations) (download)
Thu May 3 13:19:57 2012 UTC (23 months, 2 weeks ago) by pesa
Branch: MAIN
Changes since 1.1: +2 -2 lines
Migrate to virtual/pkgconfig.

(Portage version: 2.2.0_alpha101/cvs/Linux x86_64)

1 # Copyright 1999-2012 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/net-libs/qmf/qmf-2.0_p201209.ebuild,v 1.1 2012/04/04 15:47:36 pesa Exp $
4
5 EAPI=4
6
7 inherit qt4-r2
8
9 if [[ ${PV} == *9999* ]]; then
10 inherit git-2
11 EGIT_REPO_URI="git://gitorious.org/qt-labs/messagingframework.git
12 https://git.gitorious.org/qt-labs/messagingframework.git"
13 else
14 SRC_URI="http://dev.gentoo.org/~pesa/distfiles/${P}.tar.gz"
15 S=${WORKDIR}/qt-labs-messagingframework
16 fi
17
18 DESCRIPTION="The Qt Messaging Framework"
19 HOMEPAGE="http://qt.gitorious.org/qt-labs/messagingframework"
20
21 LICENSE="LGPL-2.1"
22 SLOT="0"
23 KEYWORDS="~amd64 ~x86"
24 IUSE="debug doc examples test"
25
26 RDEPEND="
27 dev-libs/icu
28 sys-libs/zlib
29 >=x11-libs/qt-core-4.6.0:4
30 >=x11-libs/qt-gui-4.6.0:4
31 >=x11-libs/qt-sql-4.6.0:4
32 examples? ( >=x11-libs/qt-webkit-4.6.0:4 )
33 "
34 DEPEND="${RDEPEND}
35 virtual/pkgconfig
36 test? ( >=x11-libs/qt-test-4.6.0:4 )
37 !!<net-libs/qmf-2.0_p201209
38 "
39
40 DOCS="CHANGES"
41
42 PATCHES=(
43 "${FILESDIR}/${PN}-tests.patch"
44 )
45
46 src_prepare() {
47 qt4-r2_src_prepare
48
49 # fix libdir
50 find "${S}" -name '*.pro' -type f -print0 | xargs -0 \
51 sed -i -re "s:/lib(/|$):/$(get_libdir)\1:" || die
52
53 sed -i -e '/benchmarks/d' \
54 -e '/tests/d' \
55 messagingframework.pro || die
56
57 if ! use examples; then
58 sed -i -e '/examples/d' messagingframework.pro || die
59 fi
60 }
61
62 src_configure() {
63 eqmake4 QMF_INSTALL_ROOT="${EPREFIX}/usr"
64 }
65
66 src_test() {
67 echo ">>> Test phase [QTest]: ${CATEGORY}/${PF}"
68 cd "${S}"/tests
69
70 einfo "Building tests"
71 eqmake4 QMF_INSTALL_ROOT="${EPREFIX}/usr"
72 emake
73
74 einfo "Running tests"
75 export QMF_DATA="${T}"
76 local fail=false test=
77 for test in locks longstream longstring python_email qcop qlogsystem \
78 qmailaddress qmailcodec qmaillog qmailmessage \
79 qmailmessagebody qmailmessageheader qmailmessagepart \
80 qmailnamespace qprivateimplementation; do
81 if ! LC_ALL=C ./tst_${test}/tst_${test}; then
82 eerror "'${test}' test failed!"
83 fail=true
84 fi
85 echo
86 done
87 ${fail} && die "some tests have failed!"
88 }
89
90 src_install() {
91 qt4-r2_src_install
92
93 if use doc; then
94 emake docs
95
96 dohtml -r doc/html/*
97 dodoc doc/html/qmf.qch
98 docompress -x /usr/share/doc/${PF}/qmf.qch
99 fi
100 }

  ViewVC Help
Powered by ViewVC 1.1.20