net-misc/electrum/electrum-1.0.ebuild

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="4"
PYTHON_DEPEND="2:2.6"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="2.5 3.*"

inherit eutils distutils gnome2-utils

MY_P=Electrum-${PV}
DESCRIPTION="User friendly Bitcoin client"
HOMEPAGE="http://electrum-desktop.com/"
SRC_URI="http://electrum-desktop.com/files/${MY_P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="gtk qt4"
REQUIRED_USE="|| ( gtk qt4 )"

LANGS="en cs de fr nl ru sl vi zh"

for X in ${LANGS}; do
        IUSE+=" linguas_${X}"
done
unset X

RDEPEND="dev-python/ecdsa
        dev-python/slowaes
        gtk? ( dev-python/pygtk:2 )
        qt4? ( dev-python/PyQt4 )"

S=${WORKDIR}/${MY_P}

DOCS="RELEASE-NOTES"

src_prepare() {
        # Prevent icon from being installed in the wrong location:
        sed -i '/electrum\.png/ d' setup.py || die
        sed -i "s:^Icon=.*:Icon=${PN}:" "${PN}.desktop" || die

        # Fix language code
        mv locale/cn locale/zh || die  # Chinese

        # Remove unrequested localization files:
        local lang
        for lang in ${LANGS#en}; do
                if use linguas_$lang; then
                        test -f "locale/$lang/LC_MESSAGES/${PN}.mo" || die
                else
                        rm -r "locale/$lang" || die
                fi
        done

        # Remove unrequested GUI implementations:
        if use !gtk; then
                rm lib/gui.py || die
        fi
        if use !qt4; then
                rm lib/gui_qt.py lib/gui_lite.py || die
                sed -i 's/default="lite"/default="gtk"/' electrum || die
        fi

        distutils_src_prepare
}

src_install() {
        doicon -s 64 ${PN}.png
        distutils_src_install
}

pkg_preinst() {
        gnome2_icon_savelist
}

pkg_postinst() {
        gnome2_icon_cache_update
        distutils_pkg_postinst
}

pkg_postrm() {
        gnome2_icon_cache_update
        distutils_pkg_postrm
}
1	# Copyright 1999-2012 Gentoo Foundation
2	# Distributed under the terms of the GNU General Public License v2
3	# $Header: $
4
5	EAPI="4"
6	PYTHON_DEPEND="2:2.6"
7	SUPPORT_PYTHON_ABIS="1"
8	RESTRICT_PYTHON_ABIS="2.5 3.*"
9
10	inherit eutils distutils gnome2-utils
11
12	MY_P=Electrum-${PV}
13	DESCRIPTION="User friendly Bitcoin client"
14	HOMEPAGE="http://electrum-desktop.com/"
15	SRC_URI="http://electrum-desktop.com/files/${MY_P}.tar.gz"
16
17	LICENSE="GPL-3"
18	SLOT="0"
19	KEYWORDS="~amd64 ~x86"
20	IUSE="gtk qt4"
21	REQUIRED_USE="\|\| ( gtk qt4 )"
22
23	LANGS="en cs de fr nl ru sl vi zh"
24
25	for X in ${LANGS}; do
26	IUSE+=" linguas_${X}"
27	done
28	unset X
29
30	RDEPEND="dev-python/ecdsa
31	dev-python/slowaes
32	gtk? ( dev-python/pygtk:2 )
33	qt4? ( dev-python/PyQt4 )"
34
35	S=${WORKDIR}/${MY_P}
36
37	DOCS="RELEASE-NOTES"
38
39	src_prepare() {
40	# Prevent icon from being installed in the wrong location:
41	sed -i '/electrum\.png/ d' setup.py \|\| die
42	sed -i "s:^Icon=.*:Icon=${PN}:" "${PN}.desktop" \|\| die
43
44	# Fix language code
45	mv locale/cn locale/zh \|\| die # Chinese
46
47	# Remove unrequested localization files:
48	local lang
49	for lang in ${LANGS#en}; do
50	if use linguas_$lang; then
51	test -f "locale/$lang/LC_MESSAGES/${PN}.mo" \|\| die
52	else
53	rm -r "locale/$lang" \|\| die
54	fi
55	done
56
57	# Remove unrequested GUI implementations:
58	if use !gtk; then
59	rm lib/gui.py \|\| die
60	fi
61	if use !qt4; then
62	rm lib/gui_qt.py lib/gui_lite.py \|\| die
63	sed -i 's/default="lite"/default="gtk"/' electrum \|\| die
64	fi
65
66	distutils_src_prepare
67	}
68
69	src_install() {
70	doicon -s 64 ${PN}.png
71	distutils_src_install
72	}
73
74	pkg_preinst() {
75	gnome2_icon_savelist
76	}
77
78	pkg_postinst() {
79	gnome2_icon_cache_update
80	distutils_pkg_postinst
81	}
82
83	pkg_postrm() {
84	gnome2_icon_cache_update
85	distutils_pkg_postrm
86	}