/[gentoo-x86]/net-misc/nx/nx-3.5.0.15.ebuild
Gentoo

Contents of /net-misc/nx/nx-3.5.0.15.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.3 - (show annotations) (download)
Sun Dec 16 16:29:05 2012 UTC (21 months ago) by ago
Branch: MAIN
Changes since 1.2: +2 -2 lines
Stable for x86, wrt bug #445766

(Portage version: 2.1.11.31/cvs/Linux x86_64, unsigned Manifest commit)

1 # Copyright 1999-2012 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/net-misc/nx/nx-3.5.0.15.ebuild,v 1.2 2012/12/03 13:43:37 ago Exp $
4
5 EAPI=4
6 inherit autotools eutils multilib
7
8 DESCRIPTION="NX compression technology core libraries"
9 HOMEPAGE="http://www.nomachine.com/developers.php
10 http://www.x2go.org/doku.php/wiki:libs:nx-libs"
11
12 SRC_URI="http://code.x2go.org/releases/source/nx-libs/nx-libs-${PV}-full.tar.gz"
13
14 LICENSE="GPL-2"
15 SLOT="0"
16 KEYWORDS="amd64 ~ppc x86"
17 IUSE="elibc_glibc"
18
19 RDEPEND="elibc_glibc? ( || ( net-libs/libtirpc <sys-libs/glibc-2.14 ) )
20 >=media-libs/libpng-1.2.8
21 >=sys-libs/zlib-1.2.3
22 virtual/jpeg"
23
24 DEPEND="${RDEPEND}
25 x11-misc/gccmakedep
26 x11-misc/imake
27 x11-proto/inputproto"
28
29 S=${WORKDIR}/nx-libs-${PV}
30
31 src_prepare() {
32 # For nxcl/qtnx
33 cd "${S}"/nxproxy
34 epatch "${FILESDIR}"/${PN}-3.2.0-nxproxy_read_from_stdin.patch
35
36 cd "${S}"
37 # Fix sandbox violation
38 epatch "${FILESDIR}"/1.5.0/nx-x11-1.5.0-tmp-exec.patch
39 # -fPIC
40 epatch "${FILESDIR}"/1.5.0/nxcomp-1.5.0-pic.patch
41 # Respect CFLAGS/CXXFLAGS
42 epatch "${FILESDIR}"/${PN}-3.3.0-cflags.patch
43 # Run autoreconf in all neeed folders
44 for i in nxcomp nxcompext nxcompshad nxproxy; do
45 cd "${S}"/${i}
46 eautoreconf ${i}
47 cd "${S}"
48 done
49
50 # From xorg-x11-6.9.0-r3.ebuild
51 cd "${S}/nx-X11"
52 HOSTCONF="config/cf/host.def"
53 echo "#define CcCmd $(tc-getCC)" >> ${HOSTCONF}
54 echo "#define OptimizedCDebugFlags ${CFLAGS} GccAliasingArgs" >> ${HOSTCONF}
55 echo "#define OptimizedCplusplusDebugFlags ${CXXFLAGS} GccAliasingArgs" >> ${HOSTCONF}
56 # Respect LDFLAGS
57 echo "#define ExtraLoadFlags ${LDFLAGS}" >> ${HOSTCONF}
58 echo "#define SharedLibraryLoadFlags -shared ${LDFLAGS}" >> ${HOSTCONF}
59 }
60
61 src_configure() {
62 cd "${S}"/nxproxy
63 econf
64 }
65
66 src_compile() {
67 cd "${S}/nx-X11"
68 FAST=1 emake World WORLDOPTS="" MAKE="make"
69
70 cd "${S}"/nxproxy
71 emake
72 }
73
74 src_install() {
75 NX_ROOT=/usr/$(get_libdir)/NX
76
77 for x in nxagent nxauth nxproxy; do
78 make_wrapper $x ./$x ${NX_ROOT}/bin ${NX_ROOT}/$(get_libdir) ||
79 die " $x wrapper creation failed"
80 done
81
82 into ${NX_ROOT}
83 dobin "${S}"/nx-X11/programs/Xserver/nxagent
84 dobin "${S}"/nx-X11/programs/nxauth/nxauth
85 dobin "${S}"/nxproxy/nxproxy
86
87 for lib in X11 Xau Xcomposite Xdamage Xdmcp Xext Xfixes Xinerama Xpm Xrandr Xrender Xtst;
88 do
89 dolib.so "${S}"/nx-X11/lib/${lib}/libNX_${lib}.so*
90 done
91 dolib.so "${S}"/nx-X11/lib/freetype2/libNX_freetype.so*
92
93 dolib.so "${S}"/nxcomp/libXcomp.so*
94 dolib.so "${S}"/nxcompext/libXcompext.so*
95 dolib.so "${S}"/nxcompshad/libXcompshad.so*
96 }

  ViewVC Help
Powered by ViewVC 1.1.20