| 1 |
# Copyright 1999-2012 Gentoo Foundation
|
| 2 |
# Distributed under the terms of the GNU General Public License v2
|
| 3 |
# $Header: /var/cvsroot/gentoo-x86/net-libs/webkit-gtk/webkit-gtk-1.8.1-r201.ebuild,v 1.6 2012/08/08 21:15:31 hwoarang Exp $
|
| 4 |
|
| 5 |
EAPI="4"
|
| 6 |
|
| 7 |
# Don't define PYTHON_DEPEND: python only needed at build time
|
| 8 |
inherit autotools eutils flag-o-matic gnome2-utils pax-utils python virtualx
|
| 9 |
|
| 10 |
MY_P="webkit-${PV}"
|
| 11 |
DESCRIPTION="Open source web browser engine"
|
| 12 |
HOMEPAGE="http://www.webkitgtk.org/"
|
| 13 |
SRC_URI="http://www.webkitgtk.org/releases/${MY_P}.tar.xz"
|
| 14 |
#SRC_URI="mirror://gentoo/${P}.tar.xz"
|
| 15 |
|
| 16 |
LICENSE="LGPL-2 LGPL-2.1 BSD"
|
| 17 |
SLOT="2"
|
| 18 |
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~amd64-linux ~ia64-linux ~x86-linux ~x86-macos"
|
| 19 |
# geoclue
|
| 20 |
IUSE="aqua coverage debug +geoloc +gstreamer +introspection +jit spell +webgl"
|
| 21 |
# bugs 372493, 416331
|
| 22 |
REQUIRED_USE="introspection? ( geoloc gstreamer )"
|
| 23 |
|
| 24 |
# use sqlite, svg by default
|
| 25 |
# dependency on >=x11-libs/gtk+-2.13:2 for gail
|
| 26 |
RDEPEND="
|
| 27 |
dev-libs/libxml2:2
|
| 28 |
dev-libs/libxslt
|
| 29 |
virtual/jpeg
|
| 30 |
>=media-libs/libpng-1.4:0
|
| 31 |
>=x11-libs/cairo-1.10
|
| 32 |
>=dev-libs/glib-2.31.8:2
|
| 33 |
>=x11-libs/gtk+-2.13:2[aqua=,introspection?]
|
| 34 |
>=dev-libs/icu-3.8.1-r1
|
| 35 |
>=net-libs/libsoup-2.37.92:2.4[introspection?]
|
| 36 |
dev-db/sqlite:3
|
| 37 |
>=x11-libs/pango-1.21
|
| 38 |
x11-libs/libXrender
|
| 39 |
|
| 40 |
geoloc? ( app-misc/geoclue )
|
| 41 |
|
| 42 |
gstreamer? (
|
| 43 |
media-libs/gstreamer:0.10
|
| 44 |
>=media-libs/gst-plugins-base-0.10.30:0.10 )
|
| 45 |
|
| 46 |
introspection? ( >=dev-libs/gobject-introspection-0.9.5 )
|
| 47 |
|
| 48 |
spell? ( >=app-text/enchant-0.22 )
|
| 49 |
|
| 50 |
webgl? ( virtual/opengl )
|
| 51 |
"
|
| 52 |
# paxctl needed for bug #407085
|
| 53 |
DEPEND="${RDEPEND}
|
| 54 |
dev-lang/perl
|
| 55 |
=dev-lang/python-2*
|
| 56 |
<sys-devel/bison-2.6
|
| 57 |
>=sys-devel/flex-2.5.33
|
| 58 |
sys-devel/gettext
|
| 59 |
dev-util/gperf
|
| 60 |
virtual/pkgconfig
|
| 61 |
dev-util/gtk-doc-am
|
| 62 |
introspection? ( jit? ( sys-apps/paxctl ) )
|
| 63 |
test? ( x11-themes/hicolor-icon-theme
|
| 64 |
jit? ( sys-apps/paxctl ) )
|
| 65 |
"
|
| 66 |
# Need real bison, not yacc
|
| 67 |
|
| 68 |
S="${WORKDIR}/${MY_P}"
|
| 69 |
|
| 70 |
pkg_setup() {
|
| 71 |
# Needed for CodeGeneratorInspector.py
|
| 72 |
python_set_active_version 2
|
| 73 |
python_pkg_setup
|
| 74 |
}
|
| 75 |
|
| 76 |
src_prepare() {
|
| 77 |
DOCS="ChangeLog NEWS" # other ChangeLog files handled by src_install
|
| 78 |
|
| 79 |
# FIXME: Fix unaligned accesses on ARM, IA64 and SPARC
|
| 80 |
# https://bugs.webkit.org/show_bug.cgi?id=19775
|
| 81 |
# TODO: FAILS TO APPLY!
|
| 82 |
#use sparc && epatch "${FILESDIR}"/${PN}-1.2.3-fix-pool-sparc.patch
|
| 83 |
|
| 84 |
# CVE-2011-3064, https://bugzilla.redhat.com/show_bug.cgi?id=807596
|
| 85 |
epatch "${FILESDIR}/${PN}-1.8.0-svgimagebuffer-clip.patch"
|
| 86 |
|
| 87 |
# USE=-gstreamer build failure, bug #412221, https://bugs.webkit.org/show_bug.cgi?id=84526
|
| 88 |
epatch "${FILESDIR}/${PN}-1.8.1-CodeGeneratorGObject-properties.patch"
|
| 89 |
|
| 90 |
# bug #416057; in 1.9.x
|
| 91 |
epatch "${FILESDIR}/${PN}-1.8.1-gst-required-version.patch"
|
| 92 |
|
| 93 |
# intermediate MacPorts hack while upstream bug is not fixed properly
|
| 94 |
# https://bugs.webkit.org/show_bug.cgi?id=28727
|
| 95 |
use aqua && epatch "${FILESDIR}"/${PN}-1.6.1-darwin-quartz.patch
|
| 96 |
|
| 97 |
# Bug #403049, https://bugs.webkit.org/show_bug.cgi?id=79605
|
| 98 |
epatch "${FILESDIR}/${PN}-1.7.5-linguas.patch"
|
| 99 |
|
| 100 |
# Drop DEPRECATED flags
|
| 101 |
sed -i -e 's:-D[A-Z_]*DISABLE_DEPRECATED:$(NULL):g' GNUmakefile.am || die
|
| 102 |
|
| 103 |
# Don't force -O2
|
| 104 |
sed -i 's/-O2//g' "${S}"/configure.ac || die
|
| 105 |
|
| 106 |
# Build-time segfaults under PaX with USE="introspection jit", bug #404215
|
| 107 |
if use introspection && use jit; then
|
| 108 |
epatch "${FILESDIR}/${PN}-1.6.3-paxctl-introspection.patch"
|
| 109 |
cp "${FILESDIR}/gir-paxctl-lt-wrapper" "${S}/" || die
|
| 110 |
fi
|
| 111 |
|
| 112 |
# We need to reset some variables to prevent permissions problems and failures
|
| 113 |
# like https://bugs.webkit.org/show_bug.cgi?id=35471 and bug #323669
|
| 114 |
gnome2_environment_reset
|
| 115 |
|
| 116 |
# https://bugs.webkit.org/show_bug.cgi?id=79498
|
| 117 |
epatch "${FILESDIR}/${PN}-1.7.90-parallel-make-hack.patch"
|
| 118 |
|
| 119 |
# XXX: failing tests
|
| 120 |
# https://bugs.webkit.org/show_bug.cgi?id=50744
|
| 121 |
# testkeyevents is interactive
|
| 122 |
# mimehandling test sometimes fails under Xvfb (works fine manually)
|
| 123 |
# datasource test needs a network connection and intermittently fails with
|
| 124 |
# icedtea-web
|
| 125 |
sed -e '/Programs\/unittests\/testwebinspector/ d' \
|
| 126 |
-e '/Programs\/unittests\/testkeyevents/ d' \
|
| 127 |
-e '/Programs\/unittests\/testmimehandling/ d' \
|
| 128 |
-e '/Programs\/unittests\/testwebdatasource/ d' \
|
| 129 |
-i Source/WebKit/gtk/GNUmakefile.am || die
|
| 130 |
# garbage collection test fails intermittently if icedtea-web is installed
|
| 131 |
epatch "${FILESDIR}/${PN}-1.7.90-test_garbage_collection.patch"
|
| 132 |
|
| 133 |
# occasional test failure due to additional Xvfb process spawned
|
| 134 |
epatch "${FILESDIR}/${PN}-1.8.1-tests-xvfb.patch"
|
| 135 |
|
| 136 |
# For >=sys-devel/automake-1.12 compability wrt #420591
|
| 137 |
sed -i -e 's:mkdir_p:MKDIR_P:' {.,Source/WebKit/gtk/po}/GNUmakefile.am || die
|
| 138 |
|
| 139 |
# Respect CC, otherwise fails on prefix #395875
|
| 140 |
tc-export CC
|
| 141 |
|
| 142 |
# Prevent maintainer mode from being triggered during make
|
| 143 |
AT_M4DIR=Source/autotools eautoreconf
|
| 144 |
|
| 145 |
# Ugly hack of a workaround for bizarre paludis behavior, bug #406117
|
| 146 |
# http://paludis.exherbo.org/trac/ticket/1230
|
| 147 |
sed -e '/ --\(en\|dis\)able-dependency-tracking/ d' -i configure || die
|
| 148 |
}
|
| 149 |
|
| 150 |
src_configure() {
|
| 151 |
# It doesn't compile on alpha without this in LDFLAGS
|
| 152 |
use alpha && append-ldflags "-Wl,--no-relax"
|
| 153 |
|
| 154 |
# Sigbuses on SPARC with mcpu and co.
|
| 155 |
use sparc && filter-flags "-mvis"
|
| 156 |
|
| 157 |
# https://bugs.webkit.org/show_bug.cgi?id=42070 , #301634
|
| 158 |
use ppc64 && append-flags "-mminimal-toc"
|
| 159 |
|
| 160 |
local myconf
|
| 161 |
|
| 162 |
# XXX: Check Web Audio support
|
| 163 |
# XXX: dependency-tracking is required so parallel builds won't fail
|
| 164 |
# WebKit2 can only be built with gtk3
|
| 165 |
# API documentation (gtk-doc) is built in webkit-gtk:3, always disable here
|
| 166 |
myconf="
|
| 167 |
$(use_enable coverage)
|
| 168 |
$(use_enable debug)
|
| 169 |
$(use_enable debug debug-features)
|
| 170 |
$(use_enable geoloc geolocation)
|
| 171 |
$(use_enable spell spellcheck)
|
| 172 |
$(use_enable introspection)
|
| 173 |
$(use_enable gstreamer video)
|
| 174 |
$(use_enable jit)
|
| 175 |
$(use_enable webgl)
|
| 176 |
--enable-web-sockets
|
| 177 |
--with-gtk=2.0
|
| 178 |
--disable-gtk-doc
|
| 179 |
--disable-webkit2
|
| 180 |
--enable-dependency-tracking
|
| 181 |
$(use aqua && echo "--with-font-backend=pango --with-target=quartz")"
|
| 182 |
|
| 183 |
econf ${myconf}
|
| 184 |
}
|
| 185 |
|
| 186 |
src_compile() {
|
| 187 |
# Horrible failure of a hack to work around parallel make problems,
|
| 188 |
# see https://bugs.webkit.org/show_bug.cgi?id=79498
|
| 189 |
emake -j1 all-built-sources-local
|
| 190 |
emake all-ltlibraries-local
|
| 191 |
emake all-programs-local
|
| 192 |
use introspection && emake WebKit-1.0.gir
|
| 193 |
emake all-data-local
|
| 194 |
default
|
| 195 |
}
|
| 196 |
|
| 197 |
src_test() {
|
| 198 |
# Tests expect an out-of-source build in WebKitBuild
|
| 199 |
ln -s . WebKitBuild || die "ln failed"
|
| 200 |
# Prevents test failures on PaX systems
|
| 201 |
use jit && pax-mark m $(list-paxables Programs/unittests/test*) \
|
| 202 |
Programs/unittests/.libs/test*
|
| 203 |
unset DISPLAY
|
| 204 |
# Tests need virtualx, bug #294691, bug #310695
|
| 205 |
# Parallel tests sometimes fail
|
| 206 |
Xemake -j1 check
|
| 207 |
}
|
| 208 |
|
| 209 |
src_install() {
|
| 210 |
default
|
| 211 |
|
| 212 |
newdoc Source/WebKit/gtk/ChangeLog ChangeLog.gtk
|
| 213 |
newdoc Source/WebKit/gtk/po/ChangeLog ChangeLog.gtk-po
|
| 214 |
newdoc Source/JavaScriptCore/ChangeLog ChangeLog.JavaScriptCore
|
| 215 |
newdoc Source/WebCore/ChangeLog ChangeLog.WebCore
|
| 216 |
|
| 217 |
# Remove .la files
|
| 218 |
find "${D}" -name '*.la' -exec rm -f '{}' +
|
| 219 |
|
| 220 |
# Prevents crashes on PaX systems
|
| 221 |
use jit && pax-mark m "${ED}usr/bin/jsc-1"
|
| 222 |
|
| 223 |
# File collisions with slot 3
|
| 224 |
# bug #402699, https://bugs.webkit.org/show_bug.cgi?id=78134
|
| 225 |
rm -rf "${ED}usr/share/gtk-doc" || die
|
| 226 |
}
|
Parent Directory
| 
Revision Log