/[gentoo-x86]/net-misc/mosh/mosh-9999.ebuild
Gentoo

Contents of /net-misc/mosh/mosh-9999.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.12 - (show annotations) (download)
Tue Oct 30 00:28:06 2012 UTC (23 months, 3 weeks ago) by xmw
Branch: MAIN
Changes since 1.11: +7 -1 lines
Fix bash-comp paths (bug 440124, thanks Marcin Mirosław)

(Portage version: 2.1.11.31/cvs/Linux x86_64, signed Manifest commit with key 62EEF090)

1 # Copyright 1999-2012 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/net-misc/mosh/mosh-9999.ebuild,v 1.11 2012/05/28 16:43:19 xmw Exp $
4
5 EAPI=4
6 EGIT_REPO_URI="https://github.com/keithw/mosh.git"
7
8 inherit autotools git-2
9
10 DESCRIPTION="Mobile shell that supports roaming and intelligent local echo"
11 HOMEPAGE="http://mosh.mit.edu"
12
13 LICENSE="GPL-3"
14 SLOT="0"
15 KEYWORDS=""
16 IUSE="bash-completion +client examples +mosh-hardening +server ufw +utempter"
17 REQUIRED_USE="|| ( client server )
18 examples? ( client )"
19
20 RDEPEND="dev-libs/protobuf
21 sys-libs/ncurses:5
22 virtual/ssh
23 client? ( dev-lang/perl
24 dev-perl/IO-Tty )
25 utempter? ( sys-libs/libutempter )"
26 DEPEND="${RDEPEND}
27 dev-vcs/git[curl]
28 virtual/pkgconfig"
29
30 src_prepare() {
31 eautoreconf
32 }
33
34 src_configure() {
35 econf \
36 $(use_enable test tests) \
37 $(use_enable bash-completion completion) \
38 $(use_enable client) \
39 $(use_enable server) \
40 $(use_enable examples) \
41 $(use_enable ufw) \
42 $(use_enable mosh-hardening hardening) \
43 $(use_with utempter)
44 }
45
46 src_compile() {
47 emake V=1
48 }
49
50 src_test() {
51 einfo "running test encrypt-decrypt"
52 ./src/tests/encrypt-decrypt -q || die
53 einfo "running test ocb-aes"
54 ./src/tests/ocb-aes -q || die
55 }
56
57 src_install() {
58 default
59
60 for myprog in $(find src/examples -type f -perm /0111) ; do
61 newbin ${myprog} ${PN}-$(basename ${myprog})
62 elog "${myprog} installed as ${PN}-$(basename ${myprog})"
63 done
64
65 if use bash-completion ; then
66 insinto /usr/share/bash-completion
67 doins "${D}"/etc/bash_completion.d/mosh
68 rm -rf "${D}"/etc/bash_completion.d
69 fi
70 }

  ViewVC Help
Powered by ViewVC 1.1.20