net-misc/electrum/electrum-1.6.2.ebuild

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/electrum/electrum-1.0.ebuild,v 1.1 2012/09/16 20:45:21 blueness Exp $

EAPI="5"

PYTHON_COMPAT=( python{2_6,2_7} )

inherit eutils distutils-r1 gnome2-utils

MY_P=Electrum-${PV}
DESCRIPTION="User friendly Bitcoin client"
HOMEPAGE="http://electrum.org/"
SRC_URI="http://download.electrum.org/download/${MY_P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="gtk qt4"
REQUIRED_USE="|| ( gtk qt4 )"

LANGS="br cs de eo es fr it lv nl ru sl vi zh"

for X in ${LANGS}; do
        IUSE+=" linguas_${X}"
done
unset X

RDEPEND="
        dev-python/setuptools
        dev-python/ecdsa
        dev-python/slowaes
        gtk? ( dev-python/pygtk:2 )
        qt4? ( dev-python/PyQt4 )"

S=${WORKDIR}/${MY_P}

DOCS="RELEASE-NOTES"

src_prepare() {
        # Prevent icon from being installed in the wrong location:
        sed -i '/electrum\.png/ d' setup.py || die
        sed -i "s:^Icon=.*:Icon=${PN}:" "${PN}.desktop" || die

        # Remove unrequested localization files:
        local lang
        for lang in ${LANGS#en}; do
                if use linguas_$lang; then
                        test -f "locale/$lang/LC_MESSAGES/${PN}.mo" || die
                else
                        rm -r "locale/$lang" || die
                fi
        done

        # Remove unrequested GUI implementations:
        if use !gtk; then
                rm lib/gui.py || die
        fi
        if use !qt4; then
                rm lib/gui_qt.py lib/gui_lite.py || die
                sed -i 's/default="lite"/default="gtk"/' electrum || die
        fi

        distutils-r1_src_prepare
}

src_install() {
        doicon -s 64 icons/${PN}.png
        distutils-r1_src_install
}

pkg_preinst() {
        gnome2_icon_savelist
}

pkg_postinst() {
        gnome2_icon_cache_update
}

pkg_postrm() {
        gnome2_icon_cache_update
}
1	# Copyright 1999-2013 Gentoo Foundation
2	# Distributed under the terms of the GNU General Public License v2
3	# $Header: /var/cvsroot/gentoo-x86/net-misc/electrum/electrum-1.0.ebuild,v 1.1 2012/09/16 20:45:21 blueness Exp $
4
5	EAPI="5"
6
7	PYTHON_COMPAT=( python{2_6,2_7} )
8
9	inherit eutils distutils-r1 gnome2-utils
10
11	MY_P=Electrum-${PV}
12	DESCRIPTION="User friendly Bitcoin client"
13	HOMEPAGE="http://electrum.org/"
14	SRC_URI="http://download.electrum.org/download/${MY_P}.tar.gz"
15
16	LICENSE="GPL-3"
17	SLOT="0"
18	KEYWORDS="~amd64 ~x86"
19	IUSE="gtk qt4"
20	REQUIRED_USE="\|\| ( gtk qt4 )"
21
22	LANGS="br cs de eo es fr it lv nl ru sl vi zh"
23
24	for X in ${LANGS}; do
25	IUSE+=" linguas_${X}"
26	done
27	unset X
28
29	RDEPEND="
30	dev-python/setuptools
31	dev-python/ecdsa
32	dev-python/slowaes
33	gtk? ( dev-python/pygtk:2 )
34	qt4? ( dev-python/PyQt4 )"
35
36	S=${WORKDIR}/${MY_P}
37
38	DOCS="RELEASE-NOTES"
39
40	src_prepare() {
41	# Prevent icon from being installed in the wrong location:
42	sed -i '/electrum\.png/ d' setup.py \|\| die
43	sed -i "s:^Icon=.*:Icon=${PN}:" "${PN}.desktop" \|\| die
44
45	# Remove unrequested localization files:
46	local lang
47	for lang in ${LANGS#en}; do
48	if use linguas_$lang; then
49	test -f "locale/$lang/LC_MESSAGES/${PN}.mo" \|\| die
50	else
51	rm -r "locale/$lang" \|\| die
52	fi
53	done
54
55	# Remove unrequested GUI implementations:
56	if use !gtk; then
57	rm lib/gui.py \|\| die
58	fi
59	if use !qt4; then
60	rm lib/gui_qt.py lib/gui_lite.py \|\| die
61	sed -i 's/default="lite"/default="gtk"/' electrum \|\| die
62	fi
63
64	distutils-r1_src_prepare
65	}
66
67	src_install() {
68	doicon -s 64 icons/${PN}.png
69	distutils-r1_src_install
70	}
71
72	pkg_preinst() {
73	gnome2_icon_savelist
74	}
75
76	pkg_postinst() {
77	gnome2_icon_cache_update
78	}
79
80	pkg_postrm() {
81	gnome2_icon_cache_update
82	}